dependence

check_abbreviations([],D,D) :- !.

check_abbreviations([eqeq(lhs(name(Id,''),_),Body)|Rest],Deps,Result) :-
    member(dep(_,Id),Deps),
    !,
    schemadeps(Id,Body,Deps1),
    append(Deps,Deps1,NewDeps),
    check_abbreviations(Rest,NewDeps,Result).

check_abbreviations([_|Rest],Deps,Result) :- check_abbreviations(Rest,Deps,Result).

extract_schemas([],[],[]) :- !.

extract_schemas([sdef(shead(Name,_),Body)|Rest], [Name|NRest],[Body|BRest]) :-
    !,extract_schemas(Rest,NRest,BRest).

extract_schemas([defeq(shead(Name,_),Body)|Rest], [Name|NRest],[Body|BRest]) :-
    !,extract_schemas(Rest,NRest,BRest).

extract_schemas([_|Rest],NRest,BRest) :- extract_schemas(Rest,NRest,BRest).

schema_dependence(Def,Dependencies) :-
    extract_schemas(Def,Names,Bodies),
    schema_dependence2(Names,Bodies,Dependencies1),
    check_abbreviations(Def,Dependencies1,Dependencies).

schema_dependence2([],_,[]).

schema_dependence2([Id|NRest],[Body|BRest],Deps) :-
    schemadeps(Id,Body,Deps1),
    append(Deps1,Deps2,Deps),
    schema_dependence2(NRest,BRest,Deps2).

schemadeps(Id,Body,Deps) :-
    sdep(Body,LDeps),
    findall(dep(Id,D),member(D,LDeps),Deps).

sdep([],[]).

sdep([S|Rest],Deps) :-
    sdep(S,Deps1),
    sdep(Rest,Deps2),
    append_not_duplicate(Deps1,Deps2,Deps).

sdep(sref(Id,_,_,_),[Id]).

sdep(sand(A,B),Deps) :- sdep([A,B],Deps).

sdep(sor(A,B),Deps) :- sdep([A,B],Deps).

sdep(simplies(A,B),Deps) :- sdep([A,B],Deps).

sdep(sequiv(A,B),Deps) :- sdep([A,B],Deps).

sdep(snot(A),Deps) :- sdep(A,Deps).

sdep(fatsemi(A,B),Deps) :- sdep([A,B],Deps).

sdep(sforall(A,B),Deps) :- sdep([A,B],Deps).

sdep(sexists(A,B),Deps) :- sdep([A,B],Deps).

sdep(sexists1(A,B),Deps) :- sdep([A,B],Deps).

sdep(hide(S,_),Deps) :- sdep(S,Deps).

sdep(project(A,B),Deps) :- sdep([A,B],Deps).

sdep(pre(S),Deps) :- sdep(S,Deps).

sdep(pipe(A,B),Deps) :- sdep([A,B],Deps).

sdep(body(Decls,_),Deps) :- sdep(Decls,Deps).

sdep(text(S),Deps) :- sdep(S,Deps).

sdep(decl(_,_),[]).

sdep(sdecl(S),Deps) :- sdep(S,Deps).