z_tools

append_not_duplicate(A,B,Result) :-
    remove_all(B,A,D),
    append(A,D,Result).

decorate_vars(In,Deco,Out) :- (Deco = '' -> In=Out ; decorate_vars2(In,Deco,Out)).

decorate_vars2([],_,[]).

decorate_vars2([name(Name,D1)|Rest],Deco,[name(Name,D2)|DRest]) :-
    atom_concat(D1,Deco,D2),
    decorate_vars2(Rest,Deco,DRest).

find_unchanged(ti(body(Decls,Where),Type),UnchangedVars,ti(body(Decls,RestWhere),Type)) :-
    find_unchanged2(Where,UnchangedVars,RestWhere).

find_unchanged2([],[],[]) :- !.

find_unchanged2([ti(equal(ti(ref(name(Name,DecoA),[]),_),
    ti(ref(name(Name,DecoB),[]),_)),bool)|ExprRest],
    [name(Name,'')|UnchangedRest],Rest) :-
    ( (DecoA = '', DecoB = '\'') % TODO: Use library(lists)
    ; (DecoA = '\'', DecoB = '')),!,
    find_unchanged2(ExprRest,UnchangedRest,Rest).

find_unchanged2([Pred|Rest],Unchanged,[Pred|FRest]) :- find_unchanged2(Rest,Unchanged,FRest).

lcombine(List,Op,Neutral,Result) :-
    lcombine2(List,Op,Neutral,Neutral,Result).

lcombine2([],_,_,Result,Result).

lcombine2([A|Rest],Op,Neutral,Acc,Result) :-
    lcombine3(Acc,A,Op,Neutral,Inter),
    lcombine2(Rest,Op,Neutral,Inter,Result).

lcombine3(Neutral,B,_,Neutral,B) :- !.

lcombine3(A,Neutral,_,Neutral,A) :- !.

lcombine3(A,B,Op,_,Result) :- Result =.. [Op,A,B].

vars_of_decl(Decls,Vars) :-
    findall(V,
    (member(decl(Vars,_Type),Decls),member(V,Vars)),
    Vars).

z_conjunction(List,Result) :- lcombine(List,and,truth,Result).

z_conjunctiont(List,Result) :-
    z_conjunctiont2(List,ti(truth,bool),Result).

z_conjunctiont2([],Result,Result).

z_conjunctiont2([A|Rest],Acc,Result) :-
    z_conjunctiont3(Acc,A,Inter),
    z_conjunctiont2(Rest,Inter,Result).

z_conjunctiont3(ti(truth,bool),B,B) :- !.

z_conjunctiont3(A,ti(truth,bool),A) :- !.

z_conjunctiont3(A,B,ti(and(A,B),bool)).

z_counter(Name,NewName) :-
    retract(z_counter_db(C)),
    C1 is C + 1,
    assertz(z_counter_db(C1)),
    atom_codes(Name,NC), number_codes(C,CC),
    append(NC,CC,NewC),
    atom_codes(NewName,NewC).

z_counter_db(1).

z_disjunction(List,Result) :- lcombine(List,or,falsity,Result).

z_translate_identifier(name(ZName,Deco), BName) :-
    atom_concat(ZName, Deco, BName).

z_translate_identifier_list([],[]).

z_translate_identifier_list([ZName|ZRest],['Identifier'(BName)|BRest]) :-
    z_translate_identifier(ZName,BName),
    z_translate_identifier_list(ZRest,BRest).

z_translate_identifiers([],[]).

z_translate_identifiers([ZName|ZRest],[BName|BRest]) :-
    z_translate_identifier(ZName,BName),
    z_translate_identifiers(ZRest,BRest).

z_translate_typed_identifier(name(ZName,Deco),Type,Infos,TExpr) :-
    ajoin([ZName,Deco],Id),
    create_texpr(identifier(Id),Type,[zname(ZName,Deco)|Infos],TExpr).

z_translate_typed_identifiers([],[],_,[]).

z_translate_typed_identifiers([ZName|Zrest],[Type|Trest],Infos,[TExpr|Brest]) :-
    z_translate_typed_identifier(ZName,Type,Infos,TExpr),
    z_translate_typed_identifiers(Zrest,Trest,Infos,Brest).