smtlib2_parser

any_chars_but_newline([C|T]) --> [C], {C \= 10}, any_chars_but_newline(T).

any_chars_but_newline([]) --> "".

any_chars_but_pipe([C|T]) --> [C], {C \= 124}, any_chars_but_pipe(T).

any_chars_but_pipe([]) --> "".

any_chars_but_quotations([C|T]) --> [C], {C \= 34}, any_chars_but_quotations(T).

any_chars_but_quotations([C,C|T]) --> [C,C], {C = 34}, any_chars_but_quotations(T).

any_chars_but_quotations([]) --> "".

asciicomment(string(Symbol)) --> "|", any_chars_but_pipe(Codes), "|", {atom_codes(Symbol,Codes)}.

at_least_once(A,[Partial|List]) -->
    call(A,Partial), ws,
    !,
    multiple_times(A,List).

at_least_once(A,_) --> err_message(A).

at_least_once_no_whitespace(A,[Partial|List]) -->
    call(A,Partial),
    multiple_times_no_whitespace(A,List).

attribute(attribute(A,Value)) --> keyword(A), real_ws, attribute_value(Value).

attribute(attribute(A)) --> keyword(A).

attribute_value(Value) --> symbol(Value).

attribute_value(Value) --> spec_constant(Value).

attribute_value(Value) --> "(", at_least_once(sexpr,Value), ")".

binary_number(0) --> "0".

binary_number(1) --> "1".

binary_numbers([H|T]) --> binary_number(H), binary_numbers(T).

binary_numbers([N]) --> binary_number(N).

binding(bind(Symbol,Term)) --> "(", must_be_symbol(Symbol), ws, !, must_be_term(Term), close_paren(bind).

close_paren(Ctxt) --> real_ws, !, close_paren(Ctxt).

close_paren(_) --> ")",!.

close_paren(Ctxt) --> err_message(closing_parenthesis(Ctxt)).

command(Command) --> "(", ws, !, command1(Command).

command(exit) --> ":x",!. % for ProB REPL compatibility

command1(set_logic(Logic)) --> "set-logic", !, ws, symbol(Logic), close_paren(set_logic).

command1(set_option(Option)) --> "set-option", !, ws, attribute(Option), close_paren(set_option).

command1(set_info(Info)) --> "set-info", !, ws, attribute(Info), close_paren(set_info).

command1(set_info(Info)) --> "meta-info", !, ws, attribute(Info), close_paren(meta_info).

command1(reset) --> "reset", !, close_paren(reset).

command1(declare_sort(Name,Arity)) --> "declare-sort", !, ws,
    symbol(Name), ws, numeral(Arity), close_paren(declare_sort).

command1(define_sort(Name,Parameters,Sort)) --> "define-sort", !, ws,
    symbol(Name), ws, "(", multiple_times(symbol,(Parameters)), ")", ws,
    !,
    must_be_smt_sort(Sort), close_paren(define_sort).

command1(declare_fun(Name,Parameters,Result)) --> "declare-fun", ws, !,
    must_be_symbol(Name), ws,
    "(", multiple_times(smt_sort,Parameters), ws, ")", ws,
    must_be_smt_sort(Result), close_paren(declare_fun).

command1(define_fun(Name,Parameters,Result,Term)) --> "define-fun", ws, !,
    symbol(Name), ws, "(", multiple_times(sorted_var,Parameters), ")", ws,
    !,
    must_be_smt_sort(Result), ws, must_be_term(Term), close_paren(define_fun).

command1(push(Num)) --> "push", !, ws, numeral(Num), close_paren(push).

command1(pop(Num)) --> "pop", !, ws, numeral(Num), close_paren(pop).

command1(assert(Term)) --> "assert", ws, !,
    must_be_term(Term), close_paren(assert).

command1(check_sat) --> "check-sat", !, close_paren(check_sat).

command1(get_assert) --> "get-assert", !, close_paren(get_assert).

command1(get_proof) --> "get-proof", !, close_paren(get_proof).

command1(get_model) --> "get-model", !, close_paren(get_model).

command1(get_unsat_core) --> "get-unsat-core", !, close_paren(get_unsat_core).

command1(get_value(Terms)) --> "get-value", ws, !, "(", at_least_once(term,Terms), ")", close_paren(get_value).

command1(get_assign) --> "get-assign", !, close_paren(get_assign).

command1(get_option(Name)) --> "get-option", ws, !, keyword(Name), close_paren(get_option).

command1(get_info(Name)) --> "get-info", ws, !, keyword(Name), close_paren(get_info).

command1(exit) --> "exit", !, close_paren(exit).

command1(_) --> err_message(command).

commands(Cmds) --> real_ws, !, commands(Cmds).

commands([Command|Commands]) -->
    command(Command), {debug_println(5,command(Command))}, !,
    commands(Commands).

commands(Commands) --> ";", any_chars_but_newline(_), newline, !, commands(Commands).

commands([]) --> !.

commands(_) --> err_message(command).

decimal_numeral(D) --> numeral(D1), ".", numeral(D2),
    {number_codes(D1,DC1), number_codes(D2,DC2),
    append([DC1,".",DC2],Codes),
    number_codes(D,Codes)}.

digit(D) --> [D], {[D]="0"} ; digit_no_zero(D).

digit_no_zero(D) --> [D], {member(D,"123456789")}.

