state_as_dot_graph

add_node(X,_) :- node_col(X,_,_,_),!. % already processed

add_node(sg_root,Translation) :-
    assertz(node_col(sg_root,Translation,lightblue,diamond)).

add_node(fd(X,Type),Translation) :- !,
    get_col_assoc(node,Type,Col),
    get_preference(dot_normal_node_shape,Shape),
    assertz(node_col(fd(X,Type),Translation,Col,Shape)).

add_node(int(X),Translation) :- !,
    Col = 'wheat3', %get_col_assoc(node,integer,Col),
    get_preference(dot_normal_node_shape,Shape),
    assertz(node_col(int(X),Translation,Col,Shape)).

add_node(string(X),Translation) :- !,
    Col = 'khaki1', %'lavender' 'burlywood', %get_col_assoc(node,integer,Col),
    get_preference(dot_normal_node_shape,Shape),
    assertz(node_col(string(X),Translation,Col,Shape)).

add_node(pred_true,T) :- !, assertz(node_col(pred_true,T,'OliveDrab4',ellipse)).

add_node(pred_false,T) :- !, assertz(node_col(pred_false,T,brown,ellipse)).

add_node(RecordOrPair,Translation) :- get_fields(RecordOrPair,Fields),!,
    translate_fields(Fields,Atoms),
    ajoin(['|{ ' | Atoms], RecTranslation),
    assertz(node_col(RecordOrPair,Translation,burlywood,record(RecTranslation))). % TO DO: maybe use dot record

add_node(Val,Translation) :- is_set(Val),!,
    Col = 'LightSteelBlue1', %get_col_assoc(node,integer,Col),
    get_preference(dot_normal_node_shape,Shape),
    assertz(node_col(Val,Translation,Col,Shape)).

add_node(Term,Translation) :- is_real(Term,_),!,
    Col = 'wheat2', %get_col_assoc(node,integer,Col),
    get_preference(dot_normal_node_shape,Shape),
    assertz(node_col(Term,Translation,Col,Shape)).

add_node(_Val,_Translation).

cluster(Type,Elements) :- b_global_set(Type),
    % compute all elements of global sets which are used in current state graph
    findall(Translation, (enum_global_type_limited(El,Type), node_col(El,Translation,_,_)),Elements).

clusters2dot([],_).

clusters2dot([cluster(Name,Elements)|T],Stream) :-
    string_escape(Name,EscName),
    format(Stream,'subgraph \"cluster_~w\" {node [style=filled,color=white]; label=\"~w\"; style=filled;color=lightgrey; ',[EscName,EscName]),
    cnodes2dot(Elements,Stream),
    clusters2dot(T,Stream).

cnodes2dot([],Stream) :- format(Stream,'}~n',[]).

cnodes2dot([H|T],Stream) :-
    translate:translate_params_for_dot([H],HP),
    string_escape(HP,HPE),
    format(Stream,'~w; ',[HPE]),
    cnodes2dot(T,Stream).

cur_col(node,0).

cur_col(edge,99).

default_colours(1,'#efdf84').

default_colours(2,'#bdef6b').

default_colours(3,'#5863ee').

default_colours(4,'LightSteelBlue1').

default_colours(5,gray).

default_colours(100,firebrick).

default_colours(101,sienna).

default_colours(102,'SlateBlue4').

default_colours(103,black).

edges2dot([],_).

edges2dot([(A,B,C)|T],Stream) :- /* edge from A -> C with label B */
    translate_node_value(A,AID),
    (B = abs_cn(BB,ColBB)
    -> translate_abs_cn_node(BB,ColBB,EdgeLabel)
    ; EdgeLabel = B),
    translate_node_value(C,CID),
    get_col_assoc(edge,EdgeLabel,EdgCol),
    format(Stream,'\"~w\" -> \"~w\" [label = \"~w\", color = \"~w\"];\n',
    [AID,CID,EdgeLabel,EdgCol]),
    edges2dot(T,Stream).

