assert_profiler

add_assert_time_tracking((H :- Body),(H :- Body2)) :- add_timer_body(Body,Body2).

add_module(M:P,_,R) :- !, R=M:P.

add_module(P,M,M:P).

add_timer_body(A,B) :- var(A),!, A=B.

add_timer_body((A , B),(A2 , B2)) :- !, add_timer_body(A,A2), add_timer_body(B,B2).

add_timer_body((A ; B),(A2 ; B2)) :- !, add_timer_body(A,A2), add_timer_body(B,B2).

add_timer_body((A -> B),(A2 -> B2)) :- !, add_timer_body(A,A2), add_timer_body(B,B2).

add_timer_body(\+(A),\+(A2)) :- !, add_timer_body(A,A2).

add_timer_body(when(G,A),when(G,A2)) :- !, add_timer_body(A,A2).

add_timer_body(A,timer:timer_det_call(F,A2)) :-
    is_assert(A,T,MT,A2),
    nonvar(T),
    my_functor(T,F,N), !,
    get_prolog_module(Module),
    add_module(T,Module,MT),
    print(assert(F,N,Module,A,A2)),nl.

add_timer_body(A,timer:timer_call(F,A2)) :-
    is_retract(A,T,MT,A2),
    nonvar(T),
    my_functor(T,F,N), !,
    get_prolog_module(Module),
    add_module(T,Module,MT),
    print(retract(F,N,Module,A,A2)),nl.

add_timer_body(B,B).

get_prolog_module(Module) :- (prolog_load_context(module,Module) -> true ; Module=user).

is_assert(assert(T),T,MT,assert(MT)).

is_assert(asserta(T),T,MT,asserta(MT)).

is_assert(assertz(T),T,MT,assertz(MT)).

is_retract(retract(T),T,MT,retract(MT)).

my_functor(V,F,N) :- var(V),!,F='VAR',N=0.

my_functor(_:P,F,N) :- !, my_functor(P,F,N).

my_functor(':-'(_,_),':-'(_,_),_) :- !, fail. %my_functor(H,F,N), my_functor(B,F2,_).

my_functor(P,F,N) :- functor(P,F,N).

ts :- timer:timer_statistics.