err_message(Expected) --> {line_counter(N), format_with_colour_nl(user_error,[red],"! Unrecognized ~w on line ~w.",[Expected,N]),fail}.

err_message(_) --> any_chars_but_newline(S), !, {format_with_colour_nl(user_error,[red],"! '~s'",[S]),fail}.

identifier(Id) --> symbol(Id).

inc_line_counter :-
    retract(line_counter(N)), debug_println(5,processed_line(N)),
    N1 is N+1, assertz(line_counter(N1)).

keyword(KW) --> ":", symbols_or_digits(L), {atom_codes(KW,L)}.

line_counter(1).

multiple_times(A,[Partial|List]) -->
    call(A,Partial), ws,
    multiple_times(A,List).

multiple_times(_A,[],In,In).

multiple_times_no_whitespace(A,List) -->
    at_least_once_no_whitespace(A,List).

multiple_times_no_whitespace(_A,[],In,In).

must_be_smt_sort(T) --> smt_sort(T),!.

must_be_smt_sort(_) --> err_message(sort).

must_be_symbol(T) --> symbol(T),!.

must_be_symbol(_) --> err_message(symbol).

must_be_term(T) --> term(T),!.

must_be_term(_) --> err_message(term).

newline --> [10],!, {inc_line_counter}.

newline --> [13],!, {inc_line_counter}.

numeral(0) --> "0".

numeral(N) --> digit_no_zero(D1), multiple_times_no_whitespace(digit,D), {number_codes(N,[D1|D])}.

parse_smtlib2(Source, ListOfCommands) :-
    debug_println(5,parsing_smtlib2(Source)),
    reset_parser,
    phrase(commands(ListOfCommands),Source),
    debug_println(5,finished_parsing).

qual_identifier(id(Id)) --> identifier(Id).

qual_identifier(id(Id,Sort)) --> "(as ", ws, !, identifier(Id), ws, smt_sort(Sort), ")".

qual_identifier(id(sign_extend(Parameter))) --> "(_ sign_extend ", !, numeral(Parameter), ")".

qual_identifier(id(zero_extend(Parameter))) --> "(_ zero_extend ", !, numeral(Parameter), ")".

qual_identifier(id(extract(P1,P2))) --> "(_ extract ", !, numeral(P1), ws, numeral(P2), ")".

real_ws --> " ", !, ws.

real_ws --> [9], !, ws.

real_ws --> newline, ws.

reset_parser :- retractall(line_counter(_)), assertz(line_counter(1)).

sexpr(E) --> spec_constant(E).

sexpr(E) --> symbol(E).

sexpr(E) --> keyword(E).

sexpr(E) --> "(", multiple_times(sexpr,E), ")".

simplesymbol(Symbol) --> single_symbol(Start), symbols_or_digits(Rest), {atom_codes(Symbol,[Start|Rest])}.

single_symbol(S) --> [S], {member(S,"abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ+-/*=%?!.$_~&^<>@")}.

single_symbol_or_digit(S) --> single_symbol(S) ; digit(S).

smt_sort(sort(S)) --> identifier(S).

smt_sort(sort(S)) --> numeral(S). % not yet supported in Translation, what does it mean?

smt_sort(sort('BitVec',[Length])) --> "(_ BitVec ", numeral(Length), ")".

smt_sort(sort(S,Params)) --> "(", identifier(S), ws, !,
    at_least_once(smt_sort,Params), close_paren(sort).

sorted_var(svar(Name,Sort)) --> "(", symbol(Name), ws, smt_sort(Sort), ")".

spec_constant(decimal(D)) --> decimal_numeral(D).

spec_constant(integer(I)) --> numeral(I).

spec_constant(string(S)) --> "\"", any_chars_but_quotations(SCodes), "\"", {atom_codes(S,SCodes)}.

spec_constant(bitvector(Val,Length)) --> "(_ bv", numeral(Val), " ", numeral(Length), ")".

spec_constant(bitvector(Binary)) --> "#b", binary_numbers(Binary).

symbol(Symbol) --> (simplesymbol(Symbol) -> [] ; asciicomment(Symbol)).

symbols_or_digits([H|T]) --> single_symbol_or_digit(H), symbols_or_digits(T).

symbols_or_digits([]) --> "".

term(let(Bindings,Term)) -->
    "(let", ws, !, "(", at_least_once(binding,Bindings), ")", ws, !, must_be_term(Term), !, close_paren(let).

term(forall(Vars,Term)) -->
    "(forall", ws, !, "(", at_least_once(sorted_var,Vars), ")", ws, !, must_be_term(Term), !, close_paren(forall).

term(exists(Vars,Term)) -->
    "(exists", ws, !, "(", at_least_once(sorted_var,Vars), ")", ws, !, must_be_term(Term), !, close_paren(exists).

term(T) --> spec_constant(T),!.

term(T) --> qual_identifier(T),!.

term(attributed_term(Term,Attributes)) --> "(", "!", ws, !,
    must_be_term(Term), ws, !,
    at_least_once(attribute,Attributes), close_paren(attributed_term).

term(id_term(Id,Terms)) --> "(", qual_identifier(Id), ws, !, at_least_once(term,Terms), close_paren(id_term).

ws --> " ", !, ws.

ws --> [9], !, ws. % tab

ws --> newline, !, ws.

ws --> "".