csp_profiler

add_time(ID,ExitTime) :- %print(add_time(ID,EnterTime,ExitTime)),nl,
    (retract(enter(ID,EnterTime))
    -> (Delta is ExitTime-EnterTime,
    assert(sol_time(ID,Delta))
    )
    ; (print(err_add_time(ID)),nl
)
).

profile_call(_,Call) :- !, call(Call).

profile_call(ID,Call) :- assert(profiled_call(ID,Call)),
    % (enter(ID,_C) -> (print('### Already profiling id: '), print(ID), print(calls(_C,Call)),nl) ; true),
    (retract(calls(ID,Nr)) -> (N1 is Nr+1, assert(calls(ID,N1))) ; assert(calls(ID,1))),
    %print(enter(ID,Call)),nl,
    statistics(runtime,[EnterTime,_]),
    asserta(enter(ID,EnterTime)),
    call(Call),
    (true ; (statistics(runtime,[RedoTime,_]),asserta(enter(ID,RedoTime))),fail),
    statistics(runtime,[ExitTime,_]),
    add_time(ID,ExitTime).

profile_call(ID,_Call) :- % print(fail(ID)),nl,
    statistics(runtime,[FailTime,_]),
    (retract(enter(ID,EnterTime))
    -> Delta is FailTime-EnterTime
    ; (Delta=0, print(err_fail(ID)),nl)
    ), assert(fail_time(ID,Delta)),
    fail.

ps :- print('-------------------'),nl,
    print('Profiler Statistics'),nl,
    calls(ID,Nr),
    print(ID), print(' calls: '), print(Nr), nl,
    findall(T,sol_time(ID,T),FST),
    print(' Sol : '),stat_list(FST),
    findall(T,fail_time(ID,T),FT),
    print(' Fail: '),stat_list(FT),
    fail.

ps :- print('-------------------'),nl.

reset_profiler :-
    retractall(enter(_,_)),
    retractall(calls(_,_)),
    retractall(profiled_call(_,_)),
    retractall(sol_time(_,_)),
    retractall(fail_time(_,_)).

stat_list(L) :- sum_list_len(L,Sum,Len,Max),
    print('Nr: '), print(Len), print(' Sum: '), print(Sum),
    (Len>0 -> (print(' Max: '), print(Max),print(' Avg: '), Avg is Sum/Len, print(Avg)) ; true),
    nl.

sum_list_len([],0,0,0).

sum_list_len([H|T],Sum,Len,Max) :-
    sum_list_len(T,ST,LT,MT),
    Sum is ST+H, Len is LT+1,
    (MT>H -> Max=MT ; Max=H).