fuzzfile

deescape(95,95). % underscore

get_z_definitions(Defs) :-
    current_fuzzfile(_,Defs).

idcontent(String) --> [C], idcontent2(C, String).

idcontent2(34, []) --> !. % closing quotation mark

idcontent2(92, [D|String]) --> % backslash
    [C],{deescape(C,D)},!,idcontent(String).

idcontent2(C, [C|String]) --> idcontent(String).

identifier(Id) --> [34], idcontent(String), {atom_codes(Id,String)}.

itemname(N) --> letter(L), itemname2(Rest), {atom_codes(N,[L|Rest])}.

itemname2([L|Rest]) --> alphanum(L), !, itemname2(Rest).

itemname2([]) --> [].

load_fuzzfile(File) :-
    reset_fuzzfile,
   
    (readfile(File,Content) -> true;
    add_error(fuzzfile,'Error while reading file', File),fail),
   
    (zparser(Defs,Content,[]) -> true;
    add_error(fuzzfile,'Error while parsing fuzz file', File), fail),
   
    assertz(current_fuzzfile(File,Defs)).

parsenumber(Number) --> digit(D), parsenumber2(Rest), {number_codes(Number,[D|Rest])}.

parsenumber2([D|Rest]) --> digit(D),!,parsenumber2(Rest).

parsenumber2([]) --> [].

precompiled_rule(Rule) :-
    member(L,"abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"),
    member(Rule,[letter(L,[L|R],R),alphanum(L,[L|T],T)]).

precompiled_rule(Rule) :-
    member(D,"0123456789"),
    member(Rule,[digit(D,[D|R],R),alphanum(D,[D|T],T)]).

precompiled_rule(whitespace([W|T],T)) :-
    member(W," \t\n\r").

precompiled_rule(to_lower_char(Upper,Lower)) :-
    nth0(N,"ABCDEFGHIJKLMNOPQRSTUVWXYZ",Upper),
    nth0(N,"abcdefghijklmnopqrstuvwxyz",Lower).

readbytes(Stream,Res) :-
    get_code(Stream,C),
    (C= -1 -> Res=[] ; Res=[C|Rest],readbytes(Stream,Rest)).

readfile(Filename,Content) :-
    open(Filename,read,Stream),
    readbytes(Stream,Content),
    close(Stream).

reset_fuzzfile :- retractall(current_fuzzfile(_,_)).

store_rules :-
    precompiled_rule(R),
    assertz(R),
    fail.

store_rules.

string(Atom) --> [34], stringcontent(String), [34], {atom_codes(Atom,String)}.

stringcontent([C|Rest]) --> [C], {C \= 34}, !, stringcontent(Rest).

stringcontent([]) --> [].

to_lower(Nr,R) :- number(Nr),!,R=Nr.

to_lower(UItem,LItem) :- atom_codes(UItem,Up),to_lower2(Up,Low),atom_codes(LItem,Low).

to_lower2([],[]).

to_lower2([Up|URest],[Low|LRest]) :-
    (to_lower_char(Up,Low) -> true ; Up = Low),
    to_lower2(URest,LRest).

wss --> whitespace, !, wss.

wss --> "".

zitem(Item) --> "(", !, zitem2(Item).

zitem(String) --> identifier(String).

zitem2([]) --> ")",!.

zitem2(Item) --> itemname(IName), wss, zitem3(IName,Item), wss, ")",!.

zitem3('LIST',List) --> !,zparser(List).

zitem3('NAME',name(Name,Deco)) --> !, identifier(Name), wss, string(Deco).

zitem3('REF',ref(Name,Params)) --> !,
    parsenumber(_), wss, zitem(Name), wss, zitem(Params).

zitem3('SREF',sref(Name,Deco,Params,Renamings)) --> !,
    parsenumber(_), wss, identifier(Name), wss, string(Deco),
    wss, zitem(Params), wss, zitem(Renamings).

zitem3('NUMBER',number(N)) --> !,
    parsenumber(_), wss, [34], parsenumber(N), [34].

zitem3(IName,Item) --> parsenumber(_), zparser(Items),
    {to_lower(IName,LIName), Item =.. [LIName | Items]}.

zparser(Items) --> wss, zparser2(Items).

zparser2([I|Rest]) --> zitem(I), !, zparser(Rest).

zparser2([]) --> [].