| 1 | % (c) 2009-2025 Lehrstuhl fuer Softwaretechnik und Programmiersprachen, | |
| 2 | % Heinrich Heine Universitaet Duesseldorf | |
| 3 | % This software is licenced under EPL 1.0 (http://www.eclipse.org/org/documents/epl-v10.html) | |
| 4 | ||
| 5 | ||
| 6 | :- module(memoization,[store_memo_expansion/3, | |
| 7 | get_stored_memo_expansion/3, | |
| 8 | compute_memo_hash/2, | |
| 9 | store_memo_computation_time/2, % for profiling | |
| 10 | ||
| 11 | register_memoization_function/6, | |
| 12 | get_registered_function/2, get_registered_function/3, | |
| 13 | get_registered_function_name/2, | |
| 14 | is_registered_function_name/1, is_registered_function_name/2, | |
| 15 | is_memoization_closure/2, is_memoization_closure/4, | |
| 16 | get_memoization_closure_value/4, | |
| 17 | %expand_memoize_stored_function_reference/2, | |
| 18 | store_memo_result/6, | |
| 19 | %get_stored_memo_result/4, | |
| 20 | apply_to_memoize/8, | |
| 21 | get_complete_memoization_expansion/6, | |
| 22 | element_of_memoization_closure/6, | |
| 23 | not_element_of_memoization_closure/6, | |
| 24 | is_lambda_value_domain_memoization_closure/5, | |
| 25 | ||
| 26 | export_memo_state/1, | |
| 27 | import_memo_state/1, | |
| 28 | ||
| 29 | tcltk_get_memo_profile_table/1, | |
| 30 | print_memo_profile/0, | |
| 31 | reset_memo_table/0, | |
| 32 | reset_memo_with_statistics/0]). | |
| 33 | ||
| 34 | :- use_module(error_manager). | |
| 35 | :- use_module(debug). | |
| 36 | ||
| 37 | :- use_module(module_information,[module_info/2]). | |
| 38 | :- module_info(group,kernel). | |
| 39 | :- module_info(description,'This module provides memoization features (for closure expansion, closure1,...).'). | |
| 40 | % used when use_closure_expansion_memoization is true | |
| 41 | ||
| 42 | :- use_module(probsrc(closures),[is_symbolic_closure/3]). | |
| 43 | :- use_module(probsrc(kernel_waitflags),[add_error_wf/5, add_message_wf/5, add_warning_wf/5]). | |
| 44 | ||
| 45 | :- use_module(extension('counter/counter'),[counter_init/0, reset_counter/1, | |
| 46 | new_counter/1, inc_counter/2, set_counter/2, | |
| 47 | get_counter/2]). | |
| 48 | ||
| 49 | ||
| 50 | :- use_module(eventhandling,[register_event_listener/3]). | |
| 51 | :- register_event_listener(startup_prob,init_memo_table, | |
| 52 | 'Initialise Preferences'). | |
| 53 | :- register_event_listener(clear_specification,reset_memo_table, | |
| 54 | 'Reset Temporary Preferences.'). | |
| 55 | ||
| 56 | ||
| 57 | ||
| 58 | % ---------------- Memoization for set comprehension / lambda / closure1 expansion: | |
| 59 | ||
| 60 | get_stored_memo_expansion(Hash,Term,Result) :- | |
| 61 | stored_memo_expansion(Hash,Term,Result), | |
| 62 | inc_counter(memoization_reuse_counter,_). | |
| 63 | ||
| 64 | :- dynamic stored_memo_expansion/3. | |
| 65 | ||
| 66 | % used for closure1 and reguluar ProB closure expansion memoization | |
| 67 | store_memo_expansion(Hash,LookupTerm,StoredResult) :- | |
| 68 | assertz(stored_memo_expansion(Hash,LookupTerm,StoredResult)). | |
| 69 | ||
| 70 | :- use_module(probsrc(hashing),[sdbm_term_hash/2]). | |
| 71 | compute_memo_hash(LookupTerm,Hash) :- | |
| 72 | inc_counter(memoization_hash_counter,_), | |
| 73 | sdbm_term_hash(LookupTerm,Hash). | |
| 74 | %hashing:my_term_hash(closure(Parameters,ParameterTypes,ClosureBody),Hash), | |
| 75 | %inc(Hash), % | |
| 76 | ||
| 77 | % ---------------- Memoization for function application | |
| 78 | ||
| 79 | :- dynamic registered_value_packed/3, registered_value_name/2, memoization_expansion_completed/1. | |
| 80 | ||
| 81 | % we register the functions to be memoized | |
| 82 | get_registered_function(Id,Val) :- registered_value(Id,_,Val). | |
| 83 | get_registered_function(Id,Name,Val) :- registered_value(Id,Name,Val). | |
| 84 | get_registered_function_name(Id,Name) :- registered_value_name(Id,Name). | |
| 85 | is_registered_function_name(Name) :- registered_value_name(_,Name). | |
| 86 | is_registered_function_name(Name,Expanded) :- registered_value_name(ID,Name), | |
| 87 | (memoization_expansion_completed(ID) -> Expanded=true ; Expanded=false). | |
| 88 | ||
| 89 | :- use_module(tools,[remove_variables/3]). | |
| 90 | :- use_module(kernel_tools,[ground_value_check/2, value_variables/2]). | |
| 91 | % register a (usually symbolic closure) value as a function | |
| 92 | % ElType is the type of the elements of the function and MemoResultClosure is a closure that | |
| 93 | % can and should be used instead of BValue to ensure memoization works | |
| 94 | register_memoization_function(Name,BValue,ElType,RecursionInfo,MemoID,MemoResultClosure) :- | |
| 95 | value_variables(BValue,Vars), | |
| 96 | %print(vars(Name,Vars,LHSValue)),nl, print(bvalue(BValue)),nl, | |
| 97 | (RecursionInfo='$recursion_value'(RecValue) | |
| 98 | -> remove_variables(Vars,[RecValue],WVars), % do not wait on RecValue; it will be set by registering MEMOID | |
| 99 | RecValue = MemoResultClosure, | |
| 100 | InnerMemoID=MemoID % already instantiate MemoID before asserting closure; cyclic use | |
| 101 | ; WVars=Vars | |
| 102 | ), | |
| 103 | ground_value_check(WVars,Ground), | |
| 104 | %print(register(Name,MemoID,Ground,BValue)),nl,nl, | |
| 105 | construct_memoization_closure(MemoID,BValue,ElType,MemoResultClosure), | |
| 106 | register_memoization_function_aux(Ground,Name,BValue,InnerMemoID,MemoID). | |
| 107 | ||
| 108 | :- block register_memoization_function_aux(-,?,?,?,?). | |
| 109 | register_memoization_function_aux(_,Name,BValue,InnerMemoID,MemoID) :- | |
| 110 | inc_counter(memoization_function_counter,InnerMemoID), | |
| 111 | formatsilent('Registering function ~w for memoization: ~w~n',[InnerMemoID,Name]), | |
| 112 | (ground_value(BValue) -> true ; add_internal_error('Non ground memo closure: ',InnerMemoID:BValue)), | |
| 113 | %(BValue=closure(_,_,BB) -> bsyntaxtree:check_used_ids_in_ast(BB) ; true), | |
| 114 | compile_value(BValue,InnerMemoID), | |
| 115 | assertz(registered_value_name(InnerMemoID,Name)), | |
| 116 | assert_registered_value(InnerMemoID,Name,BValue), | |
| 117 | %if(MemoID=InnerMemoID, format('Finish ~w~n',[MemoID]),format('FAILURE ~w~n',[InnerMemoID])). | |
| 118 | MemoID=InnerMemoID. % only unify after assertz; in case co-routines are triggered which call get_registered_function | |
| 119 | ||
| 120 | :- use_module(state_packing,[pack_value/2,unpack_value/2]). | |
| 121 | assert_registered_value(InnerMemoID,Name,BValue) :- | |
| 122 | pack_value(BValue,PValue), | |
| 123 | % mainly useful when COMPRESSION preference is full or | |
| 124 | % when force_state_packing_for_closures is true so that closure bodies packed | |
| 125 | assertz(registered_value_packed(InnerMemoID,Name,PValue)). | |
| 126 | ||
| 127 | registered_value(InnerMemoID,Name,BValue) :- | |
| 128 | registered_value_packed(InnerMemoID,Name,PValue), | |
| 129 | unpack_value(PValue,BValue). | |
| 130 | ||
| 131 | :- load_files(library(system), [when(compile_time), imports([environ/2])]). | |
| 132 | :- if(environ(cogen,true)). | |
| 133 | compile_value(closure(Paras,Ty,Body),InnerMemoID) :- | |
| 134 | compile_closure(Paras,Ty,Body,InnerMemoID),!. | |
| 135 | compile_value(_,_). | |
| 136 | :- use_module(b_cogen). | |
| 137 | :- else. | |
| 138 | compile_value(_,_). | |
| 139 | reset_cogen. | |
| 140 | :- endif. | |
| 141 | ||
| 142 | construct_memoization_closure(MemoID,BValue,ElType,Result) :- | |
| 143 | get_infos(BValue,BInfos), | |
| 144 | XFC = b(external_function_call('MEMOIZE_STORED_FUNCTION',[b(value(int(MemoID)),integer,[])]),set(ElType),[]), | |
| 145 | TID = b(identifier('_zzzz_unary'),ElType,[]), | |
| 146 | Body = b(member(TID,XFC),pred,[prob_annotation('MEMOIZE'(MemoID))|BInfos]), | |
| 147 | %bsyntaxtree:check_used_ids_in_ast(Body), | |
| 148 | %add_message(memo,'Construct memo: ',MemoID,BInfos), | |
| 149 | Result = closure(['_zzzz_unary'],[ElType], Body). | |
| 150 | ||
| 151 | :- use_module(bsyntaxtree,[get_texpr_info/2, extract_info_wo_used_ids/2, extract_pos_infos/2]). % extract_info_wo_used_ids | |
| 152 | % extract important infos, | |
| 153 | get_infos(Var,Res) :- var(Var),!,Res=[]. | |
| 154 | get_infos(closure(_,_,B),Res) :- extract_info_wo_used_ids(B,Infos),!, | |
| 155 | get_texpr_info(B,AllInfos),extract_pos_infos(AllInfos,Pos), | |
| 156 | append(Pos,Infos,Res). | |
| 157 | get_infos(_,[]). % :- print(no_infos(A)),nl. | |
| 158 | ||
| 159 | is_memoization_closure(closure(Ids,T,Body),MemoID) :- | |
| 160 | is_memoization_closure(Ids,T,Body,MemoID). | |
| 161 | ||
| 162 | :- use_module(bsyntaxtree, [get_texpr_id/2]). | |
| 163 | is_memoization_closure([ID],_T,b(Body,_,INFO),MemoID) :- | |
| 164 | ? | member(prob_annotation('MEMOIZE'(MemoID)),INFO), |
| 165 | % check Body has not been rewritten: | |
| 166 | Body = member(TID,b(RHS,_,_)), | |
| 167 | get_texpr_id(TID,ID), | |
| 168 | is_memoize_stored_function_reference(RHS,MemoID), | |
| 169 | (var(MemoID) -> add_debug_message(memoization,'Memoized function ID not yet ground: ',MemoID) | |
| 170 | % has been registered, but body was not yet ground and no MemoID assigned; see test 2209, and other priv tests | |
| 171 | % not be a problem: all relevant predicates below block until MemoID is known | |
| 172 | ; registered_value_name(MemoID,_) -> true | |
| 173 | ; add_error(memoization,'Memoized function ID not registered: ',MemoID), | |
| 174 | fail | |
| 175 | ). | |
| 176 | ||
| 177 | is_memoize_stored_function_reference(external_function_call('MEMOIZE_STORED_FUNCTION',[Arg]),MemoID) :- | |
| 178 | Arg=b(value(int(MemoID)),_,_). | |
| 179 | ||
| 180 | % check if we have a memoization closure and get its stored value | |
| 181 | get_memoization_closure_value(P,T,B,Value) :- | |
| 182 | is_memoization_closure(P,T,B,MemoID), | |
| 183 | number(MemoID), | |
| 184 | registered_value(MemoID,_,Value). | |
| 185 | ||
| 186 | % expand an (untyped) expression term referring to a stored function into full value: | |
| 187 | %expand_memoize_stored_function_reference(Expr,Value) :- | |
| 188 | % is_memoize_stored_function_reference(Expr,MemoID), | |
| 189 | % number(MemoID), % in case this is called before function registered | |
| 190 | % registered_value(MemoID,_,Value). | |
| 191 | ||
| 192 | :- use_module(probsrc(closures),[is_lambda_value_domain_normal_closure/5]). | |
| 193 | :- dynamic stored_lambda_value_domain/3. | |
| 194 | % Note: the caller must check that DomainValue, Expr are not equal to fail | |
| 195 | is_lambda_value_domain_memoization_closure(P,T,Pred, DomainValue,Expr) :- | |
| 196 | ? | is_memoization_closure(P,T,Pred,MemoID), |
| 197 | number(MemoID), | |
| 198 | (stored_lambda_value_domain(MemoID,DV,E) | |
| 199 | -> true %print(get_domain(MemoID)),nl | |
| 200 | ; registered_value(MemoID,_,closure(P2,T2,Pred2)), | |
| 201 | %print(storing(lambda_domain(MemoID))),nl, | |
| 202 | (is_lambda_value_domain_normal_closure(P2,T2,Pred2, DV,E) | |
| 203 | -> assertz(stored_lambda_value_domain(MemoID,DV,E)) | |
| 204 | ; assertz(stored_lambda_value_domain(MemoID,fail,fail)), | |
| 205 | fail | |
| 206 | ) | |
| 207 | ), | |
| 208 | DomainValue=DV, Expr = E. | |
| 209 | ||
| 210 | ||
| 211 | % ---------------------------------------------- | |
| 212 | % providing stored_memo_result_id/4 fact interface | |
| 213 | % some MemoID are stored in separate table | |
| 214 | :- dynamic stored_memo_result1/3, stored_memo_result2/3, | |
| 215 | stored_memo_result3/3, stored_memo_result4/3, | |
| 216 | stored_memo_result5/3, stored_memo_result6/3, | |
| 217 | stored_memo_result7/3, stored_memo_result8/3, | |
| 218 | stored_memo_result/4. | |
| 219 | stored_memo_result_id(1,ArgHash,Argument,StoredResult) :- !, | |
| 220 | stored_memo_result1(ArgHash,Argument,StoredResult). | |
| 221 | stored_memo_result_id(2,ArgHash,Argument,StoredResult) :- !, | |
| 222 | stored_memo_result2(ArgHash,Argument,StoredResult). | |
| 223 | stored_memo_result_id(3,ArgHash,Argument,StoredResult) :- !, | |
| 224 | stored_memo_result3(ArgHash,Argument,StoredResult). | |
| 225 | stored_memo_result_id(4,ArgHash,Argument,StoredResult) :- !, | |
| 226 | stored_memo_result4(ArgHash,Argument,StoredResult). | |
| 227 | stored_memo_result_id(5,ArgHash,Argument,StoredResult) :- !, | |
| 228 | ? | stored_memo_result5(ArgHash,Argument,StoredResult). |
| 229 | stored_memo_result_id(6,ArgHash,Argument,StoredResult) :- !, | |
| 230 | ? | stored_memo_result6(ArgHash,Argument,StoredResult). |
| 231 | stored_memo_result_id(7,ArgHash,Argument,StoredResult) :- !, | |
| 232 | ? | stored_memo_result7(ArgHash,Argument,StoredResult). |
| 233 | stored_memo_result_id(8,ArgHash,Argument,StoredResult) :- !, | |
| 234 | ? | stored_memo_result8(ArgHash,Argument,StoredResult). |
| 235 | stored_memo_result_id(MemoID,ArgHash,Argument,StoredResult) :- | |
| 236 | ? | stored_memo_result(ArgHash,MemoID,Argument,StoredResult). |
| 237 | ||
| 238 | assert_stored_memo_result_id(1,ArgHash,Argument,StoredResult) :- !, | |
| 239 | assertz(stored_memo_result1(ArgHash,Argument,StoredResult)). | |
| 240 | assert_stored_memo_result_id(2,ArgHash,Argument,StoredResult) :- !, | |
| 241 | assertz(stored_memo_result2(ArgHash,Argument,StoredResult)). | |
| 242 | assert_stored_memo_result_id(3,ArgHash,Argument,StoredResult) :- !, | |
| 243 | assertz(stored_memo_result3(ArgHash,Argument,StoredResult)). | |
| 244 | assert_stored_memo_result_id(4,ArgHash,Argument,StoredResult) :- !, | |
| 245 | assertz(stored_memo_result4(ArgHash,Argument,StoredResult)). | |
| 246 | assert_stored_memo_result_id(5,ArgHash,Argument,StoredResult) :- !, | |
| 247 | assertz(stored_memo_result5(ArgHash,Argument,StoredResult)). | |
| 248 | assert_stored_memo_result_id(6,ArgHash,Argument,StoredResult) :- !, | |
| 249 | assertz(stored_memo_result6(ArgHash,Argument,StoredResult)). | |
| 250 | assert_stored_memo_result_id(7,ArgHash,Argument,StoredResult) :- !, | |
| 251 | assertz(stored_memo_result7(ArgHash,Argument,StoredResult)). | |
| 252 | assert_stored_memo_result_id(8,ArgHash,Argument,StoredResult) :- !, | |
| 253 | assertz(stored_memo_result8(ArgHash,Argument,StoredResult)). | |
| 254 | assert_stored_memo_result_id(MemoID,ArgHash,Argument,StoredResult) :- | |
| 255 | assertz(stored_memo_result(ArgHash,MemoID,Argument,StoredResult)). | |
| 256 | ||
| 257 | retractall_stored_memo_result :- | |
| 258 | retractall(stored_memo_result1(_,_,_)), | |
| 259 | retractall(stored_memo_result2(_,_,_)), | |
| 260 | retractall(stored_memo_result3(_,_,_)), | |
| 261 | retractall(stored_memo_result4(_,_,_)), | |
| 262 | retractall(stored_memo_result5(_,_,_)), | |
| 263 | retractall(stored_memo_result6(_,_,_)), | |
| 264 | retractall(stored_memo_result7(_,_,_)), | |
| 265 | retractall(stored_memo_result8(_,_,_)), | |
| 266 | retractall(stored_memo_result(_,_,_,_)). | |
| 267 | ||
| 268 | % this clause is only ok if we have just a single function; otherwise we get collisions between different functions | |
| 269 | compute_funcall_memo_hash(int(X),MemoID,R) :- MemoID <9, !, | |
| 270 | R=X. % avoid computing hash for simple integer values; only drawback: indexing not good for too large integers | |
| 271 | % TO DO: we could register with each registered_value fact also a dynamic table_memo fact | |
| 272 | % then we can avoid clashes between different memoized functions | |
| 273 | compute_funcall_memo_hash(X,MemoID,ArgHash) :- | |
| 274 | compute_memo_hash((MemoID,X),ArgHash). | |
| 275 | ||
| 276 | ||
| 277 | % -------------------------------------------- | |
| 278 | ||
| 279 | % last argument should be left free when calling | |
| 280 | get_stored_memo_result(MemoID,Argument,ArgHash,StoredResult) :- | |
| 281 | stored_memo_result_id(MemoID,ArgHash,Argument,StoredResult), | |
| 282 | %print(get_stored(MemoID,ArgHash,StoredResult)),nl, | |
| 283 | count_reuse(MemoID). | |
| 284 | ||
| 285 | ||
| 286 | :- use_module(kernel_waitflags,[add_wd_error_span/4]). | |
| 287 | :- use_module(tools_strings,[ajoin/2]). | |
| 288 | :- use_module(store,[normalise_value_for_var/3]). | |
| 289 | store_memo_result(MemoID,Argument,ArgHash,Result,Span,WF) :- | |
| 290 | normalise_value_for_var(MemoID,Result,NormResult), | |
| 291 | store_norm_memo_result(MemoID,Argument,ArgHash,NormResult,Span,WF). | |
| 292 | ||
| 293 | :- use_module(kernel_objects,[equal_object/2]). | |
| 294 | store_norm_memo_result(MemoID,Argument,ArgHash,Result,Span,WF) :- | |
| 295 | stored_memo_result_id(MemoID,ArgHash,Argument,StoredResult), | |
| 296 | !, | |
| 297 | (Result=StoredResult -> true | |
| 298 | ; equal_object(Result,StoredResult) -> format('Two representations for memoized function (~w) result.~n',[MemoID]) | |
| 299 | ; ajoin(['Memoized function ',MemoID,' has multiple results for: '],Msg), | |
| 300 | Relation = [(Argument,StoredResult),(Argument,Result)], | |
| 301 | add_wd_error_span(Msg,'@fun'(Argument,Relation),Span,WF) | |
| 302 | %,print('stored: '),translate:print_bvalue(StoredResult),nl,print('new: '),translate:print_bvalue(Result),nl | |
| 303 | ). | |
| 304 | store_norm_memo_result(MemoID,Argument,ArgHash,Result,_,_) :- | |
| 305 | %format('Storing memo result for ~w, argument =',[MemoID]), | |
| 306 | %translate:print_bvalue(Argument),nl, translate:print_bvalue(Result),nl, | |
| 307 | assert_stored_memo_result_id(MemoID,ArgHash,Argument,Result). | |
| 308 | %assertz(stored_memo_result(ArgHash,MemoID,Argument,Result)). | |
| 309 | %print(stored_memo_result(ArgHash,MemoID,Argument,Result)),nl. | |
| 310 | ||
| 311 | ||
| 312 | % function application for memoized function: | |
| 313 | apply_to_memoize(MemoID,P,T,B,X,Y,Span,WF) :- | |
| 314 | ground_value_check(X,XV), | |
| 315 | block_apply_closure_memo_groundx(XV,MemoID,X,Y,P,T,B,raise_wd,Span,WF). | |
| 316 | ||
| 317 | :- use_module(kernel_tools,[ground_value/1]). | |
| 318 | :- use_module(kernel_objects,[equal_object_wf/3]). | |
| 319 | ||
| 320 | :- block block_apply_closure_memo_groundx(-,?, ?,?, ?,?,?, ?,?,?), | |
| 321 | block_apply_closure_memo_groundx(?,-, ?,?, ?,?,?, ?,?,?). | |
| 322 | ||
| 323 | ||
| 324 | block_apply_closure_memo_groundx(_,MemoID, X,Y, P,T,B, RaiseWD, Span,WF) :- | |
| 325 | % MemoID is ground, meaning body B is ground as well | |
| 326 | % TODO: obtain stored value directly | |
| 327 | compute_funcall_memo_hash(X,MemoID,ArgHash), | |
| 328 | if(get_stored_memo_result(MemoID,X,ArgHash,StoredResult), | |
| 329 | equal_object_wf(Y,StoredResult,WF), | |
| 330 | (start_profile_function_application(MemoID,Timer), | |
| 331 | if(check_element_of_function_closure_nowf(MemoID,X,ComputedResult,P,T,B,Span,WF), | |
| 332 | % ground WF to compute ground value for ComputedResult | |
| 333 | (stop_profile_function_application(MemoID,X,Timer,WF), | |
| 334 | (ground_value(ComputedResult) | |
| 335 | -> store_memo_result(MemoID,X,ArgHash,ComputedResult,Span,WF) | |
| 336 | ; add_error_wf(memoization,'Could not compute ground value for function application',MemoID,Span,WF), | |
| 337 | print('Argument: '),translate:print_bvalue(X),nl, | |
| 338 | print('Result: '), print(ComputedResult),nl, | |
| 339 | print('Function: '),registered_value(MemoID,_Name,FunValue), translate:print_bvalue(FunValue),nl,nl | |
| 340 | ), | |
| 341 | % To do: check if we compute two or more solutions for f(X) and add WD error | |
| 342 | equal_object_wf(Y,ComputedResult,WF) | |
| 343 | ), | |
| 344 | (RaiseWD=raise_wd, | |
| 345 | add_wd_error_span('function applied outside of domain (#8-Memo): ', '@fun'(X,closure(P,T,B)),Span,WF) | |
| 346 | ) | |
| 347 | ) | |
| 348 | ) | |
| 349 | ). | |
| 350 | ||
| 351 | :- use_module(kernel_waitflags, [init_wait_flags/2, init_wait_flags_and_push_call_stack/3,ground_wait_flags/1]). | |
| 352 | :- use_module(custom_explicit_sets,[check_element_of_function_closure/6]). | |
| 353 | check_element_of_function_closure_nowf(MemoID,X,ComputedResult,_,_,_,Span,OuterWF) :- | |
| 354 | registered_value(MemoID,Name,closure(P,T,B)),!, % can be expensive if closure contains large values | |
| 355 | init_wait_flags_and_push_call_stack(OuterWF,function_call(Name,X,Span),WF), % slows down test 1968 with recursion | |
| 356 | check_element_of_function_closure(X,ComputedResult,P,T,B,WF), | |
| 357 | ground_wait_flags(WF). | |
| 358 | check_element_of_function_closure_nowf(_,X,ComputedResult,P,T,B,_Span,_OuterWF) :- | |
| 359 | init_wait_flags(WF,[check_element_of_function_closure_nowf]), | |
| 360 | check_element_of_function_closure(X,ComputedResult,P,T,B,WF), | |
| 361 | ground_wait_flags(WF). | |
| 362 | ||
| 363 | :- use_module(library(avl),[avl_domain/2]). | |
| 364 | :- use_module(library(lists),[maplist/2]). | |
| 365 | ||
| 366 | % store the complete expansion of a memoized function for later re-use | |
| 367 | % and also passes result and done flag to an outer call | |
| 368 | :- block store_memoization_closure_expansion(?,-,?,?,?,?,?). | |
| 369 | store_memoization_closure_expansion(MemoID,_,Res,OuterDone,OuterRes,Span,WF) :- | |
| 370 | my_avl_domain(Res,List), | |
| 371 | !, | |
| 372 | debug_println(19,storing_expansion_of_memoized_function(MemoID)), | |
| 373 | (maplist(store_function_result(MemoID,Span,WF),List) | |
| 374 | -> assertz(memoization_expansion_completed(MemoID)) | |
| 375 | ; add_internal_error(memoization,'Error storing expansion for memoized function:',MemoID,Span)), | |
| 376 | equal_object_wf(Res,OuterRes,WF), OuterDone=true. | |
| 377 | store_memoization_closure_expansion(MemoID,_,R,OuterDone,OuterRes,Span,WF) :- | |
| 378 | add_warning_wf(memoization,'Cannot store expansion for memoized function:',MemoID:R,Span,WF), | |
| 379 | equal_object_wf(R,OuterRes,WF), OuterDone=true. | |
| 380 | ||
| 381 | my_avl_domain(avl_set(A),List) :- avl_domain(A,List). | |
| 382 | my_avl_domain([],[]). | |
| 383 | ||
| 384 | store_function_result(MemoID,Span,WF,(X,ComputedResult)) :- | |
| 385 | compute_funcall_memo_hash(X,MemoID,ArgHash), | |
| 386 | store_memo_result(MemoID,X,ArgHash,ComputedResult,Span,WF). % TO DO: we could use special version that also allows relations | |
| 387 | ||
| 388 | :- use_module(kernel_objects,[equal_object_optimized_wf/4]). | |
| 389 | % succeeds if function has been completely memoized and returns expansion | |
| 390 | try_get_complete_memoization_expansion(MemoID,Result,WF) :- | |
| 391 | nonvar(MemoID), | |
| 392 | memoization_expansion_completed(MemoID), | |
| 393 | debug_println(19,recovering_full_value_for_memoized_function(MemoID)), | |
| 394 | findall((X,Y),stored_memo_result_id(MemoID,_,X,Y),List), % probably not sorted ! | |
| 395 | equal_object_optimized_wf(List,Result,expand_normal_closure_memo,WF). | |
| 396 | ||
| 397 | % always succeeds to obtain the full expansion; also stores it for reuse | |
| 398 | :- block get_complete_memoization_expansion(-,?,?,?,?,?). | |
| 399 | get_complete_memoization_expansion(MemoID,Result,Done,_,_PP,WF) :- | |
| 400 | try_get_complete_memoization_expansion(MemoID,Cached,WF), | |
| 401 | !, | |
| 402 | Result=Cached, Done=true. | |
| 403 | get_complete_memoization_expansion(MemoID,Result,Done,Span,PP,WF) :- | |
| 404 | registered_value(MemoID,Name,Val), nonvar(Val), | |
| 405 | !, | |
| 406 | get_complete_memoization_expansion_aux(Val,MemoID,Name,Result,Done,Span,PP,WF). | |
| 407 | get_complete_memoization_expansion(MemoID,_,_,Span,PP,WF) :- | |
| 408 | add_error_wf(get_complete_memoization_expansion,'Memoized function ID not registered:',MemoID:PP,Span,WF), | |
| 409 | fail. | |
| 410 | ||
| 411 | ||
| 412 | get_complete_memoization_expansion_aux(Val,_MemoID,_,Result,Done,_Span,_PP,_WF) :- expanded_value(Val), !, | |
| 413 | Result=Val,Done=true. | |
| 414 | get_complete_memoization_expansion_aux(closure(P,T,B),MemoID,Name,Result,Done,Span,PP,WF) :- !, | |
| 415 | debug_println(19,expanding_memoized_function(MemoID,PP)), | |
| 416 | (custom_explicit_sets:is_infinite_or_very_large_closure(P,T,B,200000) | |
| 417 | -> add_warning_wf(PP,'Expanding infinite or very large memoized function: ',Name,B,WF) | |
| 418 | ? | ; is_symbolic_closure(P,T,B) |
| 419 | -> add_message_wf(PP,'Fully expanding symbolic memoized function: ',Name,B,WF) | |
| 420 | ; true), | |
| 421 | % bsyntaxtree:check_used_ids_in_ast(B), | |
| 422 | custom_explicit_sets:expand_normal_closure_direct(P,T,B,Expansion,DoneExp,WF), | |
| 423 | store_memoization_closure_expansion(MemoID,DoneExp,Expansion,Done,Result,Span,WF). | |
| 424 | get_complete_memoization_expansion_aux(Val,MemoID,Name,_,_,Span,PP,WF) :- | |
| 425 | add_error_wf(memoization(PP),'Illegal value stored for memoized function:',MemoID:Name,Span,WF), | |
| 426 | print(Val),nl, | |
| 427 | fail. | |
| 428 | ||
| 429 | expanded_value(avl_set(_)). | |
| 430 | expanded_value(global_set(_)). | |
| 431 | expanded_value([]). | |
| 432 | expanded_value([_|_]). | |
| 433 | ||
| 434 | :- use_module(kernel_tools,[ground_value/1]). | |
| 435 | :- use_module(kernel_objects,[check_element_of_wf/3]). | |
| 436 | % special treatment for element of memoization closure; possibly not a function call | |
| 437 | element_of_memoization_closure(MemoID,Element,WF,P,T,B) :- | |
| 438 | nonvar(Element), Element = (X,Y), | |
| 439 | % we can do a function application; we assume that we only store functions | |
| 440 | ground_value_check(X,GrX), | |
| 441 | !, %print(fun_apply_reuse(MemoID,Element)),nl, | |
| 442 | Span=B, | |
| 443 | % do_not_raise_wd: do not raise outside of domain errors | |
| 444 | block_apply_closure_memo_groundx(GrX,MemoID, X,Y, P,T,B, do_not_raise_wd, Span,WF). | |
| 445 | element_of_memoization_closure(MemoID,Element,WF,_,_,B) :- | |
| 446 | % TO DO: delay before computing complete memoization | |
| 447 | get_complete_memoization_expansion(MemoID,Set,_Done,B,element_of_memoization_closure,WF), | |
| 448 | !, %print(el_of(MemoID,Element)),nl, | |
| 449 | check_element_of_wf(Element,Set,WF). | |
| 450 | ||
| 451 | :- use_module(kernel_objects,[not_equal_object_wf/3]). | |
| 452 | :- use_module(kernel_objects,[not_element_of_wf/3]). | |
| 453 | ||
| 454 | not_element_of_memoization_closure(MemoID,Element,WF,P,T,B) :- | |
| 455 | nonvar(Element), Element = (X,Y), | |
| 456 | % we can do a function application; we assume that we only store functions | |
| 457 | ground_value_check(X,GrX), | |
| 458 | !, | |
| 459 | block_not_apply_closure_memo_groundx(GrX,MemoID, X,Y, P,T,B, do_not_raise_wd, B,WF). | |
| 460 | not_element_of_memoization_closure(MemoID,Element,WF,_,_,B) :- | |
| 461 | % TO DO: delay before computing complete memoization | |
| 462 | get_complete_memoization_expansion(MemoID,Set,_Done,B,not_element_of_memoization_closure,WF), | |
| 463 | !, | |
| 464 | not_element_of_wf(Element,Set,WF). | |
| 465 | ||
| 466 | ||
| 467 | :- block block_not_apply_closure_memo_groundx(-,?, ?,?, ?,?,?, ?,?,?). | |
| 468 | ||
| 469 | block_not_apply_closure_memo_groundx(GrX,MemoID, X,Y, P,T,B, RaiseWD, Span,WF) :- | |
| 470 | if(block_apply_closure_memo_groundx(GrX,MemoID, X,YRes, P,T,B, RaiseWD, Span,WF), | |
| 471 | not_equal_object_wf(Y,YRes,wf), | |
| 472 | true). | |
| 473 | ||
| 474 | % ------------------------------- | |
| 475 | ||
| 476 | :- dynamic function_application_time/2. | |
| 477 | :- use_module(preferences,[preference/2,get_preference/2]). | |
| 478 | :- load_files(library(system), [when(compile_time), imports([environ/2])]). | |
| 479 | :- if(\+ environ(prob_profile,false)). | |
| 480 | %:- print('Profiling Memoizations'),nl. | |
| 481 | count_reuse(MemoID) :- | |
| 482 | my_bb_get_reuse_counter(MemoID,Cnt), C1 is Cnt+1, bb_put(MemoID,C1), | |
| 483 | inc_counter(memoization_function_reuse_counter,_). | |
| 484 | my_bb_get_reuse_counter(Key,Val) :- (bb_get(Key,V) -> V=Val ; Val=0). | |
| 485 | bb_reset_reuse_counter(Key) :- bb_put(Key,0). | |
| 486 | start_profile_function_application(_,Walltime) :- preference(prob_profiling_on,false),!, Walltime=0. | |
| 487 | start_profile_function_application(_,Walltime) :- statistics(walltime,[Walltime,_]). | |
| 488 | :- use_module(probsrc(performance_messages),[perf_format_wf/3]). | |
| 489 | stop_profile_function_application(_,_,_,_) :- preference(prob_profiling_on,false),!. | |
| 490 | stop_profile_function_application(MemoID,X,Walltime1,WF) :- statistics(walltime,[Walltime2,_]), | |
| 491 | Delta is Walltime2-Walltime1, | |
| 492 | (Delta>0 -> | |
| 493 | (Delta > 1000 | |
| 494 | -> perf_format_wf('Long /* @memo ~w */ function application : ~w ms : arg: ~w~n',[MemoID,Delta,X],WF) ; true), | |
| 495 | (retract(function_application_time(MemoID,Old)) | |
| 496 | -> New is Old+Delta ; New = Delta), | |
| 497 | assertz(function_application_time(MemoID,New)) | |
| 498 | ; true | |
| 499 | ). | |
| 500 | function_application_time_available :- get_preference(prob_profiling_on,true). | |
| 501 | :- else. | |
| 502 | count_reuse(_MemoID) :- | |
| 503 | inc_counter(memoization_function_reuse_counter,_). | |
| 504 | my_bb_get_reuse_counter(_,'?'). | |
| 505 | bb_reset_reuse_counter(_). | |
| 506 | start_profile_function_application(_,0). | |
| 507 | stop_profile_function_application(_,_,_,_). | |
| 508 | function_application_time_available :- fail. | |
| 509 | :- endif. | |
| 510 | ||
| 511 | % ------------------------------- | |
| 512 | % utilities to profile expansions | |
| 513 | :- public inc/1. | |
| 514 | :- dynamic hash_count/2. | |
| 515 | inc(Hash) :- (retract(hash_count(Hash,Nr)) -> N1 is Nr+1 ; N1 = 1), assertz(hash_count(Hash,N1)). | |
| 516 | :- dynamic hash_time/2. | |
| 517 | store_memo_computation_time(Hash,Time) :- % for closure expansions, not for funct. applications | |
| 518 | retractall(hash_time(Hash,_)), assertz(hash_time(Hash,Time)). | |
| 519 | ||
| 520 | % reused and walltime info requires prob_profile flag | |
| 521 | tcltk_get_memo_profile_table(list([Header|Entries])) :- | |
| 522 | Header = list(['ID','Name','Fully','Stored Values','Reused','Walltime (ms)']), | |
| 523 | findall(Entry,get_memo_entry_info(Entry),Entries). | |
| 524 | ||
| 525 | get_memo_entry_info(list([MemoID,Name,Complete,NrStored,ReuseCnt,Walltime])) :- | |
| 526 | registered_value(MemoID,Name,_FunValue), | |
| 527 | (memoization_expansion_completed(MemoID) -> Complete='true' ; Complete = 'false'), | |
| 528 | get_memo_profile_info(MemoID,NrStored,Walltime,ReuseCnt). | |
| 529 | ||
| 530 | % get some profile info about a MemoID | |
| 531 | get_memo_profile_info(MemoID,NrStored,Walltime,ReuseCnt) :- | |
| 532 | my_bb_get_reuse_counter(MemoID,ReuseCnt), | |
| 533 | findall(1,stored_memo_result_id(MemoID,_Hash,_,_),Stored), length(Stored,NrStored), | |
| 534 | (\+ function_application_time_available -> Walltime='?' | |
| 535 | ; function_application_time(MemoID,Walltime) -> true ; Walltime=0). | |
| 536 | ||
| 537 | ||
| 538 | print_memo_profile :- | |
| 539 | ((stored_memo_expansion(_,_,_) ; registered_value_packed(_,_,_)) | |
| 540 | -> print('MEMO Table:'),nl, | |
| 541 | print_memo_table | |
| 542 | ; true). | |
| 543 | ||
| 544 | :- use_module(library(terms), [term_size/2]). | |
| 545 | % memoization:print_memo. | |
| 546 | print_memo_table :- | |
| 547 | stored_memo_expansion(Hash,LookupTerm,PackedValue), | |
| 548 | (hash_count(Hash,Count) -> print(Count), print(' : ') ; true), | |
| 549 | (hash_time(Hash,Time) -> print(Time),print(' --> ') ; true), | |
| 550 | print_memo_entry(LookupTerm), | |
| 551 | nl, print(' : '),translate:print_bvalue(PackedValue),nl,fail. | |
| 552 | print_memo_table :- | |
| 553 | debug_mode(on), | |
| 554 | registered_value(MemoID,Name,FunValue), | |
| 555 | (memoization_expansion_completed(MemoID) | |
| 556 | -> Compl=' (completely evaluated)' ; Compl=''), | |
| 557 | format('MemoID ~w stored FUNCTION ~w~w ',[MemoID,Name,Compl]), | |
| 558 | nl, print(' : '),translate:print_bvalue(FunValue),nl,fail. | |
| 559 | print_memo_table :- | |
| 560 | debug_mode(on), | |
| 561 | registered_value_name(MemoID,Name), | |
| 562 | stored_memo_result_id(MemoID,_Hash,LookupTerm,PackedValue), | |
| 563 | term_size(LookupTerm,LSz), | |
| 564 | format('MemoID ~w (~w) result for argument (size=~w) ',[MemoID,Name,LSz]), | |
| 565 | print_memo_entry(LookupTerm), | |
| 566 | term_size(PackedValue,PSz), | |
| 567 | format('~n : (size=~w) ',[PSz]),translate:print_bvalue(PackedValue),nl,fail. | |
| 568 | print_memo_table :- | |
| 569 | stored_memo_result(Hash,MemoID1,T1,_), | |
| 570 | stored_memo_result(Hash,MemoID2,T2,_), | |
| 571 | dif((MemoID1,T1),(MemoID2,T2)), | |
| 572 | format('Hash COLLISION ~w, ~w:~w vs ~w:~w~n',[Hash,MemoID1,T1,MemoID2,T2]), | |
| 573 | fail. | |
| 574 | print_memo_table :- format('Summary of reuse per memoization ID:~n',[]), | |
| 575 | registered_value_name(MemoID,Name), | |
| 576 | get_memo_profile_info(MemoID,NrStored,Walltime,ReuseCnt), | |
| 577 | format('MemoID ~w (~w) : Values Stored: ~w (~w ms to compute), Reused ~w~n',[MemoID,Name,NrStored,Walltime,ReuseCnt]), | |
| 578 | fail. | |
| 579 | print_memo_table :- get_counter(memoization_hash_counter,Hash), | |
| 580 | get_counter(memoization_reuse_counter,RHit), | |
| 581 | format('Hashes computed: ~w, expansions reused: ~w~n',[Hash,RHit]), | |
| 582 | get_counter(memoization_function_counter,F), | |
| 583 | get_counter(memoization_function_reuse_counter,FR), | |
| 584 | format('Memoization functions registered: ~w, results reused: ~w~n',[F,FR]). | |
| 585 | ||
| 586 | print_memo_entry(closure(Parameters,ParameterTypes,ClosureBody)) :- !, | |
| 587 | translate:print_bvalue(closure(Parameters,ParameterTypes,ClosureBody)). | |
| 588 | print_memo_entry(closure1_for_explicit_set(A)) :- !, | |
| 589 | print('closure1('),translate:print_bvalue(avl_set(A)), print(')'). | |
| 590 | print_memo_entry(A) :- translate:print_bvalue(A). | |
| 591 | ||
| 592 | init_memo_table :- | |
| 593 | counter_init, | |
| 594 | new_counter(memoization_reuse_counter), new_counter(memoization_hash_counter), | |
| 595 | new_counter(memoization_function_counter), new_counter(memoization_function_reuse_counter), | |
| 596 | reset_memo_table. | |
| 597 | ||
| 598 | reset_memo_table :- | |
| 599 | ? | retract(registered_value_packed(MemoID,_,_)), |
| 600 | bb_reset_reuse_counter(MemoID), | |
| 601 | retract(registered_value_name(MemoID,_)), | |
| 602 | fail. | |
| 603 | reset_memo_table :- | |
| 604 | reset_counter(memoization_reuse_counter), | |
| 605 | reset_counter(memoization_hash_counter), | |
| 606 | reset_counter(memoization_function_counter), | |
| 607 | reset_counter(memoization_function_reuse_counter), | |
| 608 | ? | (stored_memo_expansion(_,_,_) -> debug_println(19,'Resetting MEMO table') ; true), |
| 609 | retractall(hash_count(_,_)), | |
| 610 | retractall(hash_time(_,_)), | |
| 611 | retractall(stored_memo_expansion(_,_,_)), | |
| 612 | retractall(registered_value_packed(_,_,_)), | |
| 613 | retractall(registered_value_name(_,_)), | |
| 614 | retractall(function_application_time(_,_)), | |
| 615 | retractall(memoization_expansion_completed(_)), | |
| 616 | retractall(stored_lambda_value_domain(_,_,_)), | |
| 617 | retractall_stored_memo_result, | |
| 618 | reset_cogen. | |
| 619 | ||
| 620 | :- use_module(probsrc(tools),[retract_with_statistics/2]). | |
| 621 | reset_memo_with_statistics :- | |
| 622 | retract_with_statistics(memoization, | |
| 623 | [stored_memo_expansion(_,_,_), | |
| 624 | registered_value_packed(_,_,_),registered_value_name(_,_), | |
| 625 | memoization_expansion_completed(_), | |
| 626 | stored_lambda_value_domain(_,_,_), | |
| 627 | stored_memo_result1(_,_,_), stored_memo_result2(_,_,_), | |
| 628 | stored_memo_result3(_,_,_), stored_memo_result4(_,_,_), | |
| 629 | stored_memo_result5(_,_,_), stored_memo_result6(_,_,_), | |
| 630 | stored_memo_result7(_,_,_), stored_memo_result8(_,_,_), | |
| 631 | stored_memo_result(_,_,_,_)]), | |
| 632 | reset_memo_table. | |
| 633 | ||
| 634 | % export the currently registered functions into a list of terms, which can be re-imported later | |
| 635 | export_memo_state(memo_export(1,List,[use_state_packing/SP])) :- | |
| 636 | get_preference(use_state_packing,SP), | |
| 637 | findall(registered_value_packed(InnerMemoID,Name,PValue), | |
| 638 | (registered_value_packed(InnerMemoID,Name,PValue), | |
| 639 | formatsilent('value caching: exporting memoized function ~w : ~w~n',[InnerMemoID,Name])), List). | |
| 640 | ||
| 641 | % import registered functions from a list of terms | |
| 642 | import_memo_state(memo_export(_,[],_)) :- !. % nothing to import | |
| 643 | import_memo_state(memo_export(_,_,_)) :- | |
| 644 | findall(Name,registered_value_name(_,Name),Ls), | |
| 645 | Ls \= [], | |
| 646 | add_warning(memoization,'Memo table not empty for import: ',Ls), | |
| 647 | reset_memo_table, | |
| 648 | fail. | |
| 649 | import_memo_state(memo_export(1,List,Par)) :- | |
| 650 | get_preference(use_state_packing,SP), | |
| 651 | member(use_state_packing/SP,Par),!, | |
| 652 | import_memo_values(List,0). | |
| 653 | import_memo_state(memo_export(Vers,_,Paras)) :- !, | |
| 654 | add_error(memoization,'Version or COMPRESSION setting has changed from: ',Vers:Paras). | |
| 655 | import_memo_state(Term) :- | |
| 656 | add_error(memoization,'Illegal memo export term: ',Term). | |
| 657 | ||
| 658 | import_memo_values([],Nr) :- | |
| 659 | set_counter(memoization_function_counter,Nr). | |
| 660 | import_memo_values([registered_value_packed(InnerMemoID,Name,PValue) | T],Count) :- | |
| 661 | assertz(registered_value_name(InnerMemoID,Name)), | |
| 662 | assertz(registered_value_packed(InnerMemoID,Name,PValue)), | |
| 663 | formatsilent('value caching: imported memoized function ~w : ~w~n',[InnerMemoID,Name]), | |
| 664 | C1 is Count+1, | |
| 665 | import_memo_values(T,C1). | |
| 666 |