xml2b

convert_json_content_to_b([],_ParentId,NextId,OutId,_,_Span) --> {OutId=NextId}.

convert_json_content_to_b([H|T],ParentId,NextId,OutId,LineNr,Span) -->
    convert_json_element(H,ParentId,NextId,Id2,LineNr,Span),
    convert_json_content_to_b(T,ParentId,Id2,OutId,LineNr,Span).

convert_json_element(Element,ParentId,NextId,OutId,_LineNr,Span) -->
    {json_element(Element,Tag,BAttributesList,Content,LineNr)},
    !,
    {var(LineNr) -> LineNr=0 ; true},
    [(int(NextId),
    rec([ % note: fields have to be in order
    field(attributes,BAttributes), % partial function of Attributes
    field(element,string(Tag)),
    field(meta,MetaAttributes), % such as xmlLineNumber
    field(pId,int(ParentId)), % id of the parent XML record
    field(recId,int(NextId)) % id of the XML element/record
    ])
    )],
    {Id2 is NextId+1,
    number_codes(LineNr,LCC), atom_codes(LineNrAtom,LCC),
    convert_to_avl([(string(xmlLineNumber),string(LineNrAtom))],MetaAttributes),
    convert_to_avl(BAttributesList,BAttributes)
    },
    convert_json_content_to_b(Content,NextId,Id2,OutId,LineNr,Span).

convert_json_element(El,_,Id,Id,LineNr,Span) -->
    {ajoin(['Cannot translate JSON element at line ',LineNr,' to B:'],Msg),
    add_error(convert_json_to_b,Msg,El,Span)}.

convert_json_to_b(Json,BContent,Span) :- !,
    (convert_json_element(Json,0,1,_,1,Span,Conversion,[])
    -> BContent=Conversion
    ; add_error(convert_json_to_b,'Converting JSON content to B failed:',Json,Span), % probably an internal error
    fail
).

convert_xml_attributes('='(Attr,Codes),(string(Attr),string(Atom))) :- !,atom_codes(Atom,Codes).

convert_xml_attributes(A,(string(error),string(A))) :- format('**** UNKNOWN ATTRIBUTE: ~w~n',[A]).

convert_xml_content_to_b([],_ParentId,NextId,OutId) --> {OutId=NextId}.

convert_xml_content_to_b([H|T],ParentId,NextId,OutId) -->
    convert_xml_element(H,ParentId,NextId,Id2),
    convert_xml_content_to_b(T,ParentId,Id2,OutId).

convert_xml_element(Element, ParentId,NextId,OutId) -->
    % {get_counter(xml2b_current_line,CurNr),nl,print(el(CurNr,Element)),nl},
    {xml_element(Element,Tag,Attributes,Content,LineNr)},
    !,
    [(int(NextId),
    rec([ % note: fields have to be in order
    field(attributes,BAttributes), % partial function of Attributes
    field(element,string(Tag)),
    field(meta,MetaAttributes), % such as xmlLineNumber
    field(pId,int(ParentId)), % id of the parent XML record
    field(recId,int(NextId)) % id of the XML element/record
    ])
    )],
    {Id2 is NextId+1,
    number_codes(LineNr,LCC), atom_codes(LineNrAtom,LCC),
    construct_singleton_avl_set((string(xmlLineNumber),string(LineNrAtom)),MetaAttributes),
    l_convert_xml_attributes(Attributes,BAttributesList),
    convert_to_avl(BAttributesList,BAttributes)
    },
    convert_xml_content_to_b(Content,NextId,Id2,OutId).

convert_xml_element(namespace( URL, NS, Element), ParentId,NextId,OutId) --> !, % what should we do with the namespace?
    {(URL='', NS=[] -> true
    ; get_counter(xml2b_current_line,LineNr),
    format('*** Ignoring XML namespace "~s" annotation on line ~w with URL: ~w~n',[NS,LineNr,URL]))},
    convert_xml_element(Element, ParentId,NextId,OutId).

convert_xml_element(pcdata(_Codes),_,Id,Id) --> !. % should only happen when Codes consists solely of newlines

convert_xml_element(comment(Codes),_,Id,Id) --> !,{count_newlines(Codes)}.

convert_xml_element(instructions(Name, Chars),_,Id,Id) --> !,
    {get_counter(xml2b_current_line,LineNr),
    format('Ignoring XML instructions annotation on line ~w: ~w : ~w~n',[LineNr,Name,Chars])}.

convert_xml_element(doctype(Tag, DoctypeId),_,Id,Id) --> !,
    {get_counter(xml2b_current_line,LineNr),
    format('Ignoring XML doctype annotation on line ~w: ~w : ~w~n',[LineNr,Tag,DoctypeId])}.

convert_xml_element(cdata(Codes),ParentId,Id,OutId) --> !,
    % TO DO: tab expansion? see http://binding-time.co.uk/wiki/index.php/Parsing_XML_with_Prolog
    convert_xml_element(pcdata(Codes),ParentId,Id,OutId).

convert_xml_element(El,_,Id,Id) -->
    {get_counter(xml2b_current_line,LineNr),
    format('*** Unknown XML element on line ~w: ~w~n',[LineNr,El])}.

