interval

aadd(integer([MinA,MaxA]),integer([MinB,MaxB]),integer([MinC,MaxC])) :-
    MinCT is MinA + MinB, MaxCT is MaxA + MaxB,
    bound_ints(MinCT,MaxCT,MinC,MaxC).

acard(set(_Contents,[CurMinCard,CurMaxCard],_MaxCard), integer([CurMinCard,CurMaxCard])).

adiv(integer([MinA,MaxA]),integer([MinB,MaxB]),integer([MinCR,MaxCR])) :-
    % todo: div by zero
    (MaxB \= 0 -> MinC is MinA/MaxB ; MinC is MinA),
    (MinB \= 0 -> MaxC is MaxA/MinB ; MaxC is MaxA),
    MinCR is floor(MinC), MaxCR is floor(MaxC).

adomain(SV1,set(Value,[CurMinCard,CurMaxCard],MaxCard)) :-
    !, SV1 = set(couple(Value,_X),[SetCurMinCard,SetCurMaxCard],_SetMaxCard),
    max_cardinality(Value,MaxCard),
    CurMinCard = SetCurMinCard, CurMaxCard is min(SetCurMaxCard,MaxCard).

aequal(A,A,A,A,true).

aequal(integer([MinA,MaxA]),integer([MinB,MaxB]),integer([MinA,MaxA]),integer([MinB,MaxB]),false) :-
    (MaxA < MinB ; MaxB < MinA), !.

aequal(integer([MinA,MaxA]),integer([MinB,MaxB]),integer([MinOut,MaxOut]),integer([MinOut,MaxOut]),true) :-
    MinOut is max(MinA,MinB), MaxOut is min(MaxA,MaxB).

aequal(set(Type,[0,0],MaxCard),set(Type,[0,0],MaxCard),set(Type,[0,0],MaxCard),set(Type,[0,0],MaxCard),true).

agreater(A,B,C,D,Res) :- aless(B,A,D,C,Res).

aintersection(set(X,[CurMinCardX,CurMaxCardX],MaxCardX), set(Y,[_CurMinCardY,CurMaxCardY],_MaxCardY),Out) :-
    lub(X,Y,Z), CurMinCardZ is max(0,CurMinCardX-CurMaxCardY),
    CurMaxCardZ is CurMaxCardX, MaxCardZ is MaxCardX,
    Out = set(Z,[CurMinCardZ,CurMaxCardZ],MaxCardZ).

ainterval(Int1,Int2,set(Int3,[MaxCard,MaxCard],[MaxCard])) :-
    lub(Int1,Int2,Int3), max_cardinality(Int3,MaxCard).

aless(integer([MinA,MaxA]),integer([MinB,MaxB]),integer([MinA,MaxA]),integer([MinB,MaxB]),true) :-
    MaxA < MinB.

aless(integer([MinA,_MaxA]),integer([MinB,MaxB]),integer([MinA,MaxAOut]),integer([MinB,MaxB]),true) :-
    MaxAOut is MinB - 1, MaxAOut > MinA.

aless(integer([MinA,MaxA]),integer([_MinB,MaxB]),integer([MinA,MaxA]),integer([MinBOut,MaxB]),true) :-
    MinBOut is MaxA + 1, MinBOut < MaxB.

aless_equal(A,B,C,D,E) :- aless(A,B,C,D,E) ; aequal(A,B,C,D,E).

alpha(boolean,_Type,_Infos,boolean) :- !.

alpha(boolean_true,_Type,_Infos,boolean_true) :- !.

alpha(boolean_false,_Type,_Infos,boolean_false) :- !.

alpha(global(X),_Type,_Infos,global(X)) :- !.

alpha(string,_Type,_Infos,string) :- !.

alpha(integer,_Type,_Infos,integer([MinInt,MaxInt])) :- !,
    preferences:get_preference(minint,MinInt),
    preferences:get_preference(maxint,MaxInt).

alpha(couple(X,Y),_Type,_Infos,couple(AbsX,AbsY)) :- !,
    alpha(X,X,[],AbsX), alpha(Y,Y,[],AbsY).

alpha(set(_X),Type,Infos,Abs) :- !,
    alpha(empty_set,Type,Infos,Abs).

alpha(integer(X),_Type,_Infos,integer([X,X])) :- !.

alpha(empty_set,set(SetOfType),_Infos,set(AbsType,[0,0],MaxCard)) :- !,
    alpha(SetOfType,SetOfType,[],AbsType),
    max_cardinality(SetOfType,MaxCard).

amember(integer(X),set(integer(Y),[CurMinCard,CurMaxCard],MaxCard),integer(X),set(integer(Y),[CurMinCard,CurMaxCard],MaxCard),true) :-
    CurMinCard > 0, lub(integer(X),integer(Y),integer(Y)).

amember(Elem,set(Type,[CurMinCard,CurMaxCard],MaxCard),Elem,set(Type,[CurMinCard,CurMaxCard],MaxCard),true) :-
    CurMinCard > 0.

amember(Elem,set(Type,[CurMinCard,CurMaxCard],MaxCard),Elem,set(Type,[CurMinCard,CurMaxCard],MaxCard),false) :-
    CurMinCard = 0.

aminus(integer([MinA,MaxA]),integer([MinB,MaxB]),integer([MinC,MaxC])) :-
    MinCT is MinA - MaxB, MaxCT is MaxA - MinB,
    bound_ints(MinCT,MaxCT,MinC,MaxC).

