prob_cov.pl

atom_header(Keyword, Header) :-
    header(Keyword,Tests),
    datime(datime(Year,Month,Day,Hour,Min,_Sec)),
    revision(CurrentCommit),
    format_to_codes('Coverage Report (~w, generated ~w.~w.~w ~w:~w, commit ~w)', [Tests,Day,Month,Year,Hour,Min,CurrentCommit], Codes),
    atom_codes(Header, Codes).

export(Info,Header,FilenameHTML,FilenameTEX,FilenameXML,ColorizedPath,ColorizedURL,EmmaPath) :-
    write('colorising source files line by line'), nl, full_flush,
    colorize_source_files(Info, ColorizedPath),
    write('colorising source files line by line done'), nl, full_flush,
    write('generation coverage report tables'), nl, full_flush,
    gen_pltables_coverage_rows(Info, [headline(Header)],[kernel,interpreter],ColorizedURL),
    write('generation coverage report tables done'), nl, full_flush,
    write('exporting tables to html, tex and xml'), nl, full_flush,
    export_tables(FilenameHTML,FilenameTEX,FilenameXML),
    write('exporting tables to html, tex and xml done'), nl, full_flush,
    write('exporting coverage data to emma'), nl, full_flush,
    export_emma(EmmaPath),
    write('exporting coverage data to emma done'), nl, full_flush.

generate_report(Now,descriptions) :- !,
    ajoin(['./coverage_reports/html/descriptions/descriptions-',Now,'.html'],FilenameHTML),
    ajoin(['./coverage_reports/tex/descriptions/descriptions-',Now,'.tex'],FilenameTEX),
    gen_pltables_descriptions_table(descriptionstable, [headline('Module Descriptions')],
    [kernel, interpreter]),
    tables_to_html([descriptionstable], FilenameHTML),
    tables_to_latex([descriptionstable], FilenameTEX).

generate_report(Now,Keyword) :-
    format('Generating coverage report for keyword: ~w~n',[Keyword]),
    relevant_categories(Keyword,Categories),
    load_coverage_files(Categories,CoverageInfo),
    % store coverage data of certain keywords, i.e.
    % to generate units-and-laws report by reading the units and the laws reports
    % and merging them
    write_coverage_data(Keyword,CoverageInfo),
    get_file_coverage_info(CoverageInfo,FinalCoverageInfo),
    atom_header(Keyword,Header),
    ajoin(['./coverage_reports/html/',Keyword,'/',Keyword,'-',Now,'.html'],FilenameHTML),
    ajoin(['./coverage_reports/tex/',Keyword,'/',Keyword,'-',Now,'.html'],FilenameTEX),
    ajoin(['./coverage_reports/xml/',Keyword,'/',Keyword,'-',Now,'.xml'],FilenameXML),
    ajoin(['./coverage_reports/color/',Keyword,'/'],ColorizedPath),
    ajoin(['../../color/',Keyword,'/'],ColorizedURL),
    ajoin(['./coverage_reports/emma/',Keyword,'.xml'],FilenameEmma),
    export(FinalCoverageInfo,Header,FilenameHTML,FilenameTEX,FilenameXML,ColorizedPath,ColorizedURL,FilenameEmma).

hci :-
    get_file_coverage_info(Info),
    gen_pltables_coverage_rows(Info, [], [kernel, interpreter]),
    export_tables_html_stream(user_output).

hci_file :-
    get_file_coverage_info(Info),
    gen_pltables_coverage_rows(Info, [], [kernel, interpreter]),
    export_tables_html('out.html').

header(units, 'Unit Tests').

header(laws, 'Law Checking').

header(units-and-laws,'Unit and Law Tests').

header(regression,'Regression Tests').

header(all,'All Tests').

header(data_validation,'Data Validation Tests').

header(X,Joined) :- atom(X), !, ajoin(['Testcases with Group ', X],Joined).