convert_xml_to_b(Codes,BContent,Context,Span) :-
    reset_counter(xml2b_current_line),
    set_counter(xml2b_current_line,1),
    peel_and_count_newlines(Codes,PeeledCodes),
    (debug_mode(off) -> true
    ; get_counter(xml2b_current_line,InitialLineNr),
    format('XML starting at line: ~w of ~w~n',[InitialLineNr,Context])),
    %statistics(walltime,[W1,_]),
    xml_parse(PeeledCodes,xml(_Atts,Content),[format(false)],Span), % format(false) means we also see all newlines
    %statistics(walltime,[W2,_]), W is W2-W1, formatsilent('% Walltime ~w ms to parse XML using Prolog library~n',[W]),
    % xml_prob:xml_pp(xml(_Atts,Content)),nl,
    % xml_parse(Codes2,xml(_Atts,Content),[]), format('XML:~n~s~n',[Codes2]),
    %print(Content),nl,nl,
    !,
    (convert_xml_content_to_b(Content,0,1,_,Conversion,[]) -> BContent = Conversion
    ; add_error(convert_xml_to_b,'Converting XML content to B failed:',Content,Span), % probably an internal error
    fail
).

convert_xml_to_b(_,_,Context,Span) :-
    add_error(convert_xml_to_b,'XML Parsing failed, ensure that XML is valid in:',Context,Span),fail.

count_newlines([]) :- !.

count_newlines(HT) :- newline(HT,T),!, inc_counter(xml2b_current_line), count_newlines(T).

count_newlines([_|T]) :- count_newlines(T).

count_newlines_and_trim([],Res) :- !, Res=[].

count_newlines_and_trim(HT,Res) :- newline(HT,R),!, inc_counter(xml2b_current_line),
    count_newlines_and_trim3(R,[10],Res).

count_newlines_and_trim([H|T],[H|TRes]) :-
    count_newlines_and_trim(T,TRes).

count_newlines_and_trim3([],_,Res) :- !, Res=[]. % ignore accumulator

count_newlines_and_trim3(HT,Acc,Res) :- newline(HT,R),!, inc_counter(xml2b_current_line),
    count_newlines_and_trim3(R,[10|Acc],Res).

count_newlines_and_trim3([H|T],Acc,Res) :-
    revacc(Acc,[H|TRes],Res), count_newlines_and_trim(T,TRes).

get_line_nr(L-_,L) :- !.

get_line_nr(E,0) :- writeq(E), format('*** No position info: ~w~n',[E]).

json_element(@(null),null,[],[],_) :- !. % unknown line number

json_element(@(true),boolean,[(string(value),string(true))],[],_) :- !. % unknown line number

json_element(@(false),boolean,[(string(value),string(false))],[],_) :- !. % unknown line number

json_element(number(Number),number,[(string(value),string(Atom))],[],_) :- !, % unknown line number
    number_codes(Number,Codes), atom_codes(Atom,Codes).

json_element(string(String),string,[(string(value),string(String))],[],_) :- !. % unknown line number

json_element(json(Object),object,[],Object,_) :- !. % unknown line number

json_element(array(Array),array,[],Array,_) :- !. % unknown line number

json_element('='(Key,Value,Pos),attribute,[(string(key),string(Key))],[Value],LineNr) :- !, get_line_nr(Pos,LineNr).

l_convert_xml_attributes([],[]).

l_convert_xml_attributes([H|T],[CH|CT]) :- convert_xml_attributes(H,CH),
    l_convert_xml_attributes(T,CT).

newline([H|T],R) :- (H=10 -> R=T ; H=13 -> (T=[10|TX] -> R=TX ; R=T)).

peel_and_count_newlines([],Res) :- !, Res=[].

peel_and_count_newlines([H|T],Res) :- (whitespace(H) -> peel_and_count_newlines(T,Res)
    ; H=10 -> inc_counter(xml2b_current_line), peel_and_count_newlines(T,Res)
    ; H=13 -> inc_counter(xml2b_current_line),
    (T=[10|TX]
    -> peel_and_count_newlines(TX,Res)
    ; peel_and_count_newlines(T,Res))
    ; Res = [H|T]).

revacc([],Acc,Acc).

revacc([H|T],Acc,Res) :- revacc(T,[H|Acc],Res).

whitespace(9). % tab

whitespace(32).

xml2b_startup :- % call once at startup to ensure all counters exist
    counter_init,
    new_counter(xml2b_current_line).

xml_element(element(Tag,XAttributes,Content),Tag,Attributes,Content,LineNr) :-
    get_counter(xml2b_current_line,CurLineNr),
    (select('='('$attribute_linefeeds',LF),XAttributes,Rest)
    -> LineNr is CurLineNr+LF, Attributes = Rest, %print(inc_line_nr(CurLineNr,LF)),nl,
    set_counter(xml2b_current_line,LineNr)
    ; LineNr = CurLineNr, Attributes=XAttributes).

xml_element(pcdata(Codes),'CText',['='(text,NewCodes)],[],LineNr) :-
    peel_and_count_newlines(Codes,C1),
    C1 \= [],
    get_counter(xml2b_current_line,LineNr),
    count_newlines_and_trim(C1,NewCodes).