amultiplication(integer([MinA,MaxA]),integer([MinB,MaxB]),integer([MinC,MaxC])) :-
    multi_min([MinA * MinB, MaxA * MaxB, MinA * MaxB, MaxA * MinB], MinCT),
    multi_max([MinA * MinB, MaxA * MaxB, MinA * MaxB, MaxA * MinB], MaxCT),
    bound_ints(MinCT,MaxCT,MinC,MaxC).

anot_equal(E1,S1,E2,S2,Res) :-
    aequal(E1,S1,E2,S2,Res2),
    Res2 = true -> Res = false ; Res = true.

anot_member(E1,S1,E2,S2,Res) :-
    amember(E1,S1,E2,S2,Res2),
    Res2 = true -> Res = false ; Res = true.

arange(SV1,set(Value,[CurMinCard,CurMaxCard],MaxCard)) :-
    !, SV1 = set(couple(_X,Value),[SetCurMinCard,SetCurMaxCard],_SetMaxCard),
    max_cardinality(Value,MaxCard),
    CurMinCard = SetCurMinCard, CurMaxCard is min(SetCurMaxCard,MaxCard).

aset_extension([AbsVal|AbsVals],Set) :-
    aset_extension(set(AbsVal,[1,1],1),AbsVals,Set).

aset_extension(SetIn,[],SetIn).

aset_extension(SetIn,[AbsVal|AbsVals],SetOut) :-
    aunion(SetIn,set(AbsVal,[1,1],1),UpdatedSet),
    aset_extension(UpdatedSet,AbsVals,SetOut).

aset_subtraction(set(X,[CurMinCardX,CurMaxCardX],MaxCardX), set(_Y,[_CurMinCardY,CurMaxCardY],_MaxCardY),Out) :-
    CurMinCardZ is max(0,CurMinCardX - CurMaxCardY),
    Out = set(X,[CurMinCardZ,CurMaxCardX],MaxCardX).

aunion(set(X,[CurMinCardX,CurMaxCardX],MaxCardX), set(Y,[CurMinCardY,CurMaxCardY],MaxCardY),Out) :-
    lub(X,Y,Z), CurMinCardZ is max(CurMinCardX,CurMinCardY),
    % if the type did not change, maxcard still applies
    (X=Y -> MaxCardZ = MaxCardX ; MaxCardZ is MaxCardX + MaxCardY),
    CurMaxCardZ is min(MaxCardZ,CurMaxCardX + CurMaxCardY),
    Out = set(Z,[CurMinCardZ,CurMaxCardZ],MaxCardZ).

bound_by_max_int(MaxCandidate,Max) :-
    preferences:get_preference(maxint,MaxInt),
    (MaxInt < MaxCandidate -> Max = MaxInt ; Max = MaxCandidate).

bound_by_min_int(MinCandidate,Min) :-
    preferences:get_preference(minint,MinInt),
    (MinInt > MinCandidate -> Min = MinInt ; Min = MinCandidate).

bound_ints(MinC,MaxC,MinCOut,MaxCOut) :-
    bound_by_min_int(MinC,MinC2), bound_by_max_int(MinC2,MinCOut),
    bound_by_min_int(MaxC,MaxC2), bound_by_max_int(MaxC2,MaxCOut).

glb(interval_glb).

lub(lub).

lub(X,X,X).

lub(integer([CurMinA,CurMaxA]),
    integer([CurMinB,CurMaxB]),
    integer([CurMinC,CurMaxC])) :-
    CurMinC is min(CurMinA,CurMinB), CurMaxC is max(CurMaxA,CurMaxB).

map_alpha(alpha,alpha).

map_binary_operator(add,aadd).

map_binary_operator(div,adiv).

map_binary_operator(intersection,aintersection).

map_binary_operator(interval,ainterval).

map_binary_operator(minus,aminus).

map_binary_operator(multiplication,amultiplication).

map_binary_operator(set_subtraction,aset_subtraction).

map_binary_operator(union,aunion).

map_binary_test_operator(equal,aequal).

map_binary_test_operator(greater,agreater).

map_binary_test_operator(less,aless).

map_binary_test_operator(less_equal,aless_equal).

map_binary_test_operator(member,amember).

map_binary_test_operator(not_equal,anot_equal).

map_binary_test_operator(not_member,anot_member).

map_nary_operator(set_extension,aset_extension).

map_unary_operator(card,acard).

map_unary_operator(domain,adomain).

map_unary_operator(range,arange).

max_cardinality(integer([A,B]), Card) :-
    !, Card is B - A + 1.

max_cardinality(integer,Card) :-
    !, preferences:get_preference(minint,MinInt),
    preferences:get_preference(maxint,MaxInt),
    Card is MaxInt - MinInt + 1.

max_cardinality(couple(X,Y),Card) :-
    !, max_cardinality(X,CardX),
    max_cardinality(Y, CardY),
    Card is CardX * CardY.

max_cardinality(global(X),Card) :-
    b_global_set_cardinality(X,Card).

max_cardinality(boolean,2).

multi_max([A,B],Max) :- !,
    Max is max(A,B).

multi_max([H|T], Max) :-
    multi_max(T,Max2),
    Max is max(H,Max2).

multi_min([A,B],Min) :- !,
    Min is min(A,B).

multi_min([H|T], Min) :-
    multi_min(T,Min2),
    Min is min(H,Min2).