prologTasks

get_category_name(feasibility,'Feasibility Analysis').

get_category_name(enabling(_),'Enabling Analysis').

get_category_name(cbc_tests(_,_,_,_,_),'CBC Testcase Generation').

get_task_info(cbc_tests(_,_,_,_,_),Nr,Info) :-
    N1 is Nr+1,
    get_counter_info(N1,Paths,Tests,Timeouts),
    cbc_get_nr_uncovered_events(Unc),
    ajoin(['Uncovered: ',Unc, ', Paths: ',Paths,', Tests: ',Tests,', Timeouts: ',Timeouts],Info).

get_task_steps(feasibility,PrologCode,Msg) :-
    b_top_level_operation(OpName),
    operation_name_not_yet_covered(OpName),
    \+ feasible_operation_cache(OpName,_), % not yet computed
    PrologCode = enabling_analysis:feasible_operation(OpName,_), % will compute the cache
    ajoin(['feasibility of ',OpName],Msg).

get_task_steps(enabling(ExtraTimeOut),PrologCode,Msg) :- %print(get_task(ExtraTimeOut)),nl,
    init_or_op(OpName), %print(op(OpName)),nl,
    \+ cbc_enable_analysis_cache(OpName,_,_,ExtraTimeOut), % not yet computed
    PrologCode = findall(1,enabling_analysis:cbc_enable_analysis(OpName,_,_,ExtraTimeOut),_),
    ajoin(['enabling of ',OpName],Msg).

get_task_steps(cbc_tests(EventSel,TargetPredicateStr,MaxLength,Filename,Final),PrologCode,Msg) :-
    cbc_gen_test_cases_task_step(EventSel,TargetPredicateStr,MaxLength,Filename, Final, Depth, PrologCode),
    ajoin(['cbc_tests for depth ',Depth],Msg).

prologTaskAbort(Category) :- retract(task_step(Category,_PrologCode,Msg)),
    %add_internal_error('Pending task: ',task_step(Category,PrologCode,Msg)),
    print(aborting(Msg)),nl,
    fail.

prologTaskAbort(_).

prologTaskFinish(cbc_tests(_EventSel,_TargetPredicateStr,_MaxLength,_Filename,_Final)) :- !,
    sap:cbc_gen_test_cases_finish_tasks.

prologTaskFinish(_).

prologTaskStart(test,'Test Task',1000) :- !.

prologTaskStart(Category,CatMsg,Length) :-
    get_category_name(Category,CatMsg),
    retractall(task_step(Category,_,_)),
    % collect all task steps:
    findall(task_step(Category,Prolog,Msg),get_task_steps(Category,Prolog,Msg),Tasks),
    %print(task_steps(Category,Tasks)),nl,
    length(Tasks,Length),
    maplist(assertz,Tasks),nl.

prologTaskStep(test,Nr,NewMsg) :- !,
    ajoin(['Running ', Nr],NewMsg).

prologTaskStep(Category,Nr,NewMsg) :- %print(step(Nr)),nl,
    retract(task_step(Category,PrologCode,Msg)),
    % print(calling(PrologCode)),nl,
    statistics(walltime,[Start,_]),
    call(PrologCode),
    statistics(walltime,[Stop,_]),
    T is Stop-Start,
    % print(done(Msg)),nl,
    (get_task_info(Category,Nr,Info)
    -> ajoin(['Step ', Nr, ': ', Msg, ' [', Info, '] (', T, ' ms)'],NewMsg)
    ; ajoin(['Step ', Nr, ': ', Msg, ' (', T, ' ms)'],NewMsg)
).