get_col_assoc(Domain,T,Col) :- col_association(Domain,T,Col),!.

get_col_assoc(Domain,T,Col) :- get_next_col(Domain,Col),
    assertz(col_association(Domain,T,Col)).

get_fields(rec(Fields),Fields).

get_fields((A,B),Fields) :- get_pair_fields((A,B),Fields,[]).

get_next_col(Type,Col) :- retract(cur_col(Type,N)),!, N1 is N+1,
    (default_colours(N1,Col) -> NX=N1
    ; NX = 1, default_colours(1,Col)),
    assertz(cur_col(Type,NX)).

get_next_col(_T,red).

get_pair_fields((A,B)) --> !, get_pair_fields(A), get_pair_fields(B).

get_pair_fields(A) --> [field(prj,A)].

graph2dot(Stream,G) :- reset_dot,
    (get_preference(dot_horizontal_layout,true) -> RDir='LR'; RDir='TB'),
    PSize='', %(get_preference(dot_with_page_size,true) -> PSize='page="8.5, 11",ratio=fill,size="7.5,10",' ; PSize=''),
    format(Stream,'digraph state {\n graph [~wfontsize=12]\nrankdir=~w;~n',[PSize,RDir]),
    edges2dot(G,Stream),
    nodes2dot(Stream),
    findall(cluster(Ty,El),cluster(Ty,El),T),
    clusters2dot(T,Stream),
    format(Stream,'}~n',[]).

is_set(avl_set(_)).

is_set(X) :- list_set(X).

list_set([]).

list_set([_|_]).

nodes2dot(Stream) :- node_col(_,Translation,Col,Shape),
    (Shape=record(Label)
    -> format(Stream,'\"~w\" [shape=record, label=\"~w\", color = \"~w\", style = \"filled, solid\"]\n',
    [Translation,Label,Col])
    ; format(Stream,'\"~w\" [color = \"~w\", style = \"filled, solid\", shape = \"~w\"]\n',[Translation,Col,Shape])
    ),
    fail.

nodes2dot(_).

print_cstate_graph(File) :-
    current_expression(_,State),
    print_cstate_graph(State,File).

print_cstate_graph(State,File) :-
    state_graph_for_dot(State,GCE),
    open(File,write,Stream,[encoding(utf8)]),
    (graph2dot(Stream,GCE) -> close(Stream)
    ; close(Stream),
    add_error(graph_canon,'Dot conversion failed: ',graph2dot(File,GCE))
).

reset_dot :- retractall(col_association(_,_,_)),
    retractall(node_col(_,_,_,_)),
    retractall(cur_col(_,_)),
    assertz(cur_col(node,0)), assertz(cur_col(edge,99)).

trans_field(prj,VS, [' { ', VS, ' } ' | Rest], Rest) :- !.

trans_field(Name,VS, [' { ',Name,' | ', VS, ' } ' | Rest], Rest).

translate_abs_cn_node(AA,ColAA,Translation) :-
    tools:string_concatenate('_',AA,AID1),
    tools:string_concatenate(ColAA,AID1,AID2),
    tools:string_concatenate('abs',AID2,Translation).

translate_fields([],[' }|']).

translate_fields([field(Name,Value)],Res) :- !,
    trans_field(Name,VS,Res,[' }|']),
    translate_bvalue_for_dot(Value,VS).

translate_fields([field(Name,Value)|T],Res) :-
    trans_field(Name,VS,Res,['|' | Rest]),
    translate_bvalue_for_dot(Value,VS),
    translate_fields(T,Rest).

translate_node_value(abs_cn(AA,ColAA), Translation) :- !,
    translate_abs_cn_node(AA,ColAA,Translation).

translate_node_value(sg_root,Translation) :- !,
    Translation = 'ROOT-NODE', add_node(sg_root,Translation).

translate_node_value(Val,Translation) :-
    translate_bvalue_for_dot(Val,Translation),
    add_node(Val,Translation).