ground_truth

contains_record_type(b(_,Type,_)) :-
    contains_record_type_aux(Type).

contains_record_type_aux(field(_,_)) :-
    !.

contains_record_type_aux(record(_)) :-
    !.

contains_record_type_aux(Type) :-
    Type =.. [_|T],
    member(Arg, T),
    contains_record_type_aux(Arg).

current_machine_uses_records :-
    b_get_machine_variables(MachineVars),
    current_machine_uses_records_aux(MachineVars).

current_machine_uses_records :-
    b_get_machine_constants(MachineConstants),
    current_machine_uses_records_aux(MachineConstants).

current_machine_uses_records_aux(Vars) :-
    member(Var, Vars),
    contains_record_type(Var).

explicit_component_not_collected_yet(Ast) :-
    remove_all_infos(Ast, CleanAst),
    \+ explicit_collected_component(CleanAst),
    assertz(explicit_collected_component(CleanAst)).

extend_ground_truth(_, Amount, Acc, Acc) :-
    Amount =< 0,
    !.

extend_ground_truth(Component, Amount, Old, New) :-
    extend_ground_truth(Component, Old, Acc),
    Amount1 is Amount-1,
    extend_ground_truth(Component, Amount1, Acc, New),
    !.

extend_ground_truth(Component, Old, New) :-
    avl_member(Component, Old),
    !,
    avl_incr(Component, Old, 1, New).

extend_ground_truth(Component, Old, Old) :-
    assertz(missing_component(Component)).

extend_ground_truth_for_vars(ExcludeVars, VarNames, Components, Acc, New) :-
    group_atom_list(Components, GroupedComponents),
    extend_ground_truth_for_vars_aux1(ExcludeVars, VarNames, GroupedComponents, Acc, New),
    !.

extend_ground_truth_for_vars_aux1(_, [], _, Acc, Acc).

extend_ground_truth_for_vars_aux1(ExcludeVars, [VarName|T], GroupedComponents, Acc, New) :-
    extend_ground_truth_for_vars_aux2(ExcludeVars, VarName, GroupedComponents, Acc, TempNewAcc),
    extend_ground_truth_for_vars_aux1(ExcludeVars, T, GroupedComponents, TempNewAcc, New).

extend_ground_truth_for_vars_aux2(_, VarName, GroupedComponents, Acc, [(VarName,NewVarNameAcc)|TempAcc]) :-
    select((VarName,VarNameAcc), Acc, TempAcc),
    !,
    extend_ground_truth_for_vars_aux3(GroupedComponents, VarNameAcc, NewVarNameAcc).

extend_ground_truth_for_vars_aux2(ExcludeVars, VarName, GroupedComponents, Acc, [(VarName,NewVarNameAcc)|Acc]) :-
    b_get_machine_variables(MachineVars),
    \+ member(b(identifier(VarName),_,_), MachineVars),
    \+ member(b(identifier(VarName),_,_), ExcludeVars),
    % parameter ids have been added to the accumulator beforehand
    % any missing id at this point that is no operation return variable has been introduced by a let or any
    % we collect the components used for those ids as well as parameters to insert them later on in case an id is used
    get_empty_ground_truth(EmptyGt),
    extend_ground_truth_for_vars_aux3(GroupedComponents, EmptyGt, NewVarNameAcc).

extend_ground_truth_for_vars_aux2(_, _, _, Acc, Acc).

extend_ground_truth_for_vars_aux3([], VarNameAcc, VarNameAcc).

extend_ground_truth_for_vars_aux3([(Component,Amount)|T], VarNameAcc, NewVarNameAcc) :-
    extend_ground_truth(Component, Amount, VarNameAcc, TempVarNameAcc),
    extend_ground_truth_for_vars_aux3(T, TempVarNameAcc, NewVarNameAcc).

filter_used_components([], Acc, Acc).

filter_used_components([Component-Amount|T], Acc, UsedComponentsList) :-
    Amount \== 0,
    !,
    filter_used_components(T, [(Component,Amount)|Acc], UsedComponentsList).

filter_used_components([_|T], Acc, UsedComponentsList) :-
    filter_used_components(T, Acc, UsedComponentsList).

