external_functions.pl

'ENUMERATE'(Obj,pred_true,WF) :-
    get_wait_flag(1.1,WF,WF1), % ensures that wait_flag1 phase done, e.g., setting up intervals
    enumerate_aux(Obj,WF1,WF).

'LINKED_ENUMERATION'(Obj1,Obj2,pred_true,WF) :- link_enum_aux(Obj1,Obj2,WF).

enumerate_aux(X,_,WF) :- kernel_waitflags:find_waitflag_info(WF,Info,Prio,LWF), % linear in size of waitflag store !
    var(LWF), Info == element_of_avl(X),
    !,
    debug_println(9,found_element_of_avl_trigger(Prio,X)),
    LWF = Prio.

enumerate_aux(X,_,WF) :- var(X), !, frozen(X,G), %trace, print(frozen(X,G)),nl,
    trigger_enumerators(G,X,Triggered),
    (Triggered == true -> true ; add_message('ENUMERATE','Could not trigger ENUMERATE: ',X), enumerate_aux(X,X,WF)).

enumerate_aux(fd(X,GS),_,WF) :- !, kernel_objects:enumerate_basic_type_wf(fd(X,GS),global(GS),WF).

enumerate_aux(int(X),_,WF) :- !,
    kernel_objects:enumerate_basic_type_wf(int(X),integer,WF).

enumerate_aux((A,B),WF1,WF) :- !, % should we look for a element_of_avl(X) waitflag in WF store ?
    enumerate_aux(A,WF1,WF), enumerate_aux(B,WF1,WF).

enumerate_aux(rec(Fields),WF1,WF) :- !, % ditto
    maplist(enumerate_field(WF1,WF),Fields).

enumerate_aux(Obj,_,_WF) :- %kernel_waitflags:portray_waitflags(_WF),trace,
    add_error(external_functions,'Cannot ENUMERATE value yet: ',Obj).

enumerate_field(WF1,WF,field(_,Val)) :- enumerate_aux(Val,WF1,WF).

expects_waitflag('LINKED_ENUMERATION').

link_enum_aux(fd(X,_),Obj2,WF) :- !, link_enum_block(X,Obj2,WF).

link_enum_aux(int(X),Obj2,WF) :- !, link_enum_block(X,Obj2,WF).

link_enum_aux(string(X),Obj2,WF) :- !, link_enum_block(X,Obj2,WF).

link_enum_aux(Obj1,Obj2,WF) :- when(ground(Obj1),link_enum_block(1,Obj2,WF)).

link_enum_block(_X,Obj2,WF) :- %print(linked_enumeration(_X,Obj2)), tools_printing:print_arg(Obj2),nl,
    get_wait_flag1(WF,WF1), % give chance to run deterministic propagations
    enumerate_aux(Obj2,WF1,WF).

trigger_enumerators((A,B),V,Triggered) :- !, trigger_enumerators(A,V,Triggered), trigger_enumerators(B,V,Triggered).

trigger_enumerators(custom_explicit_sets:element_of_avl_set_wf3(Var,_,ApproxSize,WF1,_),V,Triggered) :-
    Var==V, var(WF1), !, print(trigger(Var,ApproxSize)),nl,WF1=float(ApproxSize), Triggered=true.

trigger_enumerators(_,_,_).