1		% (c) 2009-2026 Lehrstuhl fuer Softwaretechnik und Programmiersprachen,
2		% Heinrich Heine Universitaet Duesseldorf
3		% This software is licenced under EPL 1.0 (http://www.eclipse.org/org/documents/epl-v10.html)
4
5
6		:- module(error_manager,[init_error_manager/0,
7		add_warning/2, add_warning/3, add_warning/4,
8		reset_errors/0, clear_wd_errors/0,
9		add_error/2, add_error/3, add_error/4,
10		add_error_and_fail/3, add_error_and_fail/2,
11		add_error_fail/3,
12		add_failed_call_error/1, add_internal_error/2, add_internal_error/4,
13		register_optional_error_or_warning/1, reset_optional_errors_or_warnings/0,
14		assert_true/1,
15		add_debug_message/3, add_debug_message/4,
16		add_msg_warn_or_err/5,
17		add_message/2, add_message/3, add_message/4,
18		add_all_perrors/1, add_all_perrors/2, add_all_perrors/3, add_all_perrors/4,
19		get_perror/4,
20		no_real_perror_occurred/1,
21		get_all_errors/1, tcltk_get_all_errors/4,
22		get_tk_table_position_info/2,
23		get_all_errors_and_reset/1, % call if you want to start with a fresh top-level error scope
24		get_all_errors_with_span_info_and_reset/1, % ditto + obtain location info; excludes messages
25		get_all_errors_with_span_and_context_and_reset/1, % ditt + global context and call stack
26		get_all_errors_and_clear/1,
27		get_error/2, get_error_with_span/3,
28		get_warning/2, check_error_occured/2, check_warning_occured/2,
29		get_error_span_linecol/5, get_error_span_linecol/4,
30		simplify_span/2,
31		tk_get_error_span_linecol_for_main_file/4,
32		register_error_span/2,
33		check_error_span_file_linecol/6,
34		position_is_not_in_main_file/1,
35		error_or_warning_occured/0,
36		real_error_occurred/0, reset_real_error_occurred/0, assert_real_error_occurred/1,
37		warning_occurred/0, % true if a warning was raised
38		wd_error_occured/0,
39		test_error_occurred/1, count_errors_occurred/2,
40		get_total_number_of_errors/1,
41		reset_error_spans/0,
42
43		backup_errors/0, backed_up_error/4,
44
45		set_error_context/1, clear_error_context/0,
46		get_error_context/1, restore_error_context/1,
47		print_error_context/0,
48
49		extract_span_description/2, extract_span_description_with_opts/3,
50		extract_symbolic_label_pos/2, extract_symbolic_label/2,
51		extract_line_col/5, extract_file_line_col/6,
52		extract_all_line_col/5,
53		extract_line_col_for_main_file/5,
54		extract_subsidiary_tail_file_name/2, extract_tail_file_name/2,
55		extract_file_number_and_name/3,
56		extract_additional_description/2, extract_pos_context/4,
57		extract_definition_call_stack/2, extract_definition_call_stack_desc/2,
58		print_error_span/1, print_message_span/1,
59
60		turn_show_error_source_on/0, turn_show_error_source_off/0,
61
62		enter_new_error_scope/1, enter_new_error_scope/2,
63		enter_new_clean_error_scope/2,
64		get_current_error_scope/1,
65		exit_error_scope/2, exit_error_scope/3,
66		error_occurred_at_level/1, specific_event_occurred_at_level/2,
67		%throw_errors_in_scope/3,
68		add_new_event_in_error_scope/1, add_new_event_in_error_scope/2,
69		event_occurred_in_error_scope/1, error_occurred_in_error_scope/0,
70		clear_events_in_error_scope/2, clear_events_in_current_error_scope/1,
71		translate_error_event/2,
72		clear_enumeration_warning_in_error_scope/1,
73		clear_all_errors_in_error_scope/1,
74		call_in_fresh_error_scope_for_one_solution/1,
75		enumeration_warning_occured_in_error_scope/0,
76		is_enumeration_warning_exception/1,
77		abort_error_occured_in_error_scope/0,
78		on_enumeration_warning/2, on_enumeration_warning_with_continue/3,
79		throw_enumeration_warnings_in_current_scope/0,
80		throw_enumeration_warnings_in_scope/3,
81		catch_enumeration_warning_exceptions/2, catch_enumeration_warning_exceptions/3,
82		catch_enumeration_warning_exceptions/4, catch_enumeration_warning_exceptions_and_wd_failures/5,
83		call_with_enumeration_warning/1,
84		observe_enumeration_warnings/2,
85		critical_enumeration_warning_occured_in_error_scope/4,
86		critical_enumeration_warning_occured_in_error_scope/0,
87		virtual_time_out_occured_in_error_scope/1, % variation which returns a virtual_time_out(.) term
88		clear_enumeration_warnings/0,
89		translate_events_in_current_scope_to_warnings/2,
90		time_out_with_enum_warning_one_solution/3, % use this for finding one solution
91		time_out_with_enum_warning_one_solution/4,
92		time_out_with_enum_warning_one_solution_no_new_error_scope/3,
93		is_time_out_result/1,
94		time_out_with_enum_warning_for_findall/3, % use this if you cycle through all solutions
95		time_out_with_enum_warning_for_findall_in_current_error_scope/4,
96		get_virtual_time_out_from_exception/2, % used by time_out_with_enum_warning_for_findall
97		clpfd_overflow_msg/1,
98		is_clpfd_overflow_representation_error/2, is_clpfd_overflow_representation_error_msg/1,
99		logged_error/4,
100		display_error_statistics/0,
101		set_error_manager_silent_mode/1
102		]).
103
104		% meta_predicate annotations should appear before loading any code:
105		:- meta_predicate add_failed_call_error(0).
106		:- meta_predicate add_internal_error(-,:).
107		:- meta_predicate add_new_event_in_error_scope(-,2).
108
109		:- meta_predicate on_enumeration_warning(0,0).
110		:- meta_predicate on_enumeration_warning_with_continue(0,0,0).
111
112		:- meta_predicate catch_enumeration_warning_exceptions(0,0).
113		:- meta_predicate catch_enumeration_warning_exceptions(0,0,-).
114		:- meta_predicate catch_enumeration_warning_exceptions(0,0,-,-).
115		:- meta_predicate catch_enumeration_warning_exceptions_and_wd_failures(0,0,-,0,-).
116
117		:- meta_predicate observe_enumeration_warnings(0,0).
118
119		:- meta_predicate time_out_with_enum_warning_one_solution(0,-,-).
120		:- meta_predicate time_out_with_enum_warning_one_solution(0,-,-,-).
121
122		:- meta_predicate call_in_fresh_error_scope_for_one_solution(0).
123
124		:- meta_predicate call_with_enumeration_warning(0).
125
126		:- meta_predicate time_out_with_enum_warning_one_solution_no_new_error_scope(0,-,-).
127
128		:- meta_predicate time_out_with_enum_warning_for_findall(0,-,-).
129		:- meta_predicate time_out_with_enum_warning_for_findall2(-,0,-,-).
130
131		:- meta_predicate time_out_with_enum_warning_for_findall_in_current_error_scope(-,0,-,-).
132
133		:- meta_predicate assert_true(0).
134		:- meta_predicate catch_wd(-,0,-).
135
136		% ------------
137
138		:- use_module(library(lists)).
139
140		:- use_module(tools,[get_tail_filename/2]).
141		:- use_module(tools_lists,[count_occurences/2]).
142		:- use_module(tools_printing,[print_error/1,print_message_on_stream/3,format_error_with_nl/2,format_with_colour/4]).
143		:- use_module(tools_strings,[ajoin/2, string_concatenate/3, ajoin_with_sep/3]).
144
145		:- use_module(module_information,[module_info/2]).
146		:- module_info(group,infrastructure).
147		:- module_info(description,'The error_manager controls error messages. Error messages can be added, retrieved, counted,etc. The module also takes care of extracting source spans from error messages.').
148
149		%:- use_module(translate).
150		:- use_module(debug, [debug_mode/1, debug_println/1, debug_println/2, debug_format/3]).
151		:- use_module(preferences,[get_preference/2,reset_temporary_preference/2,
152		temporary_set_preference/3]).
153
154
155		:- use_module(extension('counter/counter'),
156		[counter_init/1, new_counter/1, get_counter/2, inc_counter/2, set_counter/2]).
157
158		% cur_block_level is now stored as a C counter, which needs to be initialised
159		init_error_manager :- counter_init(Result), new_counter(cur_block_level),
160		(Result=success -> true
161		; assert_real_error_occurred(counter),
162		print_error('C++ counter extension initialisation failure!')).
163
164
165		:- dynamic optional_error_or_warning/1.
166		register_optional_error_or_warning(Type) :-
167		(optional_error_or_warning(Type) -> true ; assertz(optional_error_or_warning(Type))).
168		reset_optional_errors_or_warnings :- retractall(optional_error_or_warning(_)).
169
170		% INTERNAL ERRORS
171
172
173		add_failed_call_error(Call) :- !,
174		add_internal_error('Internal Error; call failed: ',Call).
175
176		add_internal_error(Module,Msg,Term,Span) :-
177		add_error(internal_error(Module),Msg,Term,Span).
178		add_internal_error(Msg,Module:Call) :- !,
179		add_error(internal_error(Module),Msg,Call).
180		add_internal_error(Msg,Call) :-
181		add_error(internal_error(unknown_module),Msg,Call).
182
183
184		% ERROR SCOPING
185
186		%:- dynamic cur_block_level/1.
187		%cur_block_level(0). % no realised as a C counter
188		:- volatile error_occurred_at_level/1.
189		:- dynamic error_occurred_at_level/1.
190		:- volatile throw_error/3.
191		:- dynamic throw_error/3.
192		:- volatile do_not_print_error/2.
193		:- dynamic do_not_print_error/2.
194
195
196		get_current_error_scope(Level) :- get_counter(cur_block_level,Level).
197
198		enter_new_error_scope(Level) :-
199		enter_new_error_scope(Level,'?').
200		enter_new_error_scope(Level,PP) :-
201		enter_new_clean_error_scope(Level,PP),
202		L1 is Level - 1,
203		copy_throw_errors(L1,Level).
204		copy_throw_errors(L1,L) :-
205		throw_error(L1,Error,Span), %print(copy(throw(L1,L,Error))),nl,
206		assertz(throw_error(L,Error,Span)),fail.
207		copy_throw_errors(L1,L) :-
208		do_not_print_error(L1,Error),
209		assertz(do_not_print_error(L,Error)),fail.
210		copy_throw_errors(_,_).
211		enter_new_clean_error_scope(Level,_PP) :-
212		inc_counter(cur_block_level,L1),
213		%tools_printing:print_term_summary(enter(L1,_PP)),nl,
214		(retract(throw_error(L1,_,_)) -> retractall(throw_error(L1,_,_)) ; true), % DO WE NEED THIS ??
215		(retract(do_not_print_error(L1,_)) -> retractall(do_not_print_error(L1,_)) ; true),
216		% print(enter(L1)),nl,trace,
217		% assertz(throw_error(L1,'--debug--',_PP)),
218		Level=L1.
219
220
221		% mark that everything unifying with Error should be thrown rather than collected
222		throw_errors_in_scope(Level,Error,Span) :-
223		(\+ throw_error(Level,Error,Span) % TO DO: check that we are an instance of existing error !
224		-> assertz(throw_error(Level,Error,Span))
225		; true).
226
227		% state that this event/error should not be printd
228		silent_enum_warnings_in_scope(Level,Critical) :-
229		Error = enumeration_warning(_,_,_,_,Critical),
230		assertz(do_not_print_error(Level,Error)).
231
232		clear_all_errors_in_error_scope(Level) :- %print(clearing(Level)),nl,
233		clear_events_in_error_scope(Level,_),
234		error_occurred_at_level(L1), L1>Level, %print(clearing(L1)),nl,
235		clear_events_in_error_scope(Level,_),fail.
236		clear_all_errors_in_error_scope(_).
237
238		% useful in call_cleanup; when error block may already be exited
239		exit_error_scope_if_necessary(Level,PP) :- get_counter(cur_block_level,CurLevel),
240		(Level =< CurLevel
241		-> exit_error_scope(Level,_,PP) %,print(exit(Level,CurLevel,PP)),nl
242		; true).
243
244		exit_error_scope(Level,ErrorOcc) :- exit_error_scope(Level,ErrorOcc,unknown).
245		exit_error_scope(Level,ErrorOcc,PP) :- get_counter(cur_block_level,CurL),
246		(CurL = Level -> NewL is CurL-1
247		; Level < CurL -> NewL is Level-1,
248		% print_error_scopes,
249		format('*** exiting multiple error blocks (~w -> ~w) for ~w ***~n',[CurL,NewL,PP])
250		; format('*** block ~w already exited (currently at ~w) for ~w ***~n',[Level,CurL,PP]),
251		NewL is CurL
252		), set_counter(cur_block_level,NewL),
253		copy_error_scope_events(CurL,NewL),
254	?	(retract(throw_error(CurL,_,_)) -> retractall(throw_error(CurL,_,_)) ; true),
255		(retract(do_not_print_error(CurL,_)) -> retractall(do_not_print_error(CurL,_)) ; true),
256		(retract(error_occurred_at_level(CurL))
257		-> ErrorOcc=true,
258		(error_occurred_at_level(NewL) -> true ; assertz(error_occurred_at_level(NewL)))
259		; ErrorOcc=false).
260		%indent(Level), format('exit level ~w for ~w, cur level ~w, error occ = ~w~n',[Level,PP,CurL,ErrorOcc]).
261
262
263		% versions of enter_new_error_scope and exit_error_scope which re_enter blocks and clean up upon backtracking
264		%enter_new_error_scope_bt(Level,PP) :- enter_new_error_scope(Level,PP), exit_upon_fail(Level,PP).
265		%exit_upon_fail(_,_).
266		%exit_upon_fail(Level,PP) :- print(exit_upon_backtrack(Level,PP)),nl,
267		% exit_error_scope(Level,_,PP),fail.
268		%
269		%exit_error_scope_bt(Level,ErrorOcc,PP) :- exit_error_scope(Level,ErrorOcc,PP).
270		%exit_error_scope_bt(Level,_ErrorOcc,PP) :- print(re_enter_block(Level,PP)),nl,
271		% enter_new_error_scope(Level2,PP),
272		% (Level2=Level -> true ; print(mismatch_when_reentering_block(Level,PP)),nl),
273		% fail.
274
275		% ---------------------------
276
277
278
279		assert_real_error_in_current_block(Source) :- get_counter(cur_block_level,L),L>0,
280		%print(assert_real_error_in_current_block(L)),nl,
281		(specific_event_occurred_at_level(L,Source) -> true
282		; assertz(specific_event_occurred_at_level(L,Source))), % ensures that clear_events_in_current_error_scope does not remove error_occurred_at_level if used for enumeration warnings, ...
283		\+ error_occurred_at_level(L), assertz(error_occurred_at_level(L)),!.
284		assert_real_error_in_current_block(_).
285
286
287		reset_error_scopes :-
288		(set_counter(cur_block_level,0) -> true
289		; format(user_error,'~n*** set_counter(cur_block_level,0) failed!!~n',[]),fail
290		), % try debug random gitlab failures; something really bad happened
291		retractall(error_occurred_at_level(_)),
292		retractall(specific_event_occurred_at_level(_,_)),
293		retractall(do_not_print_error(_,_)).
294
295		% for debugging / portraying error scopes:
296		% portray_error_scopes
297		:- public print_error_scopes/0.
298		print_error_scopes :-
299		if(get_counter(cur_block_level,L),
300		(format(' Cur Block Level = ~w~n',[L]),
301		throw_error(L,Error,_Span),
302		format(' -> throw: ~w~n',[Error])
303		),
304		format(' *** NO Cur Block Level Information !!',[])
305		),
306		fail.
307		print_error_scopes :-
308		findall(L,error_occurred_at_level(L),LL),
309		format(' Errors occured at those levels: ~w~n',[LL]),
310		\+ \+ specific_event_occurred_at_level(_,_),
311		format(' Specific events at levels:~n',[]),
312		specific_event_occurred_at_level(Level,Err),
313		format(' ~w --> ~w~n',[Level,Err]),
314		fail.
315		print_error_scopes :- \+ \+ throw_error(_,_,_),
316		format(' throw_error summary:~n',[]),
317		throw_error(Level,Err,Span),
318		format(' ~w (~w : ~w)~n',[Level,Err,Span]),
319		fail.
320		print_error_scopes.
321
322		% call a predicate in fresh error scope (assuming one solution is searched for only; failure is also ok)
323		% and then discard all errors
324		call_in_fresh_error_scope_for_one_solution(Call) :-
325		enter_new_error_scope(Level,call_in_fresh_error_scope_for_one_solution),
326		call_cleanup(Call,
327		(clear_all_errors_in_error_scope(_),
328		exit_error_scope(Level,_,call_in_fresh_error_scope_for_one_solution))).
329
330		:- volatile specific_event_occurred_at_level/2.
331		:- dynamic specific_event_occurred_at_level/2.
332
333		% can be used to keep track of whether specific events occurred within an error_scope
334		add_new_event_in_error_scope(Event) :-
335		add_new_event_in_error_scope(Event,do_nothing).
336		do_nothing(_,_).
337		add_new_event_in_error_scope(Event,PrintMessageCall) :-
338		get_counter(cur_block_level,L),
339	?	(specific_event_occurred_at_level(L,Event) -> fail
340		; (throw_error(L,Event,Span)
341		-> (debug_mode(off) -> true ; print_message(informational,throwing(Event))), % trace, % <---
342		(do_not_print_error(L,Event), debug_mode(off) -> true ; call(PrintMessageCall,throwing,Span)),
343		% Note: event is not asserted ! See e.g. tests 1089, 1519, 1522, 1661, 1199, 1291, ...
344		throw(Event)
345		; assertz(specific_event_occurred_at_level(L,Event)),
346		(do_not_print_error(L,Event), debug_mode(off) -> true ; call(PrintMessageCall,not_throwing,unknown))
347		)
348		).
349
350		% call if you just want to add the error information; without throwing
351		assert_event_in_error_scope_without_throw(Event) :- get_counter(cur_block_level,L),
352		(specific_event_occurred_at_level(L,Event) -> true
353		; assertz(specific_event_occurred_at_level(L,Event))).
354
355		error_occurred_in_error_scope :- get_counter(cur_block_level,L),error_occurred_at_level(L).
356		event_occurred_in_error_scope(Event) :- get_counter(cur_block_level,L),specific_event_occurred_at_level(L,Event).
357
358		copy_error_scope_events(FromLevel,ToLevel) :- retract(specific_event_occurred_at_level(FromLevel,Event)),
359		\+ specific_event_occurred_at_level(ToLevel,Event),
360		% print(copying_event(FromLevel,ToLevel,Event)),nl,
361		assertz(specific_event_occurred_at_level(ToLevel,Event)), % should we throw if this level demands it ?
362		(throw_error(ToLevel,Event,_Span)
363		-> debug_println(20,throw_copied_event(Event)), throw(Event)),
364		fail.
365		copy_error_scope_events(_,_).
366
367		clear_events_in_current_error_scope(Event) :- get_counter(cur_block_level,L),clear_events_in_error_scope(L,Event).
368
369		%clear_events_in_error_scope(L,Event) :-retract(specific_event_occurred_at_level(L,Event)), print(retract(L,Event)),nl,fail.
370
371		clear_enumeration_warning_in_error_scope(Level) :-
372		clear_events_in_error_scope(Level,enumeration_warning(_,_,_,_,_)).
373
374		clear_events_in_error_scope(L,Event) :-
375		(specific_event_occurred_at_level(L,_)
376		-> retractall(specific_event_occurred_at_level(L,Event)),
377		(specific_event_occurred_at_level(L,_) -> true % we have not removed all events
378		; retract(error_occurred_at_level(L)) -> true
379		; true
380		)
381		; true). % no errors can have been there
382
383		throw_enumeration_warnings_in_current_scope :-
384		get_counter(cur_block_level,L), throw_enumeration_warnings_in_scope(L,_,unknown).
385
386		throw_enumeration_warnings_in_scope(Level,Critical,Span) :-
387		simplify_span(Span,SimplifiedSpan), % relevant for test 1562
388		throw_errors_in_scope(Level,enumeration_warning(_,_,_,_,Critical),SimplifiedSpan).
389
390		on_enumeration_warning(Call, BackupCall) :-
391		on_enumeration_warning_with_continue(Call, BackupCall, true).
392		% sets up a new error scope and forces enumeration_warnings to be thrown
393		% if an enumeration_warning happens the BackupCall is executed
394		on_enumeration_warning_with_continue(Call, _, _) :- is_true_call(Call),!. % happens e.g., for card_for_specific_closure3
395		on_enumeration_warning_with_continue(Call, BackupCall, TrueContinuation) :-
396		enter_new_error_scope(Level,on_enumeration_warning_with_continue),
397		throw_enumeration_warnings_in_scope(Level,_,unknown),
398		call_cleanup(
399		catch(
400		if(Call,
401		(exit_error_scope(Level,_,on_enumeration_warning_with_continue_true),
402		% TODO: we need a version that re-instates error_scope upon backtracking?!
403		call(TrueContinuation)),
404		(exit_error_scope(Level,_,on_enumeration_warning_with_continue_false),fail)
405		),
406		Exc,
407		(exit_error_scope(Level,_,on_enumeration_warning_with_continue_exception), % We do not catch timeouts
408		(Exc=enumeration_warning(_,_,_,_,_) -> call(BackupCall) ; throw(Exc))
409		)
410		),
411		exit_error_scope_if_necessary(Level,on_enumeration_warning_with_continue_timeout) % TIMEOUT
412		).
413
414		% check if we are simply calling on_enumeration_warning with trivial true call; avoid call_cleanup, error_scope.
415		is_true_call(_:X) :- !, nonvar(X), is_true_call(X).
416		is_true_call(call(X)) :- !, is_true_call(X).
417		is_true_call(true).
418
419		catch_enumeration_warning_exceptions(Call, BackupCall) :-
420		catch_enumeration_warning_exceptions_and_wd_failures(Call,BackupCall,false,fail,unknown).
421		catch_enumeration_warning_exceptions(Call, BackupCall, AddAsEventError) :-
422		catch_enumeration_warning_exceptions_and_wd_failures(Call,BackupCall,AddAsEventError,fail,unknown).
423		catch_enumeration_warning_exceptions(Call, BackupCall, AddAsEventError,Source) :-
424		catch_enumeration_warning_exceptions_and_wd_failures(Call,BackupCall,AddAsEventError,fail,Source).
425
426		% can be used to check if an exception is an enumeration warning
427		is_enumeration_warning_exception(enumeration_warning(_Enumerating,_Type,_Range,_RestrRange,_Critical)).
428
429		% removed usage of call_cleanup; can cause huge runtime in debug_mode, cf SPRM-21383 but also e.g. for ProPlanGross.mch
430		% but simple_call_cleanup requires that C does not backtrack and CleanupCall called in case of exception
431		% does not catch timeouts, relevant for test 2355; messages also printed for test 2255, 2370
432		% but using call_cleanup in SICStus 4.9 for PlanProGross.mch results in timeout after several minutes in setup constants
433		% (see test 2427; this should be fixed in SICStus 4.10)
434		:- meta_predicate simple_call_cleanup(0,0).
435		:- if((current_prolog_flag(dialect, sicstus),
436		current_prolog_flag(version_data, sicstus(4,VN,_,_,_)), VN<10)).
437		use_simple_call_cleanup :- get_preference(time_out,TO), TO>250.
438		simple_call_cleanup(C,CleanupCall) :- use_simple_call_cleanup, !,
439		% low likelihood of triggering time-outs; we are not in unsat core computations of cdclt tests (2255, 2370, ...)
440		if(C,CleanupCall, (CleanupCall,fail)).
441		simple_call_cleanup(C,CleanupCall) :-
442		call_cleanup(C,CleanupCall). % use regular call_cleanup to catch time-outs
443		:- else.
444		use_simple_call_cleanup :- fail.
445		simple_call_cleanup(C,CleanupCall) :-
446		call_cleanup(C,CleanupCall). % use regular call_cleanup to catch time-outs
447		:- endif.
448
449		% AddAsEventError = true means that caught exceptions are added as event_errors in scope
450		% (this can be important if we later want to decide whether an enumeration warning occured)
451		% WDCall: this gets called when a well_definedness_error is raised by the Call
452		% assumes Call does not backtrack to use simple_call_cleanup
453		catch_enumeration_warning_exceptions_and_wd_failures(Call, BackupCall,AddAsEventError,WDCall,Source) :-
454		enter_new_error_scope(Level,catch_enumeration_warning_exceptions),
455		% difference: we do not force to throw_errors_in_scope
456		(Source = ignore(_) -> silent_enum_warnings_in_scope(Level,critical) ; true),
457		catch(
458		simple_call_cleanup(if(Call,true,catch_wd(Level,WDCall,Source)),
459		(exit_error_scope(Level,_,catch_enumeration_warning_exceptions))),
460		% call_cleanup can be tricky in case of success of Call: the error scope may not be exited immediately; TO DO: maybe rewrite using same style as above (using if + catch)
461		enumeration_warning(A,B,C,D,E),
462		((use_simple_call_cleanup
463		-> exit_error_scope(Level,_,catch_enumeration_warning_exceptions) % added due to simple_call_cleanup
464		; true % already performed by call_cleanup
465		),
466		(AddAsEventError=false
467		-> (Source=ignore(Src)
468		-> debug_format(19,'%%% Ignoring unbounded enumeration warning (source:~w).~n',[Src])
469		; true)
470		% inform that enum warning was not serious: there is a fall-back solution
471		; assert_event_in_error_scope_without_throw(enumeration_warning(A,B,C,D,E))),
472		BackupCall)
473		). % catch
474
475		catch_wd(Level,WDCall,Source) :-
476		WDCall \= fail,
477		% print(check_wd(Level,Source)),nl, portray_events_in_error_scope,nl,
478		specific_event_occurred_at_level(Level,well_definedness_error),!,
479		formatsilentmsg(user_output,'%%% well_definedness_error (source:~w).~n',[Source]),
480		call(WDCall).
481		catch_wd(_,_,_) :- fail.
482
483
484		% execute some code when enumeration warning occurs; and then throw exception again
485		observe_enumeration_warnings(Call,ObserverCallToExecute) :-
486		catch(Call, enumeration_warning(A,B,C,D,E),
487		call_cleanup(ObserverCallToExecute, throw(enumeration_warning(A,B,C,D,E)))).
488
489
490		% sets up a new error scope and forces enumeration_warnings to be thrown
491		% the exceptions are not caught !
492		call_with_enumeration_warning(Call) :-
493		enter_new_error_scope(Level,call_with_enumeration_warning),
494		throw_enumeration_warnings_in_scope(Level,_,unknown),
495		call_cleanup(
496		(Call, % the assumption is that Call will only have one solution
497		exit_error_scope(Level,_,call_with_enumeration_warning_true)),
498		exit_error_scope_if_necessary(Level,call_with_enumeration_warning_timeout) % failure, TIMEOUT or Exception
499		).
500
501
502		% a version of time_out which treats enumeration_warnings like time-outs
503		% and also checks enumeration_warnings in case of failure
504		% assumes we only look for one solution (otherwise error scope cleanup has to be changed !! )
505		time_out_with_enum_warning_one_solution(Call,TO,TimeOutRes,ClearEnumWarnings) :-
506		enter_new_error_scope(Level,time_out_with_enum_warning_one_solution),
507		call_cleanup(
508		catch(
509		time_out_check_enum_warning_for_failure(Call,TO,TimeOutRes,ClearEnumWarnings,perform_cut),
510		enumeration_warning(A,B,C,D,E),
511		% no need to clear: we leave error_scope below
512		TimeOutRes=virtual_time_out(thrown_enumeration_warning(A,B,C,D,E))),
513		exit_error_scope(Level,_,time_out_with_enum_warning_one_solution)).
514
515		% here enumeration warnings are not cleared and propagated to outer error scope
516		time_out_with_enum_warning_one_solution(Call,TO,TimeOutRes) :-
517		time_out_with_enum_warning_one_solution(Call,TO,TimeOutRes,no_clear).
518
519
520		enumeration_warning_occured_in_error_scope :-
521		event_occurred_in_error_scope(enumeration_warning(_,_,_,_,_)).
522
523		abort_error_occured_in_error_scope :-
524		event_occurred_in_error_scope(abort_error(_)). % is this still being generated??
525		abort_error_occured_in_error_scope :-
526		event_occurred_in_error_scope(well_definedness_error).
527
528
529		% just like above; but does not set up new error_scope (for performance) and clears enumeration warnings in case of failure and success
530		time_out_with_enum_warning_one_solution_no_new_error_scope(Call,TO,TimeOutRes) :-
531		(enumeration_warning_occured_in_error_scope
532		-> %trace,
533		format('Events in error block:~n',[]),portray_events_in_error_scope,
534		add_internal_error('Error block already has enumeration warnings',time_out_with_enum_warning_one_solution_no_new_error_scope(Call,TO,TimeOutRes))
535		; true),
536		% Note: will call safe_time_out which will not call time_out when time_out_preference_disabled / disable_time_out
537		catch(
538		time_out_check_enum_warning_for_failure(Call,TO,TimeOutRes,clear_errors,perform_cut), % clear errors so we can continue using same error scope
539		enumeration_warning(A,B,C,D,E),
540		%% (print(enum_warning),nl,TimeOutRes=time_out)). %%
541		TimeOutRes=virtual_time_out(thrown_enumeration_warning(A,B,C,D,E))).
542
543
544		% check if a result is a time_out:
545		is_time_out_result(time_out).
546		is_time_out_result(virtual_time_out(_)).
547
548		% a version which is to be used not for a single call but for backtracking
549		% generate virtual time_out at the end if enumeration warning occured
550
551		time_out_with_enum_warning_for_findall(Call,TO,TimeOutRes) :-
552		enter_new_error_scope(Level,time_out_with_enum_warning_for_findall),
553		time_out_with_enum_warning_for_findall2(Level,Call,TO,TimeOutRes).
554
555		time_out_with_enum_warning_for_findall2(_Level,Call,TO,TimeOutRes) :- %print(enter(_Level)),nl,
556		catch(
557		time_out_check_enum_warning_for_failure(Call,TO,TimeOutRes,no_clear,no_cut),
558		Exc,
559		get_virtual_time_out_from_exception(Exc,TimeOutRes)). % virtual time_out
560		time_out_with_enum_warning_for_findall2(Level,_Call,_TO,_TimeOutRes) :- % print(exit(Level)),nl,
561		clear_events_in_error_scope(Level,enumeration_warning(_,_,_,_,_)),
562		exit_error_scope(Level,_,time_out_with_enum_warning_for_findall2),fail.
563
564		% a version of time_out_with_enum_warning_for_findall where you manually have to enter_new_error_scope before
565		% and exit_error_scope afterwards; useful if you repeatedly call this predicate and want to set up the block only once
566		time_out_with_enum_warning_for_findall_in_current_error_scope(_Level,Call,TO,TimeOutRes) :- %print(enter(_Level)),nl,
567		catch(
568		time_out_check_enum_warning_for_failure(Call,TO,TimeOutRes,no_clear,no_cut),
569		Exc,
570		get_virtual_time_out_from_exception(Exc,TimeOutRes)). % virtual time_out
571		time_out_with_enum_warning_for_findall_in_current_error_scope(Level,_Call,_TO,_TimeOutRes) :-
572		% does not exit level
573		clear_events_in_error_scope(Level,enumeration_warning(_,_,_,_,_)),fail.
574
575		% ------------
576
577		% see if an exception corresponds to a virtual_timeout in the form of an enumeration warning
578		% also treats a CLPFD overflow as a virtual time-out in the sense that computation was aborted
579		get_virtual_time_out_from_exception(enumeration_warning(Cause,_,_,_,_),TimeOutRes) :- !,
580		get_virtual_time_out_res(Cause,TimeOutRes).
581		get_virtual_time_out_from_exception(error(_ErrMsg,ErrTerm),TimeOutRes) :-
582		is_clpfd_overflow_representation_error(ErrTerm,Cause),!,
583		clpfd_overflow_msg(Msg),
584		add_warning(clpfd_overflow,Msg),
585		TimeOutRes = virtual_time_out(Cause).
586		get_virtual_time_out_from_exception(Exc,_) :- % not detected as virtual time-out: throw again
587		throw(Exc).
588
589		get_virtual_time_out_res(kodkod_timeout,Res) :- !, Res= virtual_time_out(kodkod_timeout).
590		get_virtual_time_out_res(_,virtual_time_out(exception)).
591
592
593		is_clpfd_overflow_representation_error(representation_error(_Constraint,_,CauseMsg),CauseMsg) :-
594		is_clpfd_overflow_representation_error_msg(CauseMsg).
595		is_clpfd_overflow_representation_error(domain_error(list_to_fdset(_FDLIST,_),_,_,_List),CauseMsg) :-
596		CauseMsg = 'CLPFD integer overflow'.
597		is_clpfd_overflow_representation_error_msg('CLPFD integer overflow').
598		is_clpfd_overflow_representation_error_msg('max_clpfd_integer').
599		is_clpfd_overflow_representation_error_msg('min_clpfd_integer').
600
601		clpfd_overflow_msg(M) :- clpfd_interface:is_64_bit_system, !,
602		(get_preference(use_clpfd_solver,true)
603		-> M = 'A CLPFD integer overflow occurred.\nSet CLPFD preference to FALSE (Animation Preferences).'
604		; M = 'A CLPFD integer overflow occurred (despite CLPFD preference being FALSE).' % should normally not happen
605		).
606		clpfd_overflow_msg('A CLPFD integer overflow occurred.\nSet CLPFD preference to FALSE (Animation Preferences) or use a 64 bit version of ProB.').
607
608		% -----------------
609
610		:- use_module(tools_meta,[safe_time_out/3]).
611		% a version of time_out which upon failure checks if enumeration warnings were generated
612		time_out_check_enum_warning_for_failure(Call,TO,TimeOutRes,ClearErrors,CutAfterFirstSol) :-
613		safe_time_out(Call,TO,TimeOutRes), % a safe version which checks that time-out value TO is not too large
614		%call(Call), TimeOutRes=ok,
615		(TimeOutRes = time_out -> ! %, print(real_timeout),nl
616		; (ClearErrors=clear_errors -> clear_enumeration_warnings
617		; true), % no_clear
618		(CutAfterFirstSol=perform_cut -> !
619		; true) % no_cut
620		%,print(sol),nl
621		).
622		time_out_check_enum_warning_for_failure(_Call,_TO,TimeOutRes,ClearErrors,_) :- % print(failure),nl,
623		virtual_time_out_occured_in_error_scope(TimeOutRes),
624		(ClearErrors=clear_errors -> clear_enumeration_warnings ; true).
625
626		virtual_time_out_occured_in_error_scope(TimeOutRes) :-
627		event_occurred_in_error_scope(enumeration_warning(A,B,C,D,critical)), % print(virtual),nl,
628		TimeOutRes = virtual_time_out(failure_enumeration_warning(A,B,C,D,critical)). % we have not investigated all possibilities; generate virtual time_out
629
630		critical_enumeration_warning_occured_in_error_scope :-
631		critical_enumeration_warning_occured_in_error_scope(_,_,_,_).
632		critical_enumeration_warning_occured_in_error_scope(A,B,C,D) :-
633		event_occurred_in_error_scope(enumeration_warning(A,B,C,D,critical)).
634
635		clear_enumeration_warnings :-
636		clear_events_in_current_error_scope(enumeration_warning(_,_,_,_,_)).
637
638		% retract events and raise real warnings
639		% Src and Msg used if these are not enumeration warnings
640		translate_events_in_current_scope_to_warnings(Src,Msg) :-
641		get_counter(cur_block_level,L),
642		retract(specific_event_occurred_at_level(L,Event)),
643		(translate_enumeration_warning(Event,EMsg,Span)
644		-> add_warning(enumeration_warning,EMsg,'',Span)
645		; add_warning(Src,Msg,Event)),
646		fail.
647		translate_events_in_current_scope_to_warnings(_,_).
648
649		% see also: print_enum_warning
650		translate_enumeration_warning(enumeration_warning(Enumerating,Type,Range,RestrictedRange,_Throwing), Msg,Span) :-
651		translate_enumeration_info(Enumerating,Info,Span),
652		ajoin(['Unbounded enumeration of ',Info,':',Type,', narrowing range: ',Range,' ---> ',RestrictedRange],Msg).
653		% Throwing=throwing -> print_pending_abort_info ?
654
655		translate_enumeration_info(enumerating(Info),Res,Span) :- !, translate_enumeration_info(Info,Res,Span). % TO DO: call get_trigger_info
656		translate_enumeration_info(b(identifier(Id),_,Info),Res,Span) :- !, Res=Id,Span=Info.
657		translate_enumeration_info(I,I,I).
658
659		% show all events in current error scope
660		portray_events_in_error_scope :- event_occurred_in_error_scope(E),
661		portray_event(E),fail.
662		portray_events_in_error_scope.
663
664		portray_event(enumeration_warning(Source,Type,Range,RestrictedRange,Critical)) :-
665		translate_enumeration_info(Source,Res,_Span), !,
666		format(' *** Enumeration Warning (~w): Source ~w, Type: ~w, Range reduction: ~w ---> ~w~n',
667		[Critical, Res, Type, Range, RestrictedRange]).
668		portray_event(E) :- format(' *** ~w~n',[E]).
669
670		% translate an event error to a short human readable form:
671		translate_error_event(Error,TransError) :-
672		(translate_enumeration_warning(Error,Msg,_)
673		-> TransError=Msg
674		; TransError=Error). % TODO: translate other errors
675
676		% -----------------------
677
678		:- volatile logged_error_hash/5, real_error_occurred/0, logged_error_spans/2, saved_subsidiary_span_pos/4.
679		:- dynamic logged_error_hash/5.
680		:- dynamic logged_message/4.
681		:- dynamic real_error_occurred/0, warning_occurred/0.
682		:- dynamic logged_error_spans/2.
683		:- dynamic saved_subsidiary_span_pos/4. % for Tcl/Tk
684
685
686		reset_real_error_occurred :-
687		(retract(real_error_occurred) -> true ; true),
688		(retract(warning_occurred) -> true ; true).
689
690		reset_errors :-
691		(reset_errors_but_not_scopes -> true
692		; format(user_error,'~n*** reset_errors_but_not_scopes failed!!~n',[]),
693		fail % something really bad happened
694		),
695		reset_error_limit_reached,
696		reset_error_scopes. % call if you want to start again at a fresh top-level, without error scopes
697		reset_errors_but_not_scopes :-
698		reset_real_error_occurred,
699		retractall(logged_error_hash(_,_,_,_,_)),
700		retractall(logged_message(_,_,_,_)),
701		reset_error_spans,
702		clear_error_context.
703
704		reset_error_span_if_required :-
705		(logged_error_hash(_,_,_,_,_) -> true
706		; retractall(logged_error_spans(_,_))).
707
708		reset_error_spans :-
709		retractall(logged_error_spans(_,_)),
710		retractall(saved_subsidiary_span_pos(_,_,_,_)).
711
712		wd_error_occured :-
713		test_error_occurred(well_definedness_error).
714
715		clear_wd_errors :-
716		clear_errors_with_source(well_definedness_error).
717		clear_errors_with_source(Source) :-
718		retractall(logged_error_spans(Source,_)),
719		retractall(logged_error_hash(_,Source,_S1,_TContext1,_Span1)),
720		retractall(logged_message(Source,_,_,_)),
721		(logged_error_hash(_,_Source2,_S2,_TContext2,_Span2) -> true
722		; reset_real_error_occurred).
723
724		print_error_span(Span) :- print_error_span(Span,error).
725		print_error_span(unknown,_) :- !.
726		print_error_span(none,_) :- !. % from Rodin
727		print_error_span([],_) :- !. % empty info list
728		print_error_span(Span,Kind) :-
729		extract_span_description(Span,PosMsg), !, % also detects info lists
730		print_error(Kind,PosMsg).
731		print_error_span(b(E,T,I),Kind) :-
732		translate_bexpr(b(E,T,I),S),!,
733		print_error(Kind,S).
734		print_error_span(span_predicate(P,_,_),Kind) :- translate_bexpr(P,S),!,
735		% can happen in Event-B when no position info can be extracted
736		print_error(Kind,S).
737		print_error_span(List,Kind) :- List = [_|_], % info list which was not recognised; probably Event-B mode
738		debug_mode(off),
739		!,
740		include(useful_info,List,UsefulList), % only show useful infos
741		(UsefulList = [] -> true
742		; print_error(Kind,UsefulList)).
743		print_error_span(Span,Kind) :- print_error(Kind,Span). % span not recognized !
744
745		useful_info(section(_)).
746		useful_info(used_ids(_)).
747
748
749		translate_bexpr(P,S) :-
750		(debug_mode(on) -> Lim=3000 ; Lim=1000),
751		translate:translate_subst_or_bexpr_with_limit(P,Lim,S).
752
753		% the same, but not using user_error and red and only printing when span recognised
754		% more detailed than translate:print_span
755		print_message_span(unknown) :- !.
756		print_message_span(Span) :-
757		extract_span_description(Span,PosMsg), !, print(PosMsg).
758		print_message_span(_). % span not recognized !
759
760		% try and extract a string (aka atom) describing the position
761		extract_span_description(Span,PosMsg) :- extract_span_description_with_opts(Span,PosMsg,[]).
762
763		extract_span_description_with_opts(span_predicate(P,_,_),PosMsg,Opts) :- !,
764		extract_span_description_with_opts(P,PosMsg,Opts).
765		extract_span_description_with_opts(b(E,_,I),PosMsg,Opts) :- !,
766		(extract_span_description_with_opts(I,PosMsg,Opts) -> true
767		; first_sub_expr(E,A) -> extract_span_description_with_opts(A,PosMsg,Opts)).
768		extract_span_description_with_opts(Span,PosMsg,Opts) :-
769		extract_line_col(Span,StartLine,StartCol,EndLine,EndCol),!,
770		(member(compact_pos_info,Opts) -> Compact=true ; Compact=false),
771		(empty_line_col(StartLine,StartCol,EndLine,EndCol)
772		-> POS = ['Unknown position'|POS2]
773		; Compact=true
774		-> POS = ['(Line:',StartLine,',Col:',StartCol|POS2]
775		; POS = ['Line: ',StartLine,' Column: ',StartCol,
776		' until Line: ',EndLine,' Column: ',EndCol|POS2]
777		),
778		(extract_file_name_with_opts(Span,Filename,Opts)
779		-> (Compact=false -> POS2 = [' in file: ',Filename|POS3] ; POS2 = [',File:',Filename,')'|POS3])
780		; (Compact=false -> POS2 = POS3 ; POS2 = [')'|POS3])
781		),
782		(extract_additional_pos_and_descr(Span,_,ContextMsg,Opts)
783		-> (member(inner_context_separator(WITHIN,_),Opts) -> true ; WITHIN = ' within '),
784		POS3 = [WITHIN,ContextMsg] ; POS3=[]),
785		ajoin(POS,PosMsg).
786		extract_span_description_with_opts(Span,PosMsg,_Opts) :-
787		extract_symbolic_span_desc(Span,Symbolic),!,
788		PosMsg=Symbolic.
789		extract_span_description_with_opts(Span,PosMsg,Opts) :-
790		% try if we have an unknown position with a known context (e.g., pos_context(unknown,call_stack(...))
791		extract_additional_pos_and_descr(Span,_,ContextMsg,Opts),!,
792		%POS = ['Unknown position within ',ContextMsg],
793		POS = ['Within ',ContextMsg],
794		ajoin(POS,PosMsg).
795		% Note: Atom Plugin is quite sensitive to above error message and capitalization
796		% (https://github.com/wysiib/language-b-eventb)
797
798		extract_symbolic_span_desc(Span,PosMsg) :-
799		extract_symbolic_label_pos(Span,Symbolic),!,
800		% TO DO: we could try and find section for Rodin
801		ajoin(['@label: ',Symbolic],PosMsg).
802
803
804		% detect if a position is empty; Line 0, Column -1 .. Line 0, Column -2 used for non available Library Definition files
805		% happens, e.g., when typing CHOOSE({1}\{1}) in REPL
806		empty_line_col(0,N1,0,N2) :- integer(N1), integer(N2), N1>N2.
807
808		assert_true(Code) :-
809		(call(Code) -> true ; add_internal_error('Assertion failed: ',Code)).
810
811		add_error_fail(Source,ErrMsg, ErrTerm) :- add_error_and_fail(Source,ErrMsg, ErrTerm).
812		add_error_and_fail(Source,ErrMsg, ErrTerm) :- add_error(Source,ErrMsg, ErrTerm),fail.
813		add_error_and_fail(Source,ErrMsg) :- add_error(Source,ErrMsg),fail.
814
815		% add_error/2, add_error/3 and add_error/4
816		add_error(Source,ErrMsg) :- add_error4(Source,ErrMsg, '',unknown).
817		add_error(Source,ErrMsg, ErrTerm) :- add_error4(Source,ErrMsg, ErrTerm,unknown).
818		add_error(Source,ErrMsg,ErrTerm,Span) :- add_error4(Source,ErrMsg,ErrTerm,Span).
819
820		add_error4(Source,ErrMsg,ErrTerm,Span) :-
821		assert_real_error_occurred(Source),
822		combine_msg_and_error_term(ErrMsg,ErrTerm,Span,S),
823		add_error_or_warning(Source,S,Span).
824
825		%:- use_module(translate, [translate_error_term/2, translate_context/2]).
826		combine_msg_and_error_term(Msg,ErrTerm,_,Res) :- ErrTerm=='', !, Res=Msg.
827		combine_msg_and_error_term(ErrMsg,ErrTerm,Span,S) :-
828		string_concatenate(ErrMsg,' ',ST),
829		safe_translate_error_term(ErrTerm,Span,RString),
830		string_concatenate(ST,RString,S).
831
832
833		:- dynamic show_error_source/0.
834		show_error_source. % True if error source and span to be printed
835		turn_show_error_source_on :- (show_error_source -> true ; assertz(show_error_source)).
836		turn_show_error_source_off :- retractall(show_error_source).
837
838		trace_if_user_wants_it :- (preferences:get_preference(trace_upon_error,true) -> safe_trace ; true).
839
840		% try Prolog's trace; if this fails (compiled code), then ask user for input.
841		safe_trace :- translate:install_b_portray_hook,
842		catch(trace, error(existence_error(_,_),_), type_to_continue).
843
844		:- dynamic do_not_interrupt_user_anymore/0.
845
846		type_to_continue :- do_not_interrupt_user_anymore,!.
847		type_to_continue :- format(user_output,'(type <RETURN> to continue, z<RETURN> to zip) ===> ',[]),
848		read_line(user_input,X),
849		(zip(X) -> assertz(do_not_interrupt_user_anymore) ; true).
850
851		zip([122|_]). %starts with z
852
853
854		print_error_source(well_definedness_error) :- !,print_error('A well-definedness error occured !').
855		print_error_source(warning(Source)) :- show_error_source,!,
856		format_error_with_nl('~n! A warning occurred (source: ~w) !',[Source]).
857		print_error_source(internal_error(Source)) :- show_error_source,!,
858		flush_output, % internal error should not happen; be sure to flush all other pending outputs so that we can see where it happened
859		format_error_with_nl('~n! An internal error occurred (source: ~w) !',[Source]).
860		print_error_source(Source) :- show_error_source,!,
861		format_error_with_nl('~n! An error occurred (source: ~w) !',[Source]).
862		print_error_source(_).
863
864		print_error_context(Kind,Context) :- ((Context = '' ; \+show_error_source) -> true ; print_error(Kind,Context)).
865
866		print_error(message,Term) :- !, print_message_on_stream(user_output,[blue],Term).
867		print_error(_,Term) :- print_error(Term).
868
869		safe_translate_error_term(ErrTerm,Span,RString) :-
870		temporary_set_preference(expand_avl_upto,5,CHNG),
871		translate:translate_error_term(ErrTerm,Span,RString),
872		reset_temporary_preference(expand_avl_upto,CHNG).
873
874		safe_translate_context(Result) :-
875		% avoid infinite loop when error occurs inside translate_context
876		current_context(Context),
877		!,
878		call_cleanup(
879		(temporary_set_preference(expand_avl_upto,4,CHNG),
880		set_error_context(translate_context),
881		(translate:translate_context(Context,TContext) -> true ; TContext=Context)
882		),
883		(reset_temporary_preference(expand_avl_upto,CHNG),
884		restore_error_context(Context))),
885		Result=TContext.
886		safe_translate_context(''). % no context
887
888		is_optional_error_or_warning(warning(Src),warning,Src) :- !, optional_error_or_warning(Src).
889		is_optional_error_or_warning(Src,error,Src) :- optional_error_or_warning(Src).
890
891		do_not_print_error(well_definedness_error) :-
892		preferences:preference(do_not_print_wd_errors,true).
893
894		add_error_or_warning(Source,ErrMsg,Span) :-
895		safe_translate_context(Context),
896		reset_error_span_if_required,
897		simplify_span(Span,SSpan), % for better hashing, assertz, retract
898		assertz_logged_error_if_new(Source,ErrMsg,Context,SSpan,New),
899		log_error_or_msg(Source,ErrMsg,SSpan),
900		(New=false -> true
901		; is_optional_error_or_warning(Source,Kind,Src2) ->
902		(extract_span_description(SSpan,PosMsg) -> true ; PosMsg=''),
903		formatsilentmsg(user_output,'% Optional ~w ~w occured: ~w ~w~n',[Kind,Src2,ErrMsg,PosMsg]),
904		register_error_span(Source,SSpan,_)
905		; register_error_span(Source,SSpan,NewSrcSpan),
906		( do_not_print_error(Source) -> true
907		; NewSrcSpan=false,
908		error_limit_reached,
909		Source \= internal_error(_) % always show internal errors
910		-> true % this is not a new Source,SSpan combination and we have already several errors;
911		; print_error_source(Source),
912		print_error(ErrMsg),
913		print_error_context(error,Context),
914		print_error_span(SSpan)
915		),
916		trace_if_user_wants_it
917		).
918
919		% optionally log errors in to a ndsjon logfile
920		log_error_or_msg(Source,ErrMsg,Span) :- get_preference(error_log_file,LogFile),
921		LogFile \= '',
922		decompose_error_source(Source,Type,Src),
923		!,
924		ndjson_log(Type,Src,ErrMsg,Span,LogFile).
925		log_error_or_msg(_,_,_).
926
927		% log error, warning or message to NDJSON log file
928		% Type is warning, error, info
929		:- use_module(tools_io,[intelligent_open/4]).
930		ndjson_log(Type,Src,ErrMsg,Span,LogFile) :-
931		force_extract_position_from_span(Span,Filename,StartLine,StartCol,EndLine,EndCol),
932		catch(intelligent_open(LogFile,append,S,[encoding(utf8)]), E,
933		(format(user_error,'~n*** Cannot open error log file: ~w~n*** Exception: ~w~n',[LogFile,E]),fail)),
934		!,
935		ndjson_write(S,Type,ErrMsg,Src,Filename,StartLine,StartCol,EndLine,EndCol),
936		(extract_additional_pos_and_descr(Span,SubPos,_Desc,[]),
937		extract_position_from_span(SubPos,Filename2,StartLine2,StartCol2,EndLine2,EndCol2),
938		ndjson_write(S,Type,ErrMsg,Src,Filename2,StartLine2,StartCol2,EndLine2,EndCol2),
939		fail
940		;
941		true
942		),
943		close(S).
944		ndjson_log(_,_,_,_,_).
945
946		% assign position to main file if we cannot extract the precise position
947		force_extract_position_from_span(Span,Filename,StartLine,StartCol,EndLine,EndCol) :-
948		extract_position_from_span(Span,Filename,StartLine,StartCol,EndLine,EndCol),!.
949		force_extract_position_from_span(_Span,Filename,StartLine,StartCol,EndLine,EndCol) :-
950		bmachine:b_get_main_filenumber(MainFN),
951		get_filename(MainFN,Filename),!,
952		% generate a virtual position, so that global errors without position are shown in Atom, VSCode,...
953		StartLine=1,StartCol=1,EndLine=1,EndCol=1.
954		force_extract_position_from_span(_Span,Filename,StartLine,StartCol,EndLine,EndCol) :-
955		specfile:currently_opened_file_status(Filename,_),
956		StartLine='-1',StartCol='-1',EndLine='-1',EndCol='-1'.
957
958		%ndjson format http://ndjson.org
959		% one JSON term per line
960		:- use_module(extrasrc(json_parser),[json_write_stream/2]).
961		ndjson_write(S,Type,ErrMsg,Src,Filename,StartLine,StartCol,EndLine,EndCol) :-
962		version:version_str(Version),
963		Term = json([type=string(Type), % Type is warning, error, info
964		message=string(ErrMsg),
965		reason=string(Src),
966		file=string(Filename),
967		start=json([line=number(StartLine),col=number(StartCol)]),
968		end=json([line=number(EndLine),col=number(EndCol)]),
969		version=string(Version)
970		]),
971		json_write_stream(S,Term), nl(S).
972
973		decompose_error_source(warning(Source),warning,Res) :- !, Res=Source.
974		decompose_error_source(internal_error(Source),internal_error,Res) :- !, Res=Source.
975		decompose_error_source(message(Source),information,Res) :- !, Res=Source. % mainly for NDJSON
976		decompose_error_source(Msg,error,Msg).
977
978
979		% the total number of errors since start; no way to reset this; useful for validation reports
980		% TO DO: maybe use counter extension; but tricky to get dependency and initialisation right
981		get_total_number_of_errors(X) :-
982		(bb_get(total_number_of_errors,R) -> X=R
983		; X=0).
984
985		inc_total_number_of_errors :-
986		(bb_get(total_number_of_errors,R)
987		-> R1 is R+1, bb_put(total_number_of_errors,R1)
988		; bb_put(total_number_of_errors,1)).
989
990
991		total_number_of_errors_at_last_reset(Res) :-
992		(bb_get(total_number_of_errors_at_last_reset,R) -> Res=R ; Res=0).
993
994		reset_error_limit_reached :-
995		bb_put(error_limit_reached_printed,false),
996		get_total_number_of_errors(T),
997		bb_put(total_number_of_errors_at_last_reset,T).
998
999		error_limit_reached :- bb_get(error_limit_reached_printed,true),!.
1000		error_limit_reached :- get_total_number_of_errors(Nr), Nr >= 100,
1001		total_number_of_errors_at_last_reset(Last), Delta is Nr-Last, Delta >= 100,
1002		format_error_with_nl('Error limit reached (total: ~w, delta: ~w); only printing new error source and locations!',[Nr,Delta]),
1003		bb_put(error_limit_reached_printed,true).
1004
1005		assert_warning_occured :-
1006		(preferences:get_preference(strict_raise_warnings,true)
1007		-> assert_real_error_occurred(warning)
1008		; warning_occurred -> true
1009		; assertz(warning_occurred)).
1010		assert_real_error_occurred(Source) :-
1011		(real_error_occurred -> true ; assertz(real_error_occurred)),
1012		inc_total_number_of_errors,
1013		assert_real_error_in_current_block(Source).
1014
1015		:- use_module(hashing,[term_depth_hash/3]).
1016		assertz_logged_error_if_new(Source,S,TContext,Span,New) :-
1017		% limit depth mainly for TContext/Span; avoiding generating many similar error messages with same msg
1018		% however, for WD errors often the msg varies (e.g. argument for function application); so this will not prevent a lot of errors
1019		term_depth_hash(logged_error_hash(Source,S,TContext,Span),4,Hash),
1020		(logged_error_hash(Hash,Source,S,TContext,Span)
1021		-> debug_println(repeated_error(Hash)),New=false
1022		; %print(new(Hash,Source,S,TContext,Span)),nl,
1023		assertz(logged_error_hash(Hash,Source,S,TContext,Span)),
1024		New=true).
1025
1026		logged_error(Source,S,TContext,Span) :- logged_error_hash(_Hash,Source,S,TContext,Span).
1027
1028		add_warning(Source,ErrMsg, ErrTerm) :-
1029		add_warning(Source,ErrMsg, ErrTerm,unknown).
1030		add_warning(Source,ErrMsg, ErrTerm,Span) :-
1031		safe_translate_error_term(ErrTerm,Span,RString),
1032		string_concatenate(ErrMsg,RString,S),
1033		assert_warning_occured,
1034		add_error_or_warning(warning(Source),S,Span).
1035		add_warning(Source,Message) :-
1036		assert_warning_occured,
1037		add_error_or_warning(warning(Source),Message,unknown).
1038
1039		% MESSAGES
1040
1041		% add message in debug mode
1042		add_debug_message(Source,ErrMsg, ErrTerm) :-
1043		add_debug_message(Source,ErrMsg, ErrTerm,unknown).
1044		add_debug_message(Source,ErrMsg, ErrTerm, Span) :-
1045		debug_mode(on),!,
1046		add_message(Source,ErrMsg, ErrTerm, Span).
1047		add_debug_message(_,_,_,_).
1048
1049
1050		% a predicate to flexibly call add_error, add_warning or add_message
1051		add_msg_warn_or_err(debug_message,Src,Msg,Term,Pos) :- !, add_debug_message(Src,Msg,Term,Pos).
1052		add_msg_warn_or_err(message,Src,Msg,Term,Pos) :- !, add_message(Src,Msg,Term,Pos).
1053		add_msg_warn_or_err(warning,Src,Msg,Term,Pos) :- !, add_warning(Src,Msg,Term,Pos).
1054		add_msg_warn_or_err(_Kind,Src,Msg,Term,Pos) :- add_error(Src,Msg,Term,Pos).
1055
1056		add_message(Source,ErrMsg, ErrTerm) :- /* same as add_error but does not add err msg */
1057		add_message(Source,ErrMsg, ErrTerm,unknown).
1058
1059		add_message(_,_, _,_Span) :- % Span=unknown,
1060		error_manager_silent_mode(on),!.
1061		add_message(Source,ErrMsg, ErrTerm,Span) :- /* same as add_error but does not add err msg */
1062		safe_translate_error_term(ErrTerm,Span,RString),
1063		string_concatenate(ErrMsg,RString,S),
1064		add_message_direct(Source, S),
1065		safe_translate_context(Context),
1066		print_error_context(message,Context),
1067		print_error_span(Span,message),
1068		log_error_or_msg(message(Source),S,Span),
1069		assertz(logged_message(Source,S,Context,Span)).
1070
1071		add_message(_,_) :- error_manager_silent_mode(on),!.
1072		add_message(Source,ErrMsg) :- add_message_direct(Source,ErrMsg).
1073
1074		add_message_direct(Source,ErrMsg) :-
1075		(show_error_source -> format_with_colour(user_output,[light_gray],'! Message (source: ~w):~n',[Source]) ; true),
1076		print_error(message,ErrMsg).
1077
1078
1079		% adds a list of errors with position information
1080		% [error(Msg,Pos)] or [warning(Msg,Pos)...]
1081		no_real_perror_occurred([]).
1082		no_real_perror_occurred([warning(_,_)|T]) :- no_real_perror_occurred(T).
1083
1084		add_all_perrors(Errors) :- add_all_perrors(Errors,[],bmachine).
1085		add_all_perrors(Errors,Files) :- add_all_perrors(Errors,Files,bmachine).
1086		add_all_perrors(Errors,Files,Context) :- add_all_perrors(Errors,Files,Context,0,100,error).
1087		add_all_perrors(Errors,Files,Context,WarnOrErr) :-
1088		add_all_perrors(Errors,Files,Context,0,100,WarnOrErr).
1089
1090		add_all_perrors([],_,_,_,_,_).
1091		add_all_perrors([H|Rest],_Filenames,ContextOfError,NrOfErrors,MaxErrors,WarnOrErr) :-
1092		NrOfErrors >= MaxErrors,!,
1093		length([H|Rest],Len),
1094		add_msg_warn_or_err(WarnOrErr,ContextOfError,
1095		'Reached maximium number of errors; number of errors not reported: ',
1096		Len,unknown).
1097		add_all_perrors([Error|Rest],Filenames,ContextOfError,NrOfErrors,MaxErrors,WarnOrErr) :-
1098		get_perror(Error,ParseErrOrWarn,Msg,Pos),
1099		extract_perror_pos(Pos,Filenames,NewPos),
1100		(ParseErrOrWarn == warning -> add_warning(ContextOfError,Msg,'',NewPos)
1101		; ParseErrOrWarn = internal_error -> add_internal_error(ContextOfError,Msg,'',NewPos)
1102		; add_msg_warn_or_err(WarnOrErr,ContextOfError,Msg,'',NewPos)),
1103		N1 is NrOfErrors+1,
1104		add_all_perrors(Rest,Filenames,ContextOfError,N1,MaxErrors,WarnOrErr).
1105
1106		extract_perror_pos(Pos,Filenames,ResPOS) :-
1107		get_position_row_cols(Pos,Srow,Scol,Erow,Ecol),
1108		get_position_filenumber(Pos,Filenumber),!,
1109		( get_filename(Filenumber,Filenames,Filename)
1110		%Ecol1 is Ecol+1,
1111		-> ResPOS = src_span(Filenumber,Filename,Srow,Scol,Erow,Ecol,[],[])
1112		% ; Filenumber = -1, Filenames=[FN] -> % just a single filename, e.g., in VisB parsing
1113		% % TODO: we need to adjust line and column numbers using a reference position
1114		% POS = src_position_with_filename_and_ec(Srow,Scol,Erow,Ecol,FN)
1115		; ResPOS = src_span(Srow,Scol,Erow,Ecol,[],[])
1116		).
1117		extract_perror_pos(pos(Srow,Scol,Filename),Files,POS) :- !, % deprecated ?
1118		adapt_null_file_name(Filename,Files,Filename2),
1119		S1 is Scol+0, % zero width span
1120		POS = src_position_with_filename_and_ec(Srow,Scol,Srow,S1,Filename2).
1121		extract_perror_pos(pos(Srow,Scol,Erow,Ecol,Filename),Files,POS) :- !,
1122		adapt_null_file_name(Filename,Files,Filename2),
1123		%Ecol1 is Ecol+1,
1124		POS = src_position_with_filename_and_ec(Srow,Scol,Erow,Ecol,Filename2).
1125		extract_perror_pos(pos(Srow,Scol),_,POS) :- !, print(deprecated_pos(Srow,Scol)),nl,
1126		POS = src_position(Srow,Scol,none,1).
1127		extract_perror_pos(Pos,_,Pos).
1128
1129		% adapt filename
1130		adapt_null_file_name(null,[File],Res) :-
1131		!, % the error is not associated to a given file, but we have a file list with just a single file;
1132		% occurs e.g. when parsing VisB JSON files
1133		Res=File.
1134		adapt_null_file_name(F,_,F).
1135
1136		get_perror(error(Msg,Pos),error,Msg,Pos) :- !.
1137		get_perror(internal_error(Msg,Pos),internal_error,Msg,Pos) :- !.
1138		get_perror(warning(Msg,Pos),warning,Msg,Pos) :- !.
1139		get_perror(M,_,M,unknown) :- format(user_error,'*** unknown perror: ~w~n',[M]).
1140
1141		% version without list of filenames
1142		get_filename(Filenumber,Filename) :-
1143		bmachine:b_get_all_used_filenames(FN),
1144		get_filename(Filenumber,FN,Filename).
1145
1146		get_filename(Filenumber,Filenames,Filename) :-
1147		number(Filenumber),!,
1148		nth1(Filenumber,Filenames,Filename).
1149		get_filename(N,F,R) :-
1150		add_internal_error('Cannot get filename: ',get_filename(N,F,R)),
1151		N=1,F=[R|_]. % return first file if possible
1152
1153		% check if error/warning occured and retract matching error/warning
1154		get_error_with_span(Source,ErrMsg,Span) :-
1155		retract(logged_error_hash(_Hash,Source,ErrMsg,_Context,Span)).
1156		get_error(Source,ErrMsg) :-
1157		retract(logged_error_hash(_,Source,ErrMsg,_,_)).
1158		get_warning(Source,ErrMsg) :-
1159		retract(logged_error_hash(_,warning(Source),ErrMsg,_,_)).
1160
1161		% now the same without actually retracting the error/warning:
1162		check_error_occured(Source,ErrMsg) :- logged_error(Source,ErrMsg,_,_).
1163		check_warning_occured(Source,ErrMsg) :- logged_error(warning(Source),ErrMsg,_,_).
1164
1165		get_next_error_or_warning(Msg) :- get_error_or_message(_Src,Type,Msg),
1166		Type \= message. % retract message, but do not return it
1167		get_error_or_message(Source,Type,Msg) :-
1168		retract_logged_error_or_message(Source,Type,ErrMsg,Context,Span),
1169		(extract_line_col(Span,StartLine,StartCol,EndLine,EndCol)
1170		-> POS = ['\n ### Line: ',StartLine,', Column: ',StartCol|POS1],
1171		((StartLine,StartCol) \= (EndLine,EndCol)
1172		-> (StartLine=EndLine -> POS1 = [' until ',EndCol|POS2]
1173		; POS1 = ['\n ### until Line: ',EndLine,', Column: ',EndCol|POS2]
1174		)
1175		; POS1 = POS2
1176		),
1177		(extract_additional_description(Span,CMsg)
1178		-> POS2 = ['\n ### within: ',CMsg,'\n\n']
1179		; POS2 = ['\n\n']
1180		),
1181		(extract_relative_file_name(Span,Filename)
1182		-> PosMsg = ['\n ### File: ',Filename | POS]
1183		; PosMsg = POS
1184		),
1185		tools:ajoin(PosMsg,EndStr)
1186		; extract_symbolic_span_desc(Span,CMsg)
1187		-> tools:ajoin(['\n ### ',CMsg,'\n\n'],EndStr)
1188		; EndStr = '\n\n'
1189		),
1190		(empty_error_context(Context)
1191		-> string_concatenate(ErrMsg,EndStr,S0)
1192		; safe_translate_error_term(Context,Span,CString),
1193		string_concatenate(CString,EndStr,CString2),
1194		string_concatenate('\n',CString2,CString3), % prefix used to be ': Context ='
1195		string_concatenate(ErrMsg,CString3,S0)
1196		),
1197		(debug_mode(off) -> Msg = S0
1198		; decompose_error_source(Source,_,SrcAtom),
1199		string_concatenate(SrcAtom,': ',S1),
1200		string_concatenate(S1,S0,Msg)
1201		).
1202
1203		empty_error_context('').
1204		empty_error_context('?ctx?').
1205
1206
1207		% retract an error
1208		retract_logged_error_or_message(Source,Type,ErrMsg,Context,Span) :- Type \== message,
1209		retract(logged_error_hash(_Hash,Source,ErrMsg,Context,Span)),
1210		(Source = warning(_) -> Type=warning
1211		; Source = internal_error(_) -> Type=internal_error
1212		; Type=error).
1213		retract_logged_error_or_message(message(Source),message,ErrMsg,Context,Span) :-
1214		retract(logged_message(Source,ErrMsg,Context,Span)).
1215
1216
1217		get_error_with_span_info(FullErrMsg,Type,ErrLocations) :-
1218		retract_logged_error_or_message(_Source,Type,ErrMsg,Context,Span),
1219		(empty_error_context(Context) -> FullErrMsg=ErrMsg
1220		; safe_translate_error_term(Context,Span,CString),
1221		ajoin([ErrMsg,'\n',CString],FullErrMsg)
1222		),
1223		findall( error_span(Filename,StartLine,StartCol,EndLine,EndCol),
1224		extract_position_from_span(Span,Filename,StartLine,StartCol,EndLine,EndCol),
1225		ErrLocations).
1226		get_error_with_span_and_context(ErrMsg,Type,ErrLocations,GlobalContext,SpanContext) :-
1227		% Global context: top-level info about what ProB was doing
1228		% Local SpanContext: definition call hierarchy or call stack
1229		retract_logged_error_or_message(_Source,Type,ErrMsg,GlobalContext,Span),
1230		(extract_additional_description(Span,SpanContext) -> true ; SpanContext=''),
1231		findall( error_span(Filename,StartLine,StartCol,EndLine,EndCol),
1232		extract_position_from_span(Span,Filename,StartLine,StartCol,EndLine,EndCol),
1233		ErrLocations).
1234
1235		extract_position_from_span(Span,Filename,StartLine,StartCol,EndLine,EndCol) :-
1236		extract_line_col(Span,StartLine,StartCol,EndLine,EndCol),
1237		(extract_file_name(Span,FName) -> Filename=FName ; Filename='').
1238
1239		% Tcl/Tk interface of SICStus cannot deal with certain strange Unicode symbols
1240		% see prob_examples/public_examples/B/Puzzles/LogicQuestion.mch where code 55349 appears
1241		tk_escape(Atom,EAtom) :- atom(Atom),!,
1242		atom_codes(Atom,C),
1243		maplist(tk_escape_code,C,EC),
1244		atom_codes(EAtom,EC).
1245		tk_escape(list(L),list(EL)) :- !, maplist(tk_escape,L,EL).
1246		tk_escape(X,X).
1247
1248		tk_escape_code(StrangeUnicode,Res) :-
1249		StrangeUnicode > 55000,!, % not sure what the limit should be here
1250		Res = 9633. % white box
1251		tk_escape_code(Code,Code).
1252
1253		tcltk_get_all_errors(Limit,list(ERes),NrErrorsShown,NrErrors) :-
1254		get_all_errors(All),
1255		length(All,NrErrors),
1256		(NrErrors =< Limit -> Res = All, NrErrorsShown = NrErrors
1257		; prefix_length(All,Res,Limit), % truncate
1258		NrErrorsShown = Limit
1259		),
1260		tk_escape(list(Res),list(ERes)).
1261
1262
1263		get_all_errors(All) :-
1264		findall(Err,get_next_error_or_warning(Err),All),
1265		All \= [],
1266		clear_error_context.
1267
1268		get_all_errors_and_clear(All) :-
1269		findall(Err,get_next_error_or_warning(Err),All),
1270		reset_errors_but_not_scopes,
1271		All \= [].
1272		get_all_errors_and_reset(All) :-
1273		findall(Err,get_next_error_or_warning(Err),All),
1274		reset_errors, % fresh top-level
1275		All \= [].
1276		get_all_errors_with_span_info_and_reset(All) :-
1277		findall(error(ErrMsg,ErrType,ErrLocations),
1278		get_error_with_span_info(ErrMsg,ErrType,ErrLocations),All),
1279		reset_errors.
1280		get_all_errors_with_span_and_context_and_reset(All) :-
1281		findall(error(ErrMsg,ErrType,ErrLocations,GlobalContext,SpanContext),
1282		get_error_with_span_and_context(ErrMsg,ErrType,ErrLocations,GlobalContext,SpanContext),All),
1283		reset_errors.
1284
1285
1286		error_or_warning_occured :- logged_error(_Source,_,_,_),!.
1287		test_error_occurred(Source) :- logged_error(Source,_,_,_),real_error_occurred,!.
1288
1289		%:- use_module(library(lists),[length/2]). length is builtin
1290
1291		count_errors_occurred(Source,NrOfErrors) :-
1292		findall(1,logged_error(Source,_,_,_),Ls),
1293		length(Ls,NrOfErrors).
1294
1295		display_error_statistics :- findall(Source,logged_error(Source,_,_,_),L),
1296		count_occurences(L,Occ),
1297		format('Error manager summary: ~w~n',[Occ]).
1298
1299
1300
1301
1302		% ERROR CONTEXTS
1303		% --------------
1304
1305		/* add context information; will be added to any error messages */
1306		% Note: Each Prolog module maintains its own blackboard for bb_get/bb_put
1307		set_error_context(Ctx) :- bb_put(error_manager_context,Ctx).
1308
1309		clear_error_context :- (bb_delete(error_manager_context,_) -> true ; true).
1310		% retractall with dynamic predicate seems to slow down
1311
1312		current_context(C) :- bb_get(error_manager_context,C).
1313
1314		get_error_context(C) :- (current_context(C) -> true ; C='?ctx?').
1315		print_error_context :- (safe_translate_context(R), R\='' -> print_error(error,R) ; true).
1316
1317		% restore an error context obtained by get_error_context
1318		restore_error_context('?ctx?') :- !, clear_error_context.
1319		restore_error_context(C) :- set_error_context(C).
1320
1321
1322		% -----------------
1323
1324		get_error_span(Source,Span) :-
1325		retract(logged_error_spans(Source,Span)).
1326
1327		% a way for external modules to register error locations, e.g., for display by Tcl/Tk HighlightSyntaxErrors
1328		register_error_span(Source,Span) :- register_error_span(Source,Span,_).
1329		register_error_span(_,unknown,New) :- !,New=false.
1330		register_error_span(Source,Span,New) :- logged_error_spans(Source,Span),!,New=false.
1331		register_error_span(Source,Span,New) :- assertz(logged_error_spans(Source,Span)),New=true.
1332
1333		get_error_span_linecol(Line,Col,EndLine,EndCol) :- get_error_span_linecol(_Source,Line,Col,EndLine,EndCol).
1334		get_error_span_linecol(Source,Line,Col,EndLine,EndCol) :-
1335		get_error_span(Source,Span), % looks at logged_error_spans and retracts
1336		extract_line_col(Span,Line,Col,EndLine,EndCol).
1337
1338		% gets repeatedly called from Tcl/Tk to get all error locations
1339		tk_get_error_span_linecol_for_main_file(Line,Col,EndLine,EndCol) :-
1340		retract(saved_subsidiary_span_pos(Line,Col,EndLine,EndCol)).
1341		tk_get_error_span_linecol_for_main_file(Line,Col,EndLine,EndCol) :-
1342		get_error_span(_Source,Span), % looks at logged_error_spans and retracts even if not in main file !
1343		(extract_primary_line_col_for_main_file(Span,Line,Col,EndLine,EndCol)
1344		-> (extract_additional_pos_and_descr(Span,SubPos,_,[]),
1345		extract_line_col_for_main_file(SubPos,SLine,SCol,SEndLine,SEndCol),
1346		assertz(saved_subsidiary_span_pos(SLine,SCol,SEndLine,SEndCol)), % store for later lookup
1347		fail
1348		; true)
1349		; % try finding subsidiary position which is in main file:
1350		extract_additional_pos_and_descr(Span,SubPos,_,[]),
1351		extract_line_col_for_main_file(SubPos,Line,Col,EndLine,EndCol)
1352		).
1353
1354
1355		% just like get_error_span_linecol but does not retract and gets Filename
1356		check_error_span_file_linecol(Source, FullFilename,Line,Col,EndLine,EndCol) :-
1357		logged_error_spans(Source,Span),
1358		(extract_file_line_col(Span,FullFilename,Line,Col,EndLine,EndCol)
1359		;
1360		extract_additional_pos_and_descr(Span,SubPos,_,[]),
1361		extract_file_line_col(SubPos,FullFilename,Line,Col,EndLine,EndCol)).
1362
1363		extract_file_line_col(Span,FullFilename,Line,Col,EndLine,EndCol) :-
1364		(extract_file_number_and_name(Span,_,FullFilename)
1365		-> true
1366		; FullFilename = unknown), % e.g. something like src_span/6; should we return unknown('?')
1367		extract_line_col(Span,Line,Col,EndLine,EndCol).
1368
1369		% try and extract symbolic (Rodin label) information
1370		extract_symbolic_label_pos(span_predicate(P,_,_),PosMsg) :- !,
1371		extract_symbolic_label_pos(P,PosMsg).
1372		extract_symbolic_label_pos(b(E,_,I),PosMsg) :- !,
1373		(extract_symbolic_label_pos(I,PosMsg) -> true
1374		; first_sub_expr(E,A) -> extract_symbolic_label_pos(A,PosMsg)).
1375		extract_symbolic_label_pos([],_) :- !,fail.
1376		extract_symbolic_label_pos([H|T],SymbolicPos) :- !,
1377		posinfo_member(N,[H|T]),
1378		extract_symbolic_label_pos(N,SymbolicPos),!.
1379		extract_symbolic_label_pos(rodinpos(Label,_),Label). % see also get_texpr_labels in bsyntaxtree
1380		extract_symbolic_label_pos(rodinpos(Model,Name,_),Label) :- ajoin([Model,':',Name],Label).
1381		extract_symbolic_label_pos(rodin_derived_context_pos(Model,Context,LabelName),Label) :-
1382		ajoin([Model,'.',Context,':',LabelName],Label).
1383		extract_symbolic_label_pos(label(Label),Label).
1384
1385		% just extract label, without model
1386		extract_symbolic_label(span_predicate(P,_,_),PosMsg) :- !,
1387		extract_symbolic_label(P,PosMsg).
1388		extract_symbolic_label(b(E,_,I),PosMsg) :- !,
1389		(extract_symbolic_label(I,PosMsg) -> true
1390		; first_sub_expr(E,A) -> extract_symbolic_label(A,PosMsg)).
1391		extract_symbolic_label([H|T],SymbolicPos) :- !,
1392		posinfo_member(N,[H|T]),
1393		extract_symbolic_label(N,SymbolicPos),!.
1394		extract_symbolic_label(rodinpos(Label,_),Label) :- Label \= []. % see also get_texpr_labels in bsyntaxtree
1395		extract_symbolic_label(rodinpos(_Model,Label,_),Label) :- Label \= [].
1396		extract_symbolic_label(rodin_derived_context_pos(_Model,_Context,Label),Label) :- Label \= [].
1397		extract_symbolic_label(label(Label),Label) :- Label \= [].
1398
1399		% quickly try and simplify a span, e.g., before asserting it in a fact (as it may become big)
1400		simplify_span(b(E,_,Infos),Res) :- !,
1401		(definite_posinfo_member(N,Infos) -> Res=N
1402		; first_sub_expr(E,A) -> simplify_span(A,Res)
1403		; Res=unknown).
1404		simplify_span(Infos,Res) :- Infos = [_|_],!,
1405		(definite_posinfo_member(N,Infos) -> Res=N ; Res=unknown).
1406		simplify_span(span_predicate(P,_,_),Res) :- !, simplify_span(P,Res).
1407		simplify_span(S,S).
1408
1409		% choose first sub-expression in case top-expression has no position info (it would be better if extract_info/3 in bsyntaxtree merges position info)
1410		first_sub_expr(negation(A,_),A).
1411		first_sub_expr(conjunct(A,_),A).
1412		first_sub_expr(disjunct(A,_),A).
1413		first_sub_expr(implication(A,_),A).
1414		first_sub_expr(equivalence(A,_),A).
1415		first_sub_expr(exists([A|_],_),A).
1416		first_sub_expr(forall([A|_],_),A).
1417		first_sub_expr(let_predicate([A|_],_,_),A).
1418		first_sub_expr(let_expression([A|_],_,_),A).
1419		first_sub_expr(let_expression_global([A|_],_,_),A).
1420		first_sub_expr(sequence([A|_]),A).
1421		first_sub_expr(parallel([A|_]),A).
1422		first_sub_expr(assign([A|_],_),A).
1423		first_sub_expr(var([A|_],_),A).
1424		first_sub_expr(equal(A,_),A).
1425		first_sub_expr(not_equal(A,_),A).
1426		first_sub_expr(function(A,_),A).
1427		first_sub_expr(less(A,_),A).
1428		first_sub_expr(less_equal(A,_),A).
1429		% TO DO: use bsyntaxtree:syntaxtraversion
1430
1431		:- use_module(tools_positions,[get_position_filenumber/2, get_position_row_cols/5]).
1432
1433		% extract_line_col(S,_,_,_,_) :- print(extract(S)),nl,fail.
1434		extract_line_col(Var,_,_,_,_) :- var(Var),!, write(variable_span(Var)),nl,
1435		fail.
1436		extract_line_col([],_,_,_,_) :- !,fail.
1437		extract_line_col([H|T],Srow,Scol,Erow,Ecol) :- !,
1438		posinfo_member(N,[H|T]),
1439		extract_line_col(N,Srow,Scol,Erow,Ecol),!.
1440		extract_line_col(closure(_,_,B),Srow,Scol,Erow,Ecol) :- !,
1441		extract_line_col(B,Srow,Scol,Erow,Ecol).
1442		extract_line_col(b(E,_,Infos),Srow,Scol,Erow,Ecol) :- !,
1443		(extract_line_col(Infos,Srow,Scol,Erow,Ecol) -> true
1444		; first_sub_expr(E,A) -> extract_line_col(A,Srow,Scol,Erow,Ecol)).
1445		extract_line_col(span_predicate(P,_,_),Srow,Scol,Erow,Ecol) :- !,
1446		extract_line_col(P,Srow,Scol,Erow,Ecol).
1447		extract_line_col(PosTerm,Srow,S1,Erow,E1) :-
1448		get_position_row_cols(PosTerm,Srow,Scol,Erow,Ecol),
1449		number(Srow),
1450		% _Filenumber is an index into list provided by b_get_all_used_filenames
1451		number(Scol), number(Erow), number(Ecol),
1452		!,
1453		(Scol>0 -> S1 is Scol-1 ; S1 = Scol), % the BParser starts column numbering at 1
1454		(Ecol>0 -> E1 is Ecol-1 ; E1 = Ecol).
1455		%E1=Ecol. %Somehow the Ecol info is ok for Tcl
1456		extract_line_col(unknown,_,_,_,_) :- !,fail.
1457		extract_line_col(pos_context(A,_,_),StartLine,StartCol,EndLine,EndCol) :- !,
1458		extract_line_col(A,StartLine,StartCol,EndLine,EndCol).
1459		extract_line_col(src_span(_Filenr,_Filename,StartLine,SC,EndLine,EC,Offset,LenBytes),StartLine,StartCol,EndLine,EndCol)
1460		:- !,
1461		extract_line_col(src_span(StartLine,SC,EndLine,EC,Offset,LenBytes),StartLine,StartCol,EndLine,EndCol).
1462		extract_line_col(src_span(SL,SC,EL,EC,_Off,_LenBytes),StartLine,StartCol,EndLine,EndCol) :- !,
1463		StartLine=SL, StartCol is SC-1,
1464		EndLine = EL, EndCol is EC-1.
1465		%:- !, StartCol is SC-1, EndCol is StartCol+LenBytes, EndLine = StartLine. %% fix because new library generates erroneous EndLine/EndCol info
1466		% EndCol is EC-1.
1467		extract_line_col(span_info(_Info,Span),SL,SC,EL,EC) :- !, extract_line_col(Span,SL,SC,EL,EC).
1468		extract_line_col(src_span_operator(SP1,SP2),SL,SC,EL,EC) :- !,
1469		(extract_line_col(SP1,SL,SC,EL,EC) ; extract_line_col(SP2,SL,SC,EL,EC)).
1470		extract_line_col(multi_span(SL,SC,EL,EC,_Off,_Len,TAIL),StartLine,StartCol,EndLine,EndCol) :- !,
1471		% TO DO: replace by multi_span/2
1472		( StartLine = SL, StartCol is SC-1,
1473		EndLine = EL, EndCol is EC-1
1474		; extract_line_col(TAIL,StartLine,StartCol,EndLine,EndCol)).
1475		%extract_line_col(multi_span(A,B),StartLine,StartCol,EndLine,EndCol) :- !,
1476		% (extract_line_col(A,StartLine,StartCol,EndLine,EndCol) ;
1477		% extract_line_col(B,StartLine,StartCol,EndLine,EndCol)).
1478		extract_line_col(src_position(StartLine,SC,_Off,LenBytes),StartLine,StartCol,EndLine,EndCol) :- !,
1479		StartCol is SC-1, EndCol is StartCol+LenBytes, EndLine is StartLine.
1480		extract_line_col(src_position_with_filename(StartLine,SC,LenBytes,_Filename),StartLine,StartCol,EndLine,EndCol) :-
1481		!,
1482		StartCol is SC-1, EndCol is StartCol+LenBytes, EndLine is StartLine.
1483		extract_line_col(src_position_with_filename_and_ec(SL,SC,EL,EC,_Fname),StartLine,StartCol,EndLine,EndCol) :-
1484		!,
1485		StartLine=SL,StartCol is SC-1,EndLine = EL, EndCol is EC-1.
1486		extract_line_col(lineCol(StartLine,StartCol),StartLine,StartCol,EndLine,EndCol) :- !,
1487		EndLine=StartLine, EndCol=StartCol.
1488		extract_line_col(span_context(Span,_),StartLine,StartCol,EndLine,EndCol) :- !,
1489		extract_line_col(Span,StartLine,StartCol,EndLine,EndCol).
1490		extract_line_col(Pos,_,_,_,_) :- is_symbolic_position(Pos),!,fail. % cannot extract line/col infos
1491		%extract_line_col(Struct,StartLine,StartCol,EndLine,EndCol) :-
1492		% is_argument_of_compound_term(Struct,Arg),
1493		% functor(Arg,FF,NN),functor(Struct,FS,NS), write(detected(FF,NN,in,FS,NS)),nl,trace,
1494		% /* recursively look for error spans inside */
1495		% extract_line_col(Arg,StartLine,StartCol,EndLine,EndCol),!.
1496		%extract_line_col(S,_,_,_,_) :- print('COULD NOT EXTRACT LINE/COL INFO: '), print(S),
1497		% functor(S,F,N), print(' '),print(F/N),nl,nl,fail.
1498
1499		%:- use_module(library(between),[between/3]).
1500		%is_argument_of_compound_term(Term,Arg) :- functor(Term,_,Arity),
1501		% between(1,Arity,ArgNr), arg(ArgNr,Term,Arg),
1502		% % this is quite dangerous, and possibly expensive
1503		% ground(Arg).
1504
1505		is_symbolic_position(rodinpos(_,_)).
1506		is_symbolic_position(rodinpos(_,_,_)).
1507		is_symbolic_position(rodin_derived_context_pos(_,_,_)).
1508		is_symbolic_position(label(_)).
1509
1510
1511		/* For TCL TK: extract all line_col information in one go and in 4 lists */
1512		extract_all_line_col(Span, StartLineList,StartColList,EndLineList,EndColList) :-
1513		findall(lc(SL,SC,EL,EC), extract_line_col(Span,SL,SC,EL,EC),All),
1514		%print(all(All,Span)),nl,
1515		split_lc(All,StartLineList,StartColList,EndLineList,EndColList).
1516
1517		split_lc([], [],[],[],[]).
1518		split_lc([lc(SL,SC,EL,EC)|T],[SL|T1],[SC|T2],[EL|T3],[EC|T4]) :-
1519		split_lc(T,T1,T2,T3,T4).
1520
1521		% TO DO: merge with line_col and in Tcl/Tk use info to highlight proper file !
1522
1523		% a version of extract_file_name with options:
1524		extract_file_name_with_opts(Pos,Filename,Opts) :- member(relative_file_name,Opts),!,
1525		extract_relative_file_name(Pos,Filename).
1526		extract_file_name_with_opts(Pos,Filename,Opts) :- member(tail_file_name,Opts),!,
1527		extract_tail_file_name(Pos,Filename).
1528		extract_file_name_with_opts(Pos,Filename,_) :-
1529		extract_file_name(Pos,Filename).
1530
1531		% TODO: maybe add a preference to always get full filename path (cf always_print_filename in translate)
1532		% TODO: do not show filename if there is only one file ?
1533		extract_relative_file_name(Pos,RelFilename) :-
1534		extract_file_name(Pos,Filename),
1535		(specfile:currently_opened_file_status(Main,_),
1536		tools:get_parent_directory(Main,MainDir),
1537		tools:gen_relative_path(Filename,MainDir,Rel)
1538		-> RelFilename = Rel
1539		; RelFilename = Filename).
1540		extract_file_name(Pos,Filename) :-
1541		extract_valid_file_number_and_name(Pos,_,Filename),
1542		Filename \=null. % Filename = null occurs in eval_strings !?
1543		extract_tail_file_name(Pos,Filename) :-
1544		extract_valid_file_number_and_name(Pos,_,FullFilename),
1545		tools:get_tail_filename(FullFilename,Filename).
1546		extract_subsidiary_tail_file_name(Pos,Filename) :-
1547		extract_valid_file_number_and_name(Pos,Nr,FullFilename),
1548		not_main_file(Nr,FullFilename),
1549		tools:get_tail_filename(FullFilename,Filename).
1550
1551		extract_valid_file_number_and_name(Pos,Nr,Filename) :-
1552		extract_file_number_and_name(Pos,Nr,Filename),
1553		valid_filename(Filename).
1554		valid_filename(F) :- atom(F). % not unknown(-1) which can come from REPL
1555		% should we detect null here?
1556
1557		% a version of extract_line_col which fails if the primary error location is not in the main file
1558		extract_primary_line_col_for_main_file(Span,Line,Col,EndLine,EndCol) :-
1559		\+((extract_file_number_and_name(Span,Nr,FullFilename),
1560		not_main_file(Nr,FullFilename))),
1561		extract_line_col(Span,Line,Col,EndLine,EndCol).
1562
1563		% a version of extract_line_col which fails if the error or subsidiary location is not in the main file
1564		extract_line_col_for_main_file(Span,Line,Col,EndLine,EndCol) :-
1565		(extract_file_number_and_name(Span,Nr,FullFilename),
1566		not_main_file(Nr,FullFilename)
1567		-> extract_additional_pos_and_descr(Span,SubPos,_,[]),
1568		extract_line_col_for_main_file(SubPos,Line,Col,EndLine,EndCol)
1569		; extract_line_col(Span,Line,Col,EndLine,EndCol)
1570		).
1571
1572		extract_file_number_and_name(V,_,_) :- var(V),!,fail.
1573		extract_file_number_and_name(value(_),_,_) :- !,fail.
1574		extract_file_number_and_name(pos_context(A,_,_), Filenumber,Filename) :- !,
1575		extract_file_number_and_name(A, Filenumber,Filename).
1576		extract_file_number_and_name(span_predicate(P,_,_), Filenumber,Filename) :- !,
1577		extract_file_number_and_name(P, Filenumber,Filename).
1578		extract_file_number_and_name(Pos, ResFileNr,Res) :-
1579		get_position_filenumber(Pos,Filenumber),!,
1580		(get_filename(Filenumber,Filename)
1581		-> ResFileNr=Filenumber,Res=Filename
1582		; ResFileNr=Filenumber,Res=unknown(Filenumber) % unknown(-1) which can come from REPL
1583		).
1584		extract_file_number_and_name(src_span(_,Filename,_,_,_,_,_,_), ResFileNr, Res) :- !,ResFileNr=unknown, Res=Filename.
1585		extract_file_number_and_name(src_span(_,_,_, _,_,_), _ResFileNr, _Res) :- !,fail. % src_span/6, No file stored
1586		extract_file_number_and_name(src_position_with_filename(_,_,_,Filename), ResFileNr, Res) :- !,ResFileNr=unknown,Res=Filename.
1587		extract_file_number_and_name(src_position_with_filename_and_ec(_,_,_,_,Filename), ResFileNr, Res) :- !,ResFileNr=unknown,Res=Filename.
1588		extract_file_number_and_name(section(RodinFilename), ResFileNr, Res) :- !,ResFileNr=unknown,Res=RodinFilename.
1589		extract_file_number_and_name([H|T],Filenumber,Filename) :- !,
1590		posinfo_member(Arg,[H|T]),
1591		extract_file_number_and_name(Arg,Filenumber,Filename),!.
1592		extract_file_number_and_name(closure(_,_,B),Filenumber,Filename) :- !,
1593		extract_file_number_and_name(B,Filenumber,Filename).
1594		extract_file_number_and_name(b(E,_,Infos),Filenumber,Filename) :- !,
1595		(extract_file_number_and_name(Infos,Filenumber,Filename) -> true
1596		; first_sub_expr(E,A) -> extract_file_number_and_name(A,Filenumber,Filename)).
1597		extract_file_number_and_name(span_context(Span,_),Filenumber,Filename) :- !,
1598		extract_file_number_and_name(Span,Filenumber,Filename).
1599		%extract_file_number_and_name(Struct,Filenumber,Filename) :-
1600		% /* recursively look for error spans inside */
1601		% is_argument_of_compound_term(Struct,Arg),
1602		% extract_file_number_and_name(Arg,Filenumber,Filename),!.
1603
1604		definite_posinfo_member(POS,Args) :- member(nodeid(POS),Args).
1605		posinfo_member(Arg,Args) :- % look for a nodeid(.) member
1606		(member(nodeid(POS),Args) -> Arg=POS). % no longer allow other members in lists ; member(Arg,Args)).
1607
1608		%:- use_module(bmachine,[b_get_all_used_filenames/1,b_get_main_filenumber/1]).
1609		position_is_not_in_main_file(Pos) :-
1610		get_position_filenumber(Pos,Filenumber),!, % B position info
1611		not_main_filenumber(Filenumber).
1612		position_is_not_in_main_file(src_span(_,Filename,_,_,_,_,_,_)) :- !,
1613		specfile:currently_opened_file_status(Main,_), Main \= Filename.
1614		position_is_not_in_main_file(src_position_with_filename(_,_,_,Filename)) :- !,
1615		specfile:currently_opened_file_status(Main,_), Main \= Filename.
1616		position_is_not_in_main_file(src_position_with_filename_ec(_,_,_,_,Filename)) :- !,
1617		specfile:currently_opened_file_status(Main,_), Main \= Filename.
1618		position_is_not_in_main_file(Struct) :- \+ atomic(Struct), Struct =.. [_|Args],
1619		/* recursively look for error spans inside */
1620		member(Arg,Args), position_is_not_in_main_file(Arg),!.
1621
1622
1623		not_main_file(Filenumber,_) :- number(Filenumber),!, % B Position info
1624		not_main_filenumber(Filenumber).
1625		not_main_file(_,Filename) :- % probably CSP position info; or unknown
1626		specfile:currently_opened_file_status(Main,_),
1627		\+ same_file_name(Main,Filename). %Main \= Filename.
1628
1629		:- use_module(tools,[get_tail_filename/2]).
1630		same_file_name(F1,F2) :-
1631		(F1=F2 -> true
1632		; atom(F1), atom(F2), % we can have a non-atomic name like package(event_b_project)
1633		get_tail_filename(F1,T1),
1634		get_tail_filename(F2,T2), T1=T2).
1635
1636		not_main_filenumber(Filenumber) :-
1637		(bmachine:b_get_main_filenumber(MainFN) -> MainFN \= Filenumber
1638		; true). % there is no main file number, this must be an additionally loaded file (e.g., VisB .def file)
1639
1640		% ---------------------------------
1641
1642
1643
1644		% find a sub-position matching a given target like context_pos
1645		find_sub_position_match(Pos,Target) :- Target=Pos,!.
1646		find_sub_position_match(b(E,_,Infos),Target) :- !,
1647		(find_sub_position_match(Infos,Target) -> true
1648		; first_sub_expr(E,A),find_sub_position_match(A,Target)).
1649		find_sub_position_match(span_predicate(P,_,_),Target) :- !,
1650		find_sub_position_match(P,Target).
1651		find_sub_position_match([H|T],Target) :- !,
1652		posinfo_member(N,[H|T]),
1653		find_sub_position_match(N,Target).
1654		find_sub_position_match(closure(_,_,B),Target) :- !,
1655		find_sub_position_match(B,Target).
1656
1657		extract_pos_context(Span,MainPos,Context,CtxtPos) :-
1658		find_sub_position_match(Span,pos_context(M,C,P)),!,
1659		MainPos=M, Context=C, CtxtPos=P.
1660
1661		% extract additional information about error span, e.g., Definition call context, other spans,...
1662		extract_additional_description(Span,FullDesc) :-
1663		extract_additional_pos_and_descr(Span,_Position,FullDesc,[]).
1664
1665		extract_additional_pos_and_descr(Span,CtxtPos,FullDesc,Opts) :-
1666		extract_pos_context(Span,MainPos,Context,CtxtPos),
1667		%nl,print(pos_context(MainPos,Context,CtxtPos)),nl,
1668		extract_context_msg(Context,MainPos,CMsg,Opts),
1669		(extract_span_description_with_opts(CtxtPos,PosMsg,Opts)
1670		-> (member(inner_context_separator(_,AT),Opts) -> true ; AT = ' at '),
1671		ajoin([CMsg,AT,PosMsg],FullDesc)
1672		; FullDesc=CMsg). % no position info available
1673
1674		extract_context_msg(call_stack(Stack),MainPos,Msg,_Opts) :- !,
1675		translate:translate_call_stack([top_level_call(MainPos)|Stack],Msg).
1676		% dynamic call stack; we add subsidiary DEFINITION calls to the Call stack
1677		% see result e.g., for public_examples/B/FeatureChecks/DEFINITIONS/DefCallStackDisplay.mch
1678		% TODO: should we also add_inner_context_description for use-cases like Atom editor
1679		extract_context_msg(definition_call(Name),MainPos,Msg,Opts) :-
1680		!, % static Definition macro expansion call stack
1681		(member(compact_pos_info,Opts)
1682		-> ajoin(['call of ',Name],OuterMsg)
1683		; ajoin(['DEFINITION call of ',Name],OuterMsg)
1684		),
1685		add_inner_context_description(MainPos,OuterMsg,Msg,Opts).
1686		extract_context_msg(C,MainPos,Msg,Opts) :- ajoin(['CONTEXT: ',C],OuterMsg),
1687		add_inner_context_description(MainPos,OuterMsg,Msg,Opts).
1688
1689
1690		add_inner_context_description(Span,OuterCMsg,FullDesc,Opts) :-
1691		% used to have this check: Span = pos_context(MainPos,Context,CtxtPos),
1692		extract_additional_pos_and_descr(Span,_Pos,InnerCMsg,Opts),!,
1693		(member(inner_context_separator(WITHIN,_),Opts) -> true ; WITHIN = ' within '),
1694		ajoin([InnerCMsg,WITHIN,OuterCMsg],FullDesc).
1695		add_inner_context_description(_,FullDesc,FullDesc,_).
1696
1697		% try and extract a definition call stack
1698		extract_definition_call_stack(pos_context(_Main,definition_call(Name),AuxPos),[Name|T]) :- !,
1699		extract_definition_call_stack(AuxPos,T).
1700		extract_definition_call_stack(_,[]).
1701
1702		% get definition call stack as atom
1703		extract_definition_call_stack_desc(CallPos,CSString) :-
1704		extract_definition_call_stack(CallPos,DefCallStack),
1705		(DefCallStack=[] -> CSString = ''
1706		; reverse(DefCallStack,RS),ajoin_with_sep(RS,'->',DefCallStackTxt),
1707		ajoin([' via ',DefCallStackTxt],CSString)
1708		).
1709		% ---------------------------------
1710
1711		% Get Source Position Info string for use in Tcl/Tk tables (column must be called 'Source'):
1712		get_tk_table_position_info(Span,PosStr) :-
1713		extract_line_col_for_main_file(Span,StartRow,StartCol,EndRow,EndCol), !,
1714		ajoin([' at line ',StartRow,':',StartCol,' - ', EndRow, ':', EndCol],PosStr). % recognised by Tk Table viewer
1715		get_tk_table_position_info(Span,PosStr) :- extract_span_description(Span,PosStr),!.
1716		get_tk_table_position_info(_,'').
1717
1718
1719		% ---------------------------------
1720
1721		:- dynamic backed_up_error/4.
1722
1723		% copy current error facts into backed_up_error facts
1724		backup_errors :-
1725		retractall(backed_up_error(_,_,_,_)),
1726		logged_error(Source,S,TContext,Span),
1727		assertz(backed_up_error(Source,S,TContext,Span)),
1728		fail.
1729		backup_errors.
1730
1731		% ---------------------------------
1732
1733		:- dynamic error_manager_silent_mode/1.
1734		% separate from debug:silent_mode to avoid dependency to debug module
1735		error_manager_silent_mode(off).
1736
1737		set_error_manager_silent_mode(X) :- retractall(error_manager_silent_mode(_)),
1738		assertz(error_manager_silent_mode(X)).
1739
1740
1741		formatsilentmsg(Stream,FS,Args) :- error_manager_silent_mode(off) -> format(Stream,FS,Args) ; true.
1742
1743		% -------------------------------------------
1744
1745		:- use_module(eventhandling,[register_event_listener/3]).
1746		:- register_event_listener(reset_prob,reset_errors,
1747		'Reset Error Manager just like after starup_prob (except total_number_of_errors)').