get_constant_component(b(integer_set('INT'),_,_), int_set).

get_constant_component(b(integer_set('INTEGER'),_,_), integer_set).

get_constant_component(b(integer_set('NAT'),_,_), nat_set).

get_constant_component(b(integer_set('NAT1'),_,_), nat1_set).

get_constant_component(b(integer_set('NATURAL'),_,_), natural_set).

get_constant_component(b(integer_set('NATURAL1'),_,_), natural1_set).

get_constant_component(b(bool_set,_,_), constant_set).

get_constant_component(b(boolean_true,boolean,_), constant_boolean).

get_constant_component(b(boolean_false,boolean,_), constant_boolean).

get_constant_component(b(integer(_),integer,_), constant_integer).

get_constant_component(b(string(_),string,_), constant_string).

get_constant_component(b(couple(_,_),couple(_,_),_), constant_couple).

get_constant_component(b(value(_),Type,_), ConstantComponent) :-
    functor(Type, TopLevelType, _),
    atom_concat(constant_, TopLevelType, ConstantComponent).

get_constant_component(b(record_field(_,_),_,_), constant_recordfield).

get_constant_component(b(empty_set,_,_), constant_set).

get_constant_component(b(set_extension(_),_,_), constant_set).

get_constant_component(b(rec(_),_,_), constant_record).

get_constant_component(b(Node,_,_), constant_set) :- % was: constant_seq
    ( Node == empty_seq
    ; Node == empty_sequence
).

get_constant_component(b(sequence_extension(_),_,_), constant_set). % was: constant_seq

get_empty_ground_truth(GroundTruth) :-
    findall(CC, ( ground_truth_component(C),
    CC = C-0
    ), Components),
    list_to_avl(Components, GroundTruth).

get_empty_ground_truth_for_vars(MachineVars, GroundTruth) :-
    findall((VarName,EmptyGt), ( member(b(identifier(VarName),_,_), MachineVars),
    get_empty_ground_truth(EmptyGt)
    ), GroundTruth).

get_ground_truth_from_operation_body(OpReturnVars, OperationBody, ParameterIds, UsedComponents) :-
    b_get_machine_variables(MachineVars),
    append(MachineVars, ParameterIds, Vars),
    get_empty_ground_truth_for_vars([b(identifier(global_ground_truth_vars),_,_),b(identifier(global_ground_truth_params),_,_)|Vars], Acc),
    retractall(operation_parameter(_)),
    retractall(explicit_collected_component(_)),
    forall(member(b(identifier(Name),_,_), ParameterIds),
    ( \+ operation_parameter(Name),
    assertz(operation_parameter(Name))
    )),
    get_library_components_from_op_ast_state(OpReturnVars, [], none, [OperationBody], _, Acc, TempUsedComponents, AssignedIds),
    !,
    % some Ids may appear in the precondition but are not assigned in the substitution, thus, missing a skip component
    find_identifier_uses(OperationBody, [], UsedIds),
    subtract(UsedIds, AssignedIds, NotAssignedIds),
    extend_ground_truth_for_vars([], NotAssignedIds, [skip], TempUsedComponents, UsedComponentsAvlList),
   
    ( Acc == UsedComponentsAvlList
    ->
    add_warning(get_ground_truth_from_operation_body, 'Empty ground truth of B components for operation/event:', [OperationBody]),
    fail
    ; post_process_operations_ground_truth(UsedComponentsAvlList, UsedComponents)
).

get_library_components_for_params_from_pred(b(Node,_,_), Acc, UsedComponents) :-
    split_conjunct_or_disjunct(Node, Functor, Lhs, Rhs),
    !,
    find_identifier_uses(Lhs, [], UsedIdsLhs),
    find_identifier_uses(Rhs, [], UsedIdsRhs),
    get_parameter_ids_from_list(UsedIdsLhs, ParamIdsLhs),
    get_parameter_ids_from_list(UsedIdsRhs, ParamIdsRhs),
    ( ParamIdsLhs \== [] ->
    get_library_components_for_params_from_pred(Lhs, Acc, NewAcc1)
    ; NewAcc1 = Acc
    ),
    ( ParamIdsRhs \== [] ->
    get_library_components_for_params_from_pred(Rhs, NewAcc1, NewAcc2)
    ; NewAcc2 = NewAcc1
    ),
    ( ( ParamIdsLhs \== [],
    ParamIdsRhs \== []
    )
    ->
    extend_ground_truth_for_vars([], [global_ground_truth_params], [Functor], NewAcc2, UsedComponents)
    ; UsedComponents = NewAcc2
    ),
    !.