header(X,Joined) :- is_list(X), maplist(atom,X), !, ajoin(['Testcases with Groups ', X],Joined).

lci :-
    get_file_coverage_info(Info),
    gen_pltables_coverage_rows(Info, [], [kernel, interpreter]),
    export_tables_latex_stream(user_output).

lci_file :-
    get_file_coverage_info(Info),
    gen_pltables_coverage_rows(Info, [], [kernel, interpreter]),
    export_tables_latex('out.tex').

load_coverage_files(IDs,CoverageData) :-
    maplist(ensure_atom,IDs,AtomicIDs),
    file_members_of_directory('./temp_coverage_data/',CoverageFiles),
    write('Reading Coverage Files'), nl,
    read_coverage_files(CoverageFiles,AtomicIDs,CoverageData).

merge_coverage_counter(counter(File,PredSpec,ClauseNo,LineNr)-Tag1,
    counter(File,PredSpec,ClauseNo,LineNr)-Tag2,
    counter(File,PredSpec,ClauseNo,LineNr)-TagOut) :-
    merge_coverage_tags(Tag1,Tag2,TagOut).

merge_coverage_data([],[]).

merge_coverage_data([C],[C]).

merge_coverage_data([H1,H2|T],Out) :-
    merge_coverage_counter(H1,H2,HMerged), !,
    merge_coverage_data([HMerged|T],Out).

merge_coverage_data([H1,H2|T],[H1|Out]) :-
    merge_coverage_data([H2|T],Out).

merge_coverage_tags(Tag1,Tag2,TagOut) :-
    Tag1 =.. [Functor1,Count1], Tag2 =.. [Functor2,Count2], !,
    Count3 is Count1 + Count2,
    (Functor1 = Functor2
    -> TagOut =.. [Functor1,Count3]
    ; TagOut =.. [nondet,Count3]).

pci :- print_coverage_info.

pci(X) :- print_coverage_info(X).

read_coverage_data(Path,Data) :-
    open(Path,read,S),
    read(S,cov(Data)),
    close(S).

read_coverage_files(Files,RelevantIDs,CoverageData) :-
    read_coverage_files(Files,RelevantIDs,[],CoverageData).

read_coverage_files([],_IDs,DataSoFar,DataSoFar).

read_coverage_files([Name-Path|Files],IDs,DataSoFar,CovData) :-
    member(Name,IDs), !,
    format('.... Reading ~w~n',[Name]),
    read_coverage_data(Path,Content),
    % coverage data should already be sorted, only merge-step
    format(' .... Merging Coverage Lists~n',[]),
    merge(DataSoFar,Content,AppendedData),
    format(' .... Merging Coverage Data~n',[]),
    merge_coverage_data(AppendedData,NewData),
    length(DataSoFar,L1), length(NewData,L2), L is L2-L1,
    format(' .... ~w tags in old, ~w tags in new, ~w difference~n',[L1,L2,L]),
    garbage_collect,
    read_coverage_files(Files,IDs,NewData,CovData).

read_coverage_files([_|Files],IDs,DataSoFar,CovData) :-
    read_coverage_files(Files,IDs,DataSoFar,CovData).

relevant_categories(units,[unit]).

relevant_categories(laws,[laws]).

relevant_categories(units-and-laws,[unit,laws]).

relevant_categories(regression,Groups) :-
    all_categories(All),
    subtract(All,[unit,laws],Groups).

relevant_categories(all,All) :-
    all_categories(All).

relevant_categories(data_validation,[data_validation]).

relevant_categories(X,[X]) :- atom(X).

relevant_categories(X,X) :- is_list(X).

write_coverage_data(FileName,Data) :-
    ajoin(['./temp_coverage_data/', FileName],Path),
    format('Writing coverage data to ~w~n',[Path]), flush_output,
    open(Path,write,Stream),
    Out=cov(Data),
    write_canonical(Stream,Out),
    write(Stream,'.'),
    close(Stream).