b_abstract_interpreter_helpers

absint_build_initial_state(BTypeList,InitialState) :-
    absint_build_initial_state2(BTypeList, UnsortedInitialState),
    samsort(UnsortedInitialState,InitialState).

absint_build_initial_state2([],[]) :- !.

absint_build_initial_state2([b(identifier(Name),Type,Args)|T],[bind(Name,InternalType)|StateT]) :-
    call_alpha(Type,Type,Args,InternalType), !,
    absint_build_initial_state(T,StateT).

absint_get_results([],OutState,[],OutState).

absint_get_results([R|Results],OutState,[NRV|ResultValues],NewOutState) :-
    def_get_texpr_id(R,ResultId),
    selectchk(bind(ResultId,NRV),OutState,OutState2),
    absint_get_results(Results,OutState2,ResultValues,NewOutState).

absint_set_up_localstate(Parameters,ParaValues,LocalState) :-
    absint_build_initial_state(Parameters,LocalState),
    findall(Val, member(bind(_Id,Val),LocalState), ParaValues).

absint_set_up_undefined_localstate([],S,S).

absint_set_up_undefined_localstate([Var|T],InS,[bind(Id,_)|OutS]) :-
    def_get_texpr_id(Var,Id),
    absint_set_up_undefined_localstate(T,InS,OutS).

assign_vals_to_vars([], [], []).

assign_vals_to_vars([H1|T1], [H2|T2], [bind(H1,H2)|T]) :-
    assign_vals_to_vars(T1, T2, T).

assign_var(identifier(Id),Value,_LS,_S,Id,Value) :- !.

assign_vars([], [], _LocalState, _StateIn, [], []).

assign_vars([TVarH|TVarT], [TValH|TValT], LocalState, StateIn, [NewVarH|NewVarT], [NewValH|NewValT]) :-
    get_texpr_expr(TVarH,VarH),
    assign_var(VarH, TValH, LocalState,StateIn, NewVarH, NewValH),
    assign_vars(TVarT, TValT, LocalState,StateIn, NewVarT, NewValT).

binary_operator(BinExpr, BOP, Arg1, Arg2) :-
    functor(BinExpr, BOP, 2),
    arg(1, BinExpr, Arg1),
    arg(2, BinExpr, Arg2).

execute_else_list([],_,_State,[]).

execute_else_list([TExpr|Rest],LocalState,InState,OutState) :-
    get_texpr_expr(TExpr,if_elsif(Test,Body)),
    absint_check_boolean_expression(Test,LocalState,NewLocalState,InState,NewInState,TestResult),
    (TestResult = true
    -> absint_execute_statement(Body,NewLocalState,NewInState,OutState,_Path)
    ; execute_else_list(Rest,NewLocalState,NewInState,OutState)).

execute_statements_in_parallel([],_LocalState,_StateIn,[],[]).

execute_statements_in_parallel([Stmt|TS],LocalState,InState,UpdatesOut,[Path1|TPath]) :-
    absint_execute_statement(Stmt,LocalState,InState,Updates1,Path1),
    execute_statements_in_parallel(TS,LocalState,InState,Updates2,TPath),
    append(Updates1,Updates2,UpdatesOut).

nary_operator(UnExpr, UOP, Arg1) :-
    functor(UnExpr, UOP, 1),
    arg(1, UnExpr, Arg1),
    is_list(Arg1).

state_lookup(Id,S1,S2,Val) :-
    statistics(walltime,_),
    statistics(runtime,_),
    state_lookup2(Id,S1,S2,Val),
    statistics(walltime,[_,Duration]),
    statistics(runtime,[_,RDuration]),
    (Duration < 20 -> true ; length(S1,LS1), length(S2,LS2),
    format('Warning: lookup of ~w took ~w (~w) ms (Val=~w,LS1=~w,LS2=~w)~n', [Id, Duration,RDuration,Val,LS1,LS2])).

state_lookup2(Id,LocalState,GlobalState,Value) :-
    (member(bind(Id,Val),LocalState) -> Value=Val
    ; member(bind(Id,Val),GlobalState) -> Value=Val
    ; state_lookup_global(Id,Value)).

state_lookup_global(Id,Val) :-
    lookup_global_constant(Id,fd(_,Set)), !,
    call_alpha(global(Set),global(Set),[],Val).

state_lookup_global(Id,Val) :-
    b_global_set(Id), !,
    call_alpha(set(global(Id)),set(global(Id)),[],Val).

state_lookup_global(Id,_Val) :- add_error_fail(lookup_value, 'Variable could not be found: ', Id).

state_store(bind(Key,_), [], []) :-
    !, add_error(absint_state_store, 'Variable could not be found in state: ', Key).

state_store(bind(Key,Value), [bind(Key,_Value)|Rest], [bind(Key,Value2)|Rest]) :-
    !, Value2=Value.

state_store(Pair, [Pair2|Rest], [Pair2|StateOut]) :-
    Pair \= Pair2,
    state_store(Pair, Rest, StateOut).

state_store_list([], State, State).

state_store_list([H|T], StateIn, StateOut) :-
    state_store(H, StateIn, StateIn1),
    state_store_list(T, StateIn1, StateOut).

test_binary_update(Arg1, Arg2, NewVal1, NewVal2, StateIn, StateOut) :-
    test_unary_update(Arg1,NewVal1,StateIn,TempStateOut),
    test_unary_update(Arg2,NewVal2,TempStateOut,StateOut).

test_unary_update(Arg,Val,StateIn,StateOut) :-
    Arg = identifier(ID) -> state_store(bind(ID,Val),StateIn,StateOut) ; StateIn = StateOut.

unary_operator(UnExpr, UOP, Arg1) :-
    functor(UnExpr, UOP, 1),
    arg(1, UnExpr, Arg1),
    \+ is_list(Arg1).