get_library_components_for_params_from_pred(b(equal(b(identifier(Name),_,_),Rhs),_,_), Acc, UsedComponents) :-
    % like p = x + 1 and we only want to collect equal and add for p but not for x
    operation_parameter(Name),
    get_library_components_from_op_ast_state([], [equal], none, [Rhs], CarryComponentsAcc, Acc, _, _),
    !,
    extend_ground_truth_for_vars([], [Name], CarryComponentsAcc, Acc, UsedComponents).

get_library_components_for_params_from_pred(b(Node,_,_), Acc, UsedComponents) :-
    Node =.. [Functor|Args],
    ground_truth_component(Functor),
    find_identifier_uses(b(Node,_,_), [], UsedIds),
    findall(Id, ( member(Id, UsedIds),
    operation_parameter(Id)
    ), ParamIds),
    ParamIds \== [],
    get_library_components_from_op_ast_state([], [], none, Args, CarryComponents, Acc, _, _),
    !,
    extend_ground_truth_for_vars([], [global_ground_truth_params], [Functor|CarryComponents], Acc, UsedComponents).

get_library_components_for_params_from_pred(_, Acc, Acc).

get_library_components_from_assignments(_, _, [], [], Acc, Acc, []).

get_library_components_from_assignments(ExcludeVars, CarryComponents, [Id|TId], [Assignment|TA], Acc, UsedComponents, [AssignedId|AssignedVars]) :-
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, none, [b(assign_single_id(Id,Assignment),subst,[])], _, Acc, NewAcc1, AssignedIds),
    AssignedIds = [AssignedId],
    get_library_components_from_assignments(ExcludeVars, CarryComponents, TId, TA, NewAcc1, UsedComponents, AssignedVars).

get_library_components_from_op_ast(ExcludeVars, CarryComponents, AssigningVar, In, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    retractall(operation_parameter(_)),
    retractall(explicit_collected_component(_)),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, In, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds).

get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, In, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    wrap_list_if_flat(In, NIn),
    get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, NIn, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds).

