state_permuter

extract_value([vals(Set,Vals)|T],_X,Set,PX,AV2) :- !,
    remove(Vals,PX,Vals2),
    AV2 = [vals(Set,Vals2)|T].

extract_value([H|T],X,Set,PX,[H|T2]) :-
    extract_value(T,X,Set,PX,T2).

label_permutation(Perm) :-
    findall(vals(Set,Vals), (b_global_set(Set),set_of_values(Set,Vals)), AV),
    %print(label_perm(Perm,AV)),nl,
    label_permutation(Perm,AV).

label_permutation([],_).

label_permutation([perm(X,PX,Set)|T], AV) :- % print(p(X,Set)),nl,
    extract_value(AV,X,Set,PX,AV2), %print(val(X,PX,AV2)),nl,
    label_permutation(T,AV2).

permute_fields([],P,P,[]).

permute_fields([field(Name,Val)|T],In,Out,[field(Name,PVal)|PT]) :-
    permute_value(Val,In,In2,PVal),
    permute_fields(T,In2,Out,PT).

permute_state(X,NPX) :-
    ( b_exists_global_set_with_potential_symmetry
    -> permute_state2(X,NPX) ; NPX=X).

permute_state2(State,PermutedState) :-
    (State = concrete_constants(BState)
    -> PermutedState = concrete_constants(NPX)
    ; (State = csp_and_b(CSPState,BState)
    -> PermutedState = csp_and_b(CSPState,NPX)
    ; (State=BState, PermutedState=NPX)
    )
    ),
    expand_const_and_vars_to_full_store(BState,FullBState), /* TO DO: better treatment of ConstID in const_and_vars */
    permute_state3(FullBState,[],PX),normalise_store(PX,NPX).

permute_state3([],Perm,[]) :- % print(labeling(Perm)),nl,
    label_permutation(Perm).

permute_state3([bind(X,Val)|T],InPerm,[bind(X,PermVal)|PT]) :-
    (permute_value(Val,InPerm,OutPerm,PermVal)
    -> true
    ; add_error(state_permuter,'permute_value failed: ',permute_value(Val,InPerm,OutPerm,PermVal)),
    PermVal = Val
    ),
    %print(perm(Val,PermVal,OutPerm)),nl,
    permute_state3(T,OutPerm,PT).

permute_value(pred_false /* bool_false */,P,P,pred_false /* bool_false */).

permute_value(pred_true /* bool_true */,P,P,pred_true /* bool_true */).

permute_value(fd(X,Set),InPerm,OutPerm,PX) :-
    ((b_global_deferred_set_with_card_gt1(Set)
    ; is_unused_b_global_constant(Set,X) /* TO DO: only makes sense if more than one unused global constant */
    )
    -> (member(perm(X,PX,Set),InPerm)
    -> OutPerm = InPerm
    ; OutPerm = [perm(X,PX,Set)|InPerm]
    )
    ; OutPerm=InPerm, PX=fd(X,Set)
).

permute_value(global_set(X),P,P,global_set(X)).

permute_value(freetype(X),P,P,freetype(X)).

permute_value(avl_set(X),In,Out,PermutedList) :-
    expand_custom_set_to_list(avl_set(X),Value),
    % print(perm(X,Value)),nl,
    permute_value(Value,In,Out,PermutedList).

permute_value([],P,P,[]).

permute_value(int(X),P,P,int(X)).

permute_value(term(X),P,P,term(X)).

permute_value(string(X),P,P,string(X)).

permute_value(rec(X),In,Out,rec(PX)) :-
    permute_fields(X,In,Out,PX).

permute_value(freeval(I,C,X),In,Out,freeval(I,C,PX)) :-
    permute_value(X,In,Out,PX).

permute_value([H|T],In,Out,[PH|PT]) :-
    permute_value(H,In,In2,PH),
    permute_value(T,In2,Out,PT).

permute_value((H,T),In,Out,(PH,PT)) :-
    permute_value(H,In,In2,PH),
    permute_value(T,In2,Out,PT).

permute_value(closure(X,Y,Z),P,P,closure(X,Y,Z)).

permute_value(closure_x(X,Y,Z,E),P,P,closure_x(X,Y,Z,E)).

permute_value(abort(Err),P,P,abort(Err)) :- print(deprecated_abort_in_permute_value(Err)),nl.

remove([X|T],X,T).

remove([Y|T],X,[Y|DT]) :- remove(T,X,DT).

set_of_values(Set,Vals) :- b_global_deferred_set(Set),all_elements_of_type(Set,Vals).

set_of_values(Set,Vals) :-
    findall(fd(X,Set),is_unused_b_global_constant(Set,X), Vals),
    Vals \= [].