eventhandling

announce_event(Event) :- %print(announce(Event)),nl,
    ( known_events(Event,_) ->
    announce_event2(Event)
    ;
    add_internal_error('Unknown event',announce_event(Event))).

announce_event2(Event) :-
    check_lifecycle(Event),
    findall(Predicate, registered_listener(Event,Predicate,_Desc), Calls),
    maplist(call_for_event(Event), Calls)
. %, format('Finished processing ~w~n',[Event]).

call_for_event(Event,Predicate) :-
    % format('Event ~w --triggered--> ~w~n',[Event,Predicate]),
    ( call(Predicate) -> true
    ;
    ajoin(['Call for event ',Event,' failed.'],Msg),
    add_internal_error(Msg,Predicate)).

check_lifecycle(Event) :- last_event(X), %nl,print(event(Event,last(X))),nl,
    !,
    (missing_transition(X,Event) -> true ; true),
    retractall(last_event(_)),
    assertz(last_event(Event)).

check_lifecycle(Event) :- add_internal_error('No last event for ',check_lifecycle(Event)),
    assertz(last_event(Event)).

known_events(compile_prob,'ProB is being compiled').

known_events(startup_prob,'ProB is starting up').

known_events(clear_specification,'After we have finished with a specification').

known_events(reset_specification,'Resetting animator, without changing specification').

known_events(start_initialising_specification,'We start loading a (new) specification').

known_events(specification_initialised,'Directly after the specificiation has been loaded').

known_events(reset_prob,'Resetting probcli (preferences, ... back to defaults), requires clear_specification before').

known_events(change_of_animation_mode,'Changing Animation Mode (e.g., adding CSP guide)').

known_events(start_solving,'Begin solving a new predicate').

known_events(end_solving,'End of solving a predicate').

known_events(play_counterexample,'Getting counterexample from cache').

known_events(start_unit_tests,'Starting ProB Unit Tests').

known_events(stop_unit_tests,'Stop ProB Unit Tests').

last_event(none).

missing_transition(specification_initialised,start_initialising_specification) :-
    add_warning(event_handling,'Missing event after specification_initialised: ',clear_specification).

missing_transition(clear_specification,specification_initialised) :-
    add_warning(event_handling,'Missing event after clear_specification: ',start_initialising_specification).

missing_transition(specification_initialised,specification_initialised) :-
    add_warning(event_handling,'Previous specification not cleared').

missing_transition(start_initialising_specification,start_initialising_specification) :-
    add_warning(event_handling,'Double Start of Specification Initialisation').

missing_transition(Prev,reset_prob) :- Prev \= clear_specification,
    add_warning(event_handling,'Missing event before reset_prob: ',clear_specification).

register_event_listener(Event,Pred,Description) :- %print(register(Event,Module)),nl,
    ( known_events(Event,_) ->
    register_event_listener2(Event,Pred,Description)
    ;
    print(unknown(Event)),nl,
    format('~n!!! Unknown event ~w (from ~w) : ~w~n~n',[Event,Pred,Description])
%add_internal_error('Unknown event',register_event_listener(Event,Pred,Description))
).

register_event_listener2(Event,Pred,Description) :-
    (registered_listener(Event,Pred,Description) -> true
    ; assertz(registered_listener(Event,Pred,Description))).

store_virtual_event(Event) :-
    ( known_events(Event,_) ->
    check_lifecycle(Event)
    ;
    add_internal_error('Unknown event',announce_event(Event))).