get_library_components_from_op_ast_state_l(_, CarryComponents, _, [], CarryComponents, Acc, NewAcc, AssignedIds) :-
    !,
    NewAcc = Acc,
    AssignedIds = [].

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [Ast|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    Ast = b(rlevent(_Name,_Section,_Status,_Params,Guard,_Theorems,Actions,_VWitnesses,_PWitnesses,_Unmod,_AbstractEvents),_,_),
    !,
    get_library_components_for_params_from_pred(Guard, Acc, NewAcc1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, Actions, _, NewAcc1, NewAcc2, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(Substitution,_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    Substitution =.. [Functor,Assignments],
    ( Functor = parallel
    ; Functor = sequence
    ),
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, Assignments, _, Acc, NewAcc, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(Node,_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    Node =.. [Functor,_Ids,Pred,Substitutions],
    ( Functor = let
    ; Functor = any
    ),
    !,
    get_library_components_for_params_from_pred(Pred, Acc, NewAcc1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, Substitutions, CarryComponentsAcc, NewAcc1, NewAcc2, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponentsAcc, AssigningVar, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(precondition(Pred,Substitution),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_for_params_from_pred(Pred, Acc, NewAcc1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, [Substitution], _, NewAcc1, NewAcc2, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(select([Substitution1],Substitution),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, [Substitution,Substitution1], _, Acc, NewAcc, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(select(Substitutions),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, Substitutions, CarryComponentsAcc, Acc, NewAcc, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponentsAcc, AssigningVar, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(select_when(Pred,Substitution),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_for_params_from_pred(Pred, Acc, NewAcc1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, [Substitution], CarryComponentsAcc, NewAcc1, NewAcc2, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponentsAcc, AssigningVar, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(if_then_else(Pred,If,Else),subst,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, [Pred], CarryComponentsAccPred, Acc, _, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, [if_then_else|CarryComponentsAccPred], AssigningVar, [If,Else], CarryComponentsAcc, Acc, NewAcc1, AssignedIds2),
    extend_ground_truth_for_vars(ExcludeVars, [global_ground_truth_vars], [if_then_else|CarryComponentsAccPred], NewAcc1, NewAcc2),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponentsAcc, AssigningVar, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds3),
    append([AssignedIds1,AssignedIds2,AssignedIds3], AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(if_then_else(Pred,If,Else),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    % if_then_else expression
    get_library_components_from_op_ast_state(ExcludeVars, [if_then_else|CarryComponents], AssigningVar, [Pred,If,Else], CarryComponentsAcc, Acc, NewAcc, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponentsAcc, AssigningVar, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(if(SubstitutionList),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    extend_ground_truth_for_vars(ExcludeVars, [global_ground_truth_vars], [if_then_else], Acc, NewAcc1),
    get_library_components_from_op_ast_state(ExcludeVars, [if_then_else|CarryComponents], AssigningVar, SubstitutionList, _, NewAcc1, NewAcc2, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(if_elsif(Condition,Substitution),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_from_op_ast_state(ExcludeVars, [], AssigningVar, [Condition], CarryComponentsAccPred, Acc, _, AssignedIds1),
    extend_ground_truth_for_vars(ExcludeVars, [global_ground_truth_vars], [if_then_else|CarryComponentsAccPred], Acc, NewAcc1),
    get_library_components_from_op_ast_state(ExcludeVars, [if_then_else|CarryComponentsAccPred], AssigningVar, [Substitution], _, NewAcc1, NewAcc2, AssignedIds2),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds3),
    append([AssignedIds1,AssignedIds2,AssignedIds3], AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(assign(Ids,Assignments),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_from_assignments(ExcludeVars, CarryComponents, Ids, Assignments, Acc, NewAcc1, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc1, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(identifier(_Name),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(skip,subst,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    !,
    b_get_machine_variables(MachineVars),
    findall(N, member(b(identifier(N),_,_), MachineVars), MachineVarNames),
    extend_ground_truth_for_vars(ExcludeVars, MachineVarNames, [skip|CarryComponents], Acc, NewAcc),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds1),
    append(MachineVarNames, AssignedIds1, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, none, [b(assign_single_id(b(identifier(Name),_,_),b(identifier(Name),_,_)),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, [Name|AssignedIds]) :-
    !,
    extend_ground_truth_for_vars(ExcludeVars, [Name], [skip|CarryComponents], Acc, NewAcc),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, none, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, none, [b(assign_single_id(b(identifier(Name),_,_),_),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, [Name|AssignedIds]) :-
    % exclude assignments of operation return values
    member(b(identifier(Name),_,_), ExcludeVars),
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, none, T, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, none, [b(assign_single_id(b(identifier(Name),_,_),Arg),_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, [Name|AssignedIds]) :-
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, none, [Arg], CarryComponentsAcc, Acc, NewAcc1, AssignedIds1),
    extend_ground_truth_for_vars(ExcludeVars, [Name], CarryComponentsAcc, NewAcc1, NewAcc2),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, none, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, none, [b(Node,_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    % treat becomes_element_of and becomes_such like assignments when collecting components since the semantics do not matter here
    Node =.. [Functor,Ids,Arg],
    ( Functor == becomes_element_of
    ; Functor == becomes_such
    ),
    !,
    findall(Name, member(b(identifier(Name),_,_), Ids), IdNames),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, none, [Arg], CarryComponentsAcc, Acc, NewAcc1, AssignedIds1),
    extend_ground_truth_for_vars(ExcludeVars, IdNames, [Functor|CarryComponentsAcc], NewAcc1, NewAcc2),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, none, T, NewCarryComponentsAcc, NewAcc2, UsedComponents, AssignedIds2),
    append([IdNames, AssignedIds1, AssignedIds2], AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [Constant|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    get_constant_component(Constant, ConstantComponent),
    !,
    % do not duplicate constant components for the same constant value
    ( explicit_component_not_collected_yet(Constant) ->
    CarryComponents2 = [ConstantComponent|CarryComponents]
    ; CarryComponents2 = CarryComponents
    ),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents2, AssigningVar, T, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(Node,_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    Node =.. [Component|Args],
    \+ member(Component, [assign_single_id,assign,choice]),
    explicit_component_not_collected_yet(b(Node,_,_)),
    !,
    get_library_components_from_op_ast_state_l(ExcludeVars, [Component|CarryComponents], AssigningVar, Args, CarryComponentsAcc, Acc, NewAcc, AssignedIds),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponentsAcc, AssigningVar, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [List|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    is_list(List),
    !,
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, List, CarryComponentsAcc, Acc, NewAcc, AssignedIds1),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponentsAcc, AssigningVar, T, NewCarryComponentsAcc, NewAcc, UsedComponents, AssignedIds2),
    append(AssignedIds1, AssignedIds2, AssignedIds).

get_library_components_from_op_ast_state_l(ExcludeVars, CarryComponents, AssigningVar, [b(Node,_,_)|T], NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds) :-
    ( skip_record_for_operator(Node) ->
    !,
    fail
    ; true
    ),
    functor(Node, Functor, _),
    ( \+ explicit_component_not_collected_yet(b(Node,_,_)) ->
    true
    ; add_warning(get_library_components_from_op_ast, 'Warning: Skipped component with functor:', [Functor,Node])
    ),
    get_library_components_from_op_ast_state(ExcludeVars, CarryComponents, AssigningVar, T, NewCarryComponentsAcc, Acc, UsedComponents, AssignedIds).

get_library_components_from_pred_or_expr(Ast, UsedComponentsList) :-
    % if no assignment is made in Ast, the CarryComponents are the UsedComponents
    get_empty_ground_truth(EmptyGt),
    get_library_components_from_op_ast([], [], none, Ast, CarryComponents, [], _, _),
    extend_ground_truth_for_vars([], [global], CarryComponents, [(global,EmptyGt)], UsedComponents),
    member((global,GroundTruth), UsedComponents),
    avl_to_list(GroundTruth, TempUsedComponentsList),
    filter_used_components(TempUsedComponentsList, [], UsedComponentsList).

get_missing_components(MissingComponents) :-
    findall(C, missing_component(C), MissingComponents).

get_parameter_ids_from_list([], []).

get_parameter_ids_from_list([ID|T], [ID|NT]) :-
    operation_parameter(ID),
    !,
    get_parameter_ids_from_list(T, NT).

get_parameter_ids_from_list([_|T], NT) :-
    get_parameter_ids_from_list(T, NT).

ground_truth_component(C) :-
    b_component(C).

ground_truth_component(constant_set).

ground_truth_component(constant_couple).

ground_truth_component(constant_boolean).

ground_truth_component(constant_integer).

ground_truth_component(constant_string).

ground_truth_component(constant_recordfield).

ground_truth_component(constant_record).

group_atom_list([], []).

group_atom_list([X], [(X,1)]).

group_atom_list([X|T], [(X,N1)|Compressed]) :-
    findall(X, member(X, T), LX),
    length(LX, N),
    N1 is N+1,
    subtract(T, [X], NewT),
    group_atom_list(NewT, Compressed).

post_process_operations_ground_truth([], []).

post_process_operations_ground_truth([(VarName, GtAvl)|T], [(VarName, CleanGt)|NT]) :-
    avl_to_list(GtAvl, GtList),
    filter_used_components(GtList, [], CleanGt),
    post_process_operations_ground_truth(T, NT).

skip_record_for_operator(assign_single_id(b(function(_,_),_,_),_)).

skip_record_for_operator(choice(_)).

split_conjunct_or_disjunct(conjunct(Lhs, Rhs), conjunct, Lhs, Rhs).

split_conjunct_or_disjunct(disjunct(Lhs, Rhs), disjunct, Lhs, Rhs).

wrap_list_if_flat(H, H) :-
    is_list(H),
    !.

wrap_list_if_flat(